My ListView inside multiple Tab item is possible ?

[caramen]

Helo peoples

 

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$hGui = GUICreate ("Multiple List", 500 , 550 )
$hTab = GUICtrlCreateTab ( 10 , 10 ,480,530 )
GUICtrlCreateTabItem("1")
$hCheckBox1 = GUICtrlCreateCheckbox ( "$hCheckBox1" , 20 , 50 ,200 , 20)
$Console = GUICtrlCreateListView("-----------Historique-----------", 20 , 230 , 200 , 200 )
_GUICtrlListView_SetColumnWidth ($Console , 0 , 800 )
$hTab2 = GUICtrlCreateTabItem("2")
;GUICtrlSetState($Console,$GUI_SHOW)Failed
GUISetState (@SW_SHOW , $hGui )

While (1)
   Sleep(100)
   $msg = GUIGetMsg ()
      Switch $msg
         Case $GUI_EVENT_CLOSE
            _Exit ()
      EndSwitch
WEnd

Func _Exit ()
   Exit
EndFunc

Is it possible to have :

"$Console" In $hTab & $hTab2 ?

 

Thanks

[Nine]

What would be the purpose of having the exact same Historique ListView in 2 different tabs ?

[caramen]

It s becose I need tabs in my tool. I will have 4-5 tabs. Then dev more tabs later probably.

 

And I am doing a console in each tab to trace what's going on.

Then if i add a line in the console like

_GUICtrlListView_AddItem($Console,"|"&$kO&"/"&$gB&"|Copied|Failed|"&repOfTheFile )

I would like to have the line in all console, I know whitch tab made the item becose of the tag "Copied" and if an other tab is adding item:

_GUICtrlListView_AddItem($Console,"|"&$kO&"/"&$gB&"|Moved|Failed|"&repOfTheFile )

Again an other tag and I would like to see it also in all console.

(And the purpose is becose : )

I mean actually if i add a tab. and If i want to log everything. I have to add $Console(Number) In each precedent finished Tab. I would like to dodge this. I dont want to go back in my code again.

_GUICtrlListView_AddItem($Console,"|"&$kO&"/"&$gB&"|Moved|Failed|"&repOfTheFile )
;NewTab made So i have to add this in all tab
_GUICtrlListView_AddItem($Console1,"|"&$kO&"/"&$gB&"|Moved|Failed|"&repOfTheFile )
;NewTab made So i have to add this in all tab
_GUICtrlListView_AddItem($Console2,"|"&$kO&"/"&$gB&"|Moved|Failed|"&repOfTheFile )

 

Edited March 23, 2019 by caramen

[BrewManNH]

You can only have a control in one tab at a time, but there's nothing stopping you from creating duplicates of that control for the other tabs, and updating them all at the same time.

[caramen]

12 minutes ago, BrewManNH said:

You can only have a control in one tab at a time, but there's nothing stopping you from creating duplicates of that control for the other tabs, and updating them all at the same time.

I tryed that before asking. @BrewManNH

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$kO=0
$gB=0
$repOfTheFile="C:/"

$hGui = GUICreate ("Multiple List", 500 , 550 )
$hTab = GUICtrlCreateTab ( 10 , 10 ,480,530 )
GUICtrlCreateTabItem("1")
$hCheckBox1 = GUICtrlCreateCheckbox ( "$hCheckBox1" , 20 , 50 ,200 , 20)
$Console = GUICtrlCreateListView("-----------Historique-----------", 20 , 230 , 200 , 200 )
_GUICtrlListView_SetColumnWidth ($Console , 0 , 800 )
$hTab2 = GUICtrlCreateTabItem("2")
$hCheckBox2 = GUICtrlCreateCheckbox ( "$hCheckBox2" , 20 , 50 ,200 , 20)
$Console = GUICtrlCreateListView("-----------Historique-----------", 20 , 230 , 200 , 200 )
GUISetState (@SW_SHOW , $hGui )

While (1)
   Sleep(100)
   $iCheck = _IsChecked ($hCheckBox1)
   $iCheck2 = _IsChecked ($hCheckBox2)
      If $iCheck = True Or $iCheck2 = True Then
         _un ()
         _deux ()
         ;_Debug ()
      EndIf
   $msg = GUIGetMsg ()
      Switch $msg
         Case $GUI_EVENT_CLOSE
            _Exit ()
      EndSwitch
WEnd

Func _un ()
   If $iCheck = True Then
      _GUICtrlListView_AddItem($Console,"|"&$kO&"/"&$gB&"|Copied|Failed|"&$repOfTheFile )
      GUICtrlSetState($hCheckBox1,$GUI_UNCHECKED)
   EndIf
EndFunc

Func _deux ()
   If $iCheck2 = True Then
      _GUICtrlListView_AddItem($Console,"|"&$kO&"/"&$gB&"|Moved|Failed|"&$repOfTheFile )
      GUICtrlSetState($hCheckBox2,$GUI_UNCHECKED)
   EndIf
EndFunc

Func _Exit ()
   Exit
EndFunc

Func _IsChecked($idControlID)
    Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

Only tab two updated.

Edited March 23, 2019 by caramen

[Nine]

57 minutes ago, caramen said:

I would like to dodge this. I dont want to go back in my code again.

You can't dodge it.  But you can make it so you don't have to go back in your code if you add a new tab.  So instead of naming your consoles $Console1, $Console2, $Console3, etc.  Simply put them into an array of consoles.  Create a single function that will update all the consoles based on the ubound of the array.

[caramen]

Ohhhh good idea! Thanks!

[mikell]

Why such a complication ? wouldn't something like this be *much* easier ?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$kO=0
$gB=0
$repOfTheFile="C:/"

$hGui = GUICreate ("Multiple List", 500 , 550 )
$hTab = GUICtrlCreateTab ( 10 , 10 ,480, 200 )
GUICtrlCreateTabItem("1")
$hCheckBox1 = GUICtrlCreateCheckbox ( "$hCheckBox1" , 20 , 50 ,200 , 20)
$hTab2 = GUICtrlCreateTabItem("2")
$hCheckBox2 = GUICtrlCreateCheckbox ( "$hCheckBox2" , 20 , 50 ,200 , 20)
GUICtrlCreateTabItem("")
$Console = GUICtrlCreateListView("-----------Historique-----------", 20 , 230 , 200 , 200 )
GUISetState (@SW_SHOW , $hGui )

While (1)
   Sleep(10)
   $msg = GUIGetMsg()
      Switch $msg
         Case $hCheckBox1
              If _IsChecked ($hCheckBox1) Then _un ()
         Case $hCheckBox2
              If _IsChecked ($hCheckBox2) Then _deux ()
         Case $GUI_EVENT_CLOSE
            _Exit ()
      EndSwitch
WEnd

Func _un ()
      _GUICtrlListView_AddItem($Console,"|"&$kO&"/"&$gB&"|Copied|Failed|"&$repOfTheFile )
      GUICtrlSetState($hCheckBox1,$GUI_UNCHECKED)
EndFunc

Func _deux ()
      _GUICtrlListView_AddItem($Console,"|"&$kO&"/"&$gB&"|Moved|Failed|"&$repOfTheFile )
      GUICtrlSetState($hCheckBox2,$GUI_UNCHECKED)
EndFunc

Func _Exit ()
   Exit
EndFunc

Func _IsChecked($idControlID)
    Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

 

[caramen]

@mikell Thanks for suggestion it was reproducer