String Manipulation(scrool)

[Kyme]

Hello Guys

I want to make a scroll text and send it to a lcd, I've managed the connection and be able to display it but i faced the "too much chars to be displayed" problem, so i need to create a function to scroll the text, the problem is that i have no idea how can i get the first char and put it last if the string it's too big and if not then let it as it is
Can anybody give me an idea where can i start?

Thank you

[RTFC]

example

[Melba23]

Kyme,

RTFC took the words from right out of my mouth!

M23

[RTFC]

Truly, I feel blessed today, as for once in my life I was faster than the black double goose-tailed winged dragon-griffon beasty lying in a bowl of red chilli (or whatever it is).

[Melba23]

RTFC,

It is a chimera - in this specific case the badge of one of my previous units.

M23

[Kyme]

2 hours ago, RTFC said:

example

Thank you for fast response
i saw the script prior posting and as i understood it's a gui thing, i need a string format
i have a function that require a string to print it on lcd, can be used marquee to create a same size string as original one but rotating?maybe i've missed something, i could make a function to subtract the max-1 both sides and concatenate them and trim it to @30 chars, but it sounds painful and i guess it's harder then it sounds.
My small project it's to make a lcd app to print song name that's playing on spotify.

Till now i've managed to do the displaying but i want the text to be on 1 line only, and if the title it's longer then to scroll the text.

Edit:

this is what i'm come up to, is there any other more elegant solution, it looks sooo trivial...

$title="Adelitas Way - What It Takes"&"   " ;31
$max=10
while 1
   $title=title($title)
   ConsoleWrite(StringTrimRight($title,Int(StringLen($title))-$max)&@CRLF)
   Sleep(100)

WEnd

Func title($otitle)
   local $o_title=$otitle
   local $size=StringLen($o_title)
   local $char=StringTrimRight($o_title,$size-1)
   local $title_subed=StringTrimLeft($o_title,1)
   $first=StringTrimLeft($o_title,1)
   ;ConsoleWrite($title_subed&$char&@CRLF)
    Return $title_subed&$char
EndFunc

 

Edited April 25, 2019 by Kyme

[jchd]

Try this and adapt:

HotKeySet("{ESC}", _Terminate)

Local $title = "Adelitas Way - What It Takes" & " here more long text, much larger than LCD 24-char display (example)  ...      "
Local $max = 24
Local $str = $title & $title        ; yes, concat two copies of text
Local $i
While 1
    $i += 1
    ConsoleWrite(StringMid($str, Mod($i, StringLen($title)), $max) & @CRLF)
    Sleep(200)
WEnd

Func _Terminate()
    Exit
EndFunc

 

[Gianni]

...rotate a string left or right by a wanted num of chars

expandcollapse popup

#include <GUIConstantsEx.au3>

Local $sString = "I want to make a scroll text and send it to a lcd, I've managed the connection and be able to display it but i faced the ""too much chars to be displayed"" problem " & ChrW(9786) & " " & ChrW(9829) & "  "
Local $iLCD_Len = 24

GUICreate("LCD", 400, 30)
$hLCD = GUICtrlCreateLabel("", 0, 0, 400, 30)
GUICtrlSetFont(-1, 20, 400, 0, "Courier New")
GUICtrlSetBkColor(-1, 0x550000)
GUICtrlSetColor(-1, 0xff0000)
GUISetState()

While 1
    $idMsg = GUIGetMsg()
    Select
        Case $idMsg = $GUI_EVENT_CLOSE
            ExitLoop
    EndSelect
    ControlSetText('', '', $hLCD, StringLeft($sString, $iLCD_Len))

    $sString = _StringRotate($sString, -1)
    Sleep(100)
WEnd

GUIDelete()

; rotate a string by a nr of chars
; negative number rotate left <-- , positive number rotate right -->
Func _StringRotate($sString, $sStep = -1)
    Local $Len = StringLen($sString)
    Local $bROL = $sStep < 0
    $sStep = Mod(Abs($sStep), $Len)
    If $bROL Then
        Return StringRight($sString, $Len - $sStep) & StringLeft($sString, $sStep)
    Else
        Return StringRight($sString, $sStep) & StringLeft($sString, $Len - $sStep)
    EndIf
EndFunc   ;==>_StringRotate

 

Edited April 25, 2019 by Chimp