Search for text within a string after specific text

[KDoc]

Hi,

Is there an easier way to search for text data Autoit String with specific parameters.  

For example, I have a string $A="Customer Name: John Smith, Address: 1234 Main Street, Chicago, IL, Customer Rec#: 123457, PHone Number#: 555-555-1212'

I want to be able to grab the customer # by searching the phrase 'Customer Rec #:' and only grabbing the data after that phrase till for example the comma after the #.  I know some programming languages offer data extraction through patterns and wasn't sure if there was a similar or easier way in Autoit to extract data this way. 

Thanks

K

[Jos]

Sure: Open the helpfile and look for StringRegExp().

Jos

[water]

I'm not very familiar with Regular Expressions so I use multiple StringSplit:

#include <StringConstants.au3>
Global $A = "Customer Name: John Smith, Address: 1234 Main Street, Chicago, IL, Customer Rec#: 123457, PHone Number#: 555-555-1212"
Global $aSplit = StringSplit($A, "Customer Rec#:", $STR_NOCOUNT + $STR_ENTIRESPLIT)
If @error Then Exit MsgBox(0, "Error", "String 'Customer Rec#:' not found!")
Global $aCustomerNumber = StringSplit($aSplit[1], ",")
If @error Then Exit MsgBox(0, "Error", "No Customer Rec# found!")
MsgBox(0, "Customer Rec#", $aCustomerNumber[1])

 

[Jos]

Isn't really that difficult.  

Global $A = "Customer Name: John Smith, Address: 1234 Main Street, Chicago, IL, Customer Rec#: 123457, PHone Number#: 555-555-1212"
Global $aCustomerNumber = StringRegExp($A, "Customer Rec#: (.*?),",3)
If @error Then Exit MsgBox(0, "Error", "String 'Customer Rec#:' not found!")
MsgBox(0, "Customer Rec#", $aCustomerNumber[0])

Jos

[Exit]

or

#include <String.au3>
Global $sA = "Customer Name: John Smith, Address: 1234 Main Street, Chicago, IL, Customer Rec#: 123457, PHone Number#: 555-555-1212"
Global $aCustomerNumber = _StringBetween($sA, "Customer Rec#: ", ", ")
MsgBox(0, "Customer Rec#", (@error?"not found":$aCustomerNumber[0]))

 

[westernira]

open the helpfile and then find the command.

[Melba23]

westernira,

Pretty punchy post for a newcomer to the forum, but welcome anyway.

I hope your first question gets a more sympathetic response that the one you have just provided. I would however suggest adopting a slightly more emollient tone if you want that to be the case.

M23

[iamtheky]

moar stringops!

Global $A = "Customer Name: John Smith, Address: 1234 Main Street, Chicago, IL, Customer Rec#: 123457, PHone Number#: 555-555-1212"
msgbox(0, '' , StringLeft((stringmid($A , StringInStr($A , "Customer Rec#: ") + StringLen("Customer Rec#: ") - 1)) , (StringInStr(stringmid($A , StringInStr($A , "Customer Rec#: ") + StringLen("Customer Rec#: ") - 1) , ",") - 1)))

 

[Exit]

 @iamtheky  Not foolproof, see aditional blank In customer

Global $A = "Customer Name: John Smith, Address: 1234 Main Street, Chicago, IL, Customer Rec#: 123457, PHone Number#: 555-555-1212"
msgbox(0, '' , StringLeft((stringmid($A , StringInStr($A , "Customer Rec#: ") + StringLen("Customer Rec#: ") - 1)) , (StringInStr(stringmid($A , StringInStr($A , "Customer Rec#: ") + StringLen("Customer Rec#: ") - 1) , ",") - 1)),2)

;~ Not foolproof, see aditional blank In customer ---------------------------------v
Global $A = "Customer Name: John Smith, Address: 1234 Main Street, Chicago, IL, Cus tomer Rec#: 123457, PHone Number#: 555-555-1212"
msgbox(0, '' , StringLeft((stringmid($A , StringInStr($A , "Customer Rec#: ") + StringLen("Customer Rec#: ") - 1)) , (StringInStr(stringmid($A , StringInStr($A , "Customer Rec#: ") + StringLen("Customer Rec#: ") - 1) , ",") - 1)))

 

Edited May 18, 2019 by Exit

[iamtheky]

I dont make scripts for people who dont properly sanitize their input, its gross