Big Analogue Clock

[MattyD]

Hey folks,

This is actually the beginnings of something else - but I was pretty happy with how this part turned out.

So hey, here is a clock.

it is drag-able
Escape (after clicking on clock) : Exit
Wheel: Grow & Shrink
Click Wheel: Reset Size

Edit: somehow missed an include directive...

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters = -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#NoTrayIcon
#include <GDIPlus.au3>
#include <GUIConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", 1)

Global $hGUI, $iWinH, $iWinW, $iChSize, _
        $iStartSz, $iMargin, $iCanvasSz, $iWinXStartPos
Global Const $PI = 4 * ATan(1)
Global Const $MAGIC_PINK = 0xFF00FF, $MAGIC_PINK_ARGB = 0xFFFF00FF

$iWinH = @DesktopHeight
$iWinW = $iWinH
$iCanvasSz = $iWinH

$iMargin = 4
$iStartSz = Int($iWinH / 4) - (2 * $iMargin)
$iWinXStartPos = 0 ;Right Side: ide@DesktopWidth - ($iStartSz + (2 * $iMargin))

$hGUI = GUICreate("Clock", $iWinW, $iWinH, $iWinXStartPos, 0, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TOPMOST))
GUISetBkColor($MAGIC_PINK)
_WinAPI_SetLayeredWindowAttributes($hGUI, $MAGIC_PINK, 0xF0)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")
GUIRegisterMsg($WM_MOUSEWHEEL, "WM_MOUSEWHEEL")
GUIRegisterMsg($WM_NCMBUTTONDOWN, "WM_NCMBUTTONDOWN")

Clock()

Func Clock()

    Local $hGraphic, $hClockBitmap, $hClockGraphic
    Local $iSize, $iDigSize, $iOrigin
    Local $iNumDist, $iDigXOffset, $iDigYOffset
    Local $ixOffset, $iyOffset
    Local $hFrameBrush, $hNoseBrush, $hHighlightBrush, $hFaceBrush
    Local $hBlackPen, $hSecPen, $hMinPen, $hHourPen
    Local $iSec, $iMin, $iHour
    Local $ixSecOffset, $iySecOffset, $ixMinOffset, $iyMinOffset, _
            $ixHourOffset, $iyHourOffset

    $iDigSize = $iSize / 20
    $iChSize = $iStartSz

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    $hClockBitmap = _GDIPlus_BitmapCreateFromGraphics($iCanvasSz, $iCanvasSz, $hGraphic)
    $hClockGraphic = _GDIPlus_ImageGetGraphicsContext($hClockBitmap)
    _GDIPlus_GraphicsSetSmoothingMode($hClockGraphic, 4)

    $hFrameBrush = _GDIPlus_BrushCreateSolid(0xFF80BBCC)
    $hNoseBrush = _GDIPlus_BrushCreateSolid(0xEE778888)
    $hHighlightBrush = _GDIPlus_BrushCreateSolid(0x44FF00FF)
    $hFaceBrush = _GDIPlus_BrushCreateSolid(0xFFEEF0FF)

    $hSecPen = _GDIPlus_PenCreate(0xBB882255, 1)
    $hMinPen = _GDIPlus_PenCreate(0xBBFF8833, 4)
    $hHourPen = _GDIPlus_PenCreate(0xEE4488AA, 5)
    $hBlackPen = _GDIPlus_PenCreate(0xFF000000, 4)

    Do
        If $iSize <> $iChSize Or @SEC <> $iSec Then
            $iSize = $iChSize
            $iDigSize = $iSize / 20
            $iOrigin = Int($iSize / 2) + $iMargin

            $iNumDist = $iSize / 2 - ($iSize / 8)
            $iDigXOffset = .55 * $iDigSize
            $iDigYOffset = -(.7 * $iDigSize)

            _GDIPlus_GraphicsClear($hClockGraphic, $MAGIC_PINK_ARGB)

            _GDIPlus_GraphicsFillEllipse($hClockGraphic, $iMargin, $iMargin, $iSize, $iSize, $hFrameBrush)
            _GDIPlus_GraphicsFillEllipse($hClockGraphic, $iMargin + 8, $iMargin + 8, $iSize - 8, $iSize - 8, $hHighlightBrush)
            _GDIPlus_GraphicsFillEllipse($hClockGraphic, $iMargin + 8, $iMargin + 8, $iSize - 16, $iSize - 16, $hFaceBrush)
            _GDIPlus_GraphicsDrawEllipse($hClockGraphic, $iMargin, $iMargin, $iSize, $iSize, $hBlackPen)

            For $i = 1 To 12
                $ixOffset = Int($iNumDist * Sin($i * ($PI / 6)))
                $iyOffset = Int($iNumDist * Cos($i * ($PI / 6)))
                $ixOffset -= (StringLen($i) * $iDigXOffset)
                $iyOffset -= $iDigYOffset

                _GDIPlus_GraphicsDrawString($hClockGraphic, $i, ($iOrigin + $ixOffset), ($iOrigin - $iyOffset), "Symbol", $iDigSize)
            Next

            $iSec = @SEC
            $iMin = 60 * @MIN + $iSec
            $iHour = (3600 * @HOUR) + $iMin

            $ixSecOffset = Int((0.83 * $iNumDist) * Sin($iSec * ($PI / 30)))
            $iySecOffset = Int((0.83 * $iNumDist) * Cos($iSec * ($PI / 30)))

            $ixMinOffset = Int((0.85 * $iNumDist) * Sin($iMin * ($PI / 1800)))
            $iyMinOffset = Int((0.85 * $iNumDist) * Cos($iMin * ($PI / 1800)))

            $ixHourOffset = Int((0.65 * $iNumDist) * Sin($iHour * ($PI / 21600)))
            $iyHourOffset = Int((0.65 * $iNumDist) * Cos($iHour * ($PI / 21600)))

            _GDIPlus_GraphicsDrawLine($hClockGraphic, $iOrigin, $iOrigin, $iOrigin + $ixHourOffset, $iOrigin - $iyHourOffset, $hHourPen)
            _GDIPlus_GraphicsDrawLine($hClockGraphic, $iOrigin, $iOrigin, $iOrigin + $ixMinOffset, $iOrigin - $iyMinOffset, $hMinPen)
            _GDIPlus_GraphicsDrawLine($hClockGraphic, $iOrigin, $iOrigin, $iOrigin + $ixSecOffset, $iOrigin - $iySecOffset, $hSecPen)
            _GDIPlus_GraphicsFillEllipse($hClockGraphic, $iOrigin - 3, $iOrigin - 3, 6, 6, $hNoseBrush)

            _GDIPlus_GraphicsDrawImageRect($hGraphic, $hClockBitmap, 0, 0, $iCanvasSz, $iCanvasSz)
        EndIf

    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GDIPlus_BrushDispose($hFrameBrush)
    _GDIPlus_BrushDispose($hNoseBrush)
    _GDIPlus_BrushDispose($hHighlightBrush)
    _GDIPlus_BrushDispose($hFaceBrush)
    _GDIPlus_PenDispose($hSecPen)
    _GDIPlus_PenDispose($hMinPen)
    _GDIPlus_PenDispose($hHourPen)
    _GDIPlus_PenDispose($hBlackPen)
    _GDIPlus_BitmapDispose($hClockBitmap)
    _GDIPlus_GraphicsDispose($hClockGraphic)

    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Clock

Func WM_NCMBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

    $iChSize = $iStartSz
EndFunc   ;==>WM_NCMBUTTONDOWN

Func WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

    Local $iWheelDist, $iRate

    $iRate = 0.25
    $iWheelDist = BitShift($wParam, 16)

    $iChSize -= Int($iRate * $iWheelDist)
    If $iChSize < 120 Then $iChSize = 120
    If $iChSize > $iCanvasSz - (2 * $iMargin) Then $iChSize = $iCanvasSz - (2 * $iMargin)
EndFunc   ;==>WM_MOUSEWHEEL

Func WM_NCHITTEST($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

    Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

 

Edited May 1, 2019 by MattyD

[Earthshine]

that just made me smile. i  think i will run it on my desktop a while. it's great to stare at, like in school, waiting for recess or lunch.. lol, looks good.

Edited May 1, 2019 by Earthshine

[dmob]

Nice one 👍👍

[MattyD]

Thanks Guys

[wolflake]

Digital clocks are ok and compact but there is nothing like and analog clock to let me know I'm late.

Nice job!

[Sidley]

Nice job, I've tried using the trig functions to offset text in GDI but it didn't quite work out. This looks perfect.

[MattyD]

Thanks Sidley

To be fair I did cheat a little bit with the text offset - changing the font size/type face may slightly throw the alignment.

By rights I probably should've used _GDIPlus_GraphicsMeasureString to find the measurements of the bounding box, then calculate an offset off that.

Matt