zPlayer - My own little audio/video player

[CYCho]

Under the current setup, you will have to drag the video window to the 2nd monitor manually. You can try to let the video start in the 2nd monitor automatically by changing the left of $videoGUI to the @DesktopWidth of the tablet at its creation time. I didn't test this and I will be interested in knowing how it performs.
 

Global $videoGUI = GUICreate("zPlayer Video Control", $videoWidth, $videoHeight, @DesktopWidth, -1, $WS_OVERLAPPEDWINDOW)

 

[carlvanwormer]

OK. I'll try some variations tonight.  The system works as expected, and with your changes as a functional starting point I'll be doing minor hack/tweaks to optimize it after my tablet arrives.  I'll let you know if I have success with the auto-positioning.

Thanks,
Carl

 

[carlvanwormer]

What video player is being used by the program?  The VLC player has settings that can control screen modes and monitor choices.

[CYCho]

zPlayer uses Windows Media Player embedded in Internet Explorer. Take a look at Func MyWMPlayer() at the end of the code. You wanted to have a bare-bone video player and this is what it is. You can add other functions if you want to.

I tested automatic display of video window in the 2nd monitor and it worked perfectly. Of course, the 2nd monitor must be set as an extension for this to work.

[carlvanwormer]

OK, I think you've given me all the pieces I need to work with over the next week.  I'll report the results of my hack/mods as I polish the code framework.  Thanks for your great contribution to my dad's new home entertainment system.

[carlvanwormer]

That check is good (and it works).  

The Monk videos I have contain the English audio on track 2 and the English captions on the second channel.  I've been unable to get WMP to show me the subtitles, but they are visible in the VLC player.  Is there any way for me to substitute the VLC player for the call to WMP?

My tablet is supposed to be here next Monday (instead of today, as promised), so I've been tweaking button sizes to make the exit button much smaller (and harder to  accidently hit).

 

Later,

Carl

[CYCho]

I have no experience with VLC. You could probably control VLC through generic Send("{MEDIA_*}") keys.

For Windows Media Player, you may be able to solve the problems with plugins, but my experience is limited to local subtitle plugin, which worked OK. I'm sorry I can't help you further. Unfortunately I don't have a file with 2nd track and 2nd channel, so I'm undable to do a study.

Edited August 19, 2021 by CYCho

[Earthshine]

Vlc has an api so it’s probably possible. VLC has excellent subtitle support unlike most crap windows players

Edited August 19, 2021 by Earthshine

[carlvanwormer]

My initial searches for how to start experiments with the send media keys was unsuccessful.  I was unable to locate the starting point as how to invoke the media player so I could send keys/commands to it.  Are there some search terms that would help me to find that starting point?  

Thanks,
Carl

[CYCho]

Below is a quick and dirty version that uses VLC. Please give it a try.
 

expandcollapse popup

; File name: zPlayer-VLC.au3
#include <File.au3>
#include <Array.au3>
#include <GuiConstants.au3>

Opt("WinTitleMatchMode", 2)

HotKeySet("^!{END}", "MyExit")

$vlcPath = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\vlc.exe", "")
If $vlcPath = "" Then Exit MsgBox(0, "", "VLC is not installed!")

Global $fileTypes = "mp4 wmv avi mkv flv webM"
Global $aList, $guiMsg, $lPaused

;If Not FileExists(@ScriptDir & "\VLC-Playlist.txt") Then
    $aList = _FileListToArrayRec(@ScriptDir, StringReplace("*." & $fileTypes, " ", ";*."), 1, 0, 0, 2)
    If Not IsArray($aList) Then
        MsgBox(0, "", "This program should reside in the driectory where video files are located.")
        Exit
    EndIf

    Global $playList = ''
    $playList &= '<?xml version="1.0" encoding="UTF-8"?>' & @CR
    $playList &= '<playlist xmlns="http://xspf.org/ns/0/" xmlns:vlc="http://www.videolan.org/vlc/playlist/ns/0/" version="1">' & @CR
    $playList &= @TAB & '<title>Playlist</title>' & @CR
    $playList &= @TAB & '<trackList>' & @CR
    For $i = 1 To $aList[0]
        $playList &= @TAB & @TAB & '<track>' & @CR
        $playList &= @TAB & @TAB & @TAB & '<location>file:///' & URLEncode($aList[$i]) & '</location>' & @CR
        $playList &= @TAB & @TAB & @TAB & '<extension application="http://www.videolan.org/vlc/playlist/0">' & @CR
        $playList &= @TAB & @TAB & @TAB & @TAB & '<vlc:id>' & $i-1 & '</vlc:id>' & @CR
        $playList &= @TAB & @TAB & @TAB & @TAB & '<vlc:option>file-caching=1000</vlc:option>' & @CR
        $playList &= @TAB & @TAB & @TAB & '</extension>' & @CR
        $playList &= @TAB & @TAB & '</track>' & @CR
    Next
    $playList &= @TAB & '</trackList>' & @CR
    $playList &= @TAB & '<extension application="http://www.videolan.org/vlc/playlist/0">' & @CR
    For $i = 1 To $aList[0]
        $playList &= @TAB & @TAB & '<vlc:item tid="' & $i-1 & '"/>' & @CR
    Next
    $playList &= @TAB & '</extension>' & @CR
    $playList &= '</playlist>' & @CR

    $fh = FileOpen(@ScriptDir & "\VLC-Playlist.xspf", 2)
    FileWrite($fh, $playList)
    FileClose($fh)
;EndIf

Global $vcWidth = 600, $shuttleWidth = 24, $sliderLength = $vcWidth-$shuttleWidth, $vcHeight = 565
Global $vcGUI = GUICreate("zPlayer_Carl by C Y Cho", $vcWidth, $vcHeight, -1, -1)
Global $vcPause = GUICtrlCreateButton("Pause", 5, 0, $vcWidth-10, 400)
GUICtrlSetFont(-1, 100, 900)
GUICtrlSetColor(-1, 0x666666)
GUICtrlSetCursor(-1, 0)
Global $vcPrevious = GUICtrlCreateButton("Previous", 5, 400, 355, 80)
GUICtrlSetFont(-1, 40, 900)
GUICtrlSetColor(-1, 0x666666)
GUICtrlSetCursor(-1, 0)
Global $vcNext = GUICtrlCreateButton("Next", 360, 400, 235, 80)
GUICtrlSetFont(-1, 40, 900)
GUICtrlSetColor(-1, 0x666666)
GUICtrlSetCursor(-1, 0)
Global $vcExit = GUICtrlCreateButton("Exit", 5, 480, 590, 80)
GUICtrlSetFont(-1, 40, 900)
GUICtrlSetColor(-1, 0x666666)
GUICtrlSetCursor(-1, 0)
GUISetState(@SW_SHOW, $vcGUI)
WinSetOnTop($vcGUI, "", 1)

Run($vlcPath & " " & @ScriptDir & "\VLC-Playlist.xspf")
Sleep(1000)
$hWnd = WinGetHandle("[CLASS:Qt5QWindowIcon]", "VLC")   ; Please check if your VLC window class matches with this
;WinMove($hWnd, "", @DesktopWidth, 0)   ; This line should be uncommented when using dual monitors
WinSetState($hWnd, "", @SW_MAXIMIZE)

While 1
    $guiMsg = GUIGetMsg()
    Switch $guiMsg
        Case $vcNext
            WinActivate($hWnd)
            Send("{MEDIA_NEXT}")
            If $lPaused = True Then
                GUICtrlSetData($vcPause, "Pause")
                $lPaused = False
            EndIf
        Case $vcPrevious
            WinActivate($hWnd)
            Send("{MEDIA_PREV}")
            If $lPaused = True Then
                GUICtrlSetData($vcPause, "Pause")
                $lPaused = False
            EndIf
        Case $vcPause
            WinActivate($hWnd)
            If $lPaused = False Then
                GUICtrlSetData($vcPause, "Play")
                $lPaused = True
            Else
                GUICtrlSetData($vcPause, "Pause")
                $lPaused = False
            EndIf
            Send("{MEDIA_PLAY_PAUSE}")
        Case $vcExit, $GUI_EVENT_CLOSE
            MyExit()
    EndSwitch
    If Not WinExists($hWnd) Then MyExit()
WEnd

Func URLEncode($sFileName)
    Local $sBinary = StringToBinary($sFileName, 4)
    Local $sEncodedName = ""
    For $j = 1 To BinaryLen($sBinary)
        Local $sByte = StringTrimLeft(BinaryMid($sBinary, $j, 1), 2)
        Local $ascii = Dec($sByte)
        If ($ascii >= 48 And $ascii <= 57) Or ($ascii >= 65 And $ascii <= 90) Or ($ascii >= 97 And $ascii <= 122) _
            Or StringInStr("45 46 58 91 93 95", StringRight(1000+$ascii, 2)) Then
            $sEncodedName &= Chr($ascii)
        ElseIf $ascii = 92 Then
            $sEncodedName &= "/"
        Else
            $sEncodedName &= "%" & $sByte
        EndIf
    Next
    Return $sEncodedName
EndFunc

Func MyExit()
    ProcessClose("vlc.exe")
    Exit
EndFunc

 

Edited August 20, 2021 by CYCho

[carlvanwormer]

This doesn't seem to do anything in stand-alone mode.  Do I need to splice it into my current code?  I'll be out for the rest of the evening and will check back tomorrow.

 

Thanks,
Carl

 

[CYCho]

1 hour ago, carlvanwormer said:

This doesn't seem to do anything in stand-alone mode

I don't quite get what you mean. Did you save this code in an au3 file (any name other than vlc.au3), for example, zPlayer-VLC.au3 in the media file directory, compile it and run? Of course, the VLC must have been installed in that computer.

Please look through the code and raise any question. You will note that the code first makes an xml playlist and plays that playlist instead of individual media files. So, in your case, the directory had better not contain any video files other than Monk. Please bear in mind that the playlist will contain the file names in alphabetical order, and you may have to change the file names to keep the playing order as intended.

You will also note that the file names in the playlist are encoded to UTF-8 as VLC requires, and so they should work OK with unicode characters.

I hope this works for you.

Edited August 20, 2021 by CYCho

[carlvanwormer]

I pasted the code into a new SciTE file, but I didn't save it out.  I hit the F5 key and nothing happened, so I figured something was broken in the file.  After reading your question, I made a new file, pasted the text into it, and then saved it out with an arbitrary filename.  After that process, I hit the F5 again and got VLC errors"

Your input can't be opened:

VLC is unable to open the MRL 'file:///C:/Users/Carl/Documents/AutoIt/Monk'. Check the log for details.

Your input can't be opened:

VLC is unable to open the MRL 'file:///C:/Users/Carl/Documents/AutoIt/Monk%20Season%201/Season'. Check the log for details.

Your input can't be opened:

VLC is unable to open the MRL 'file:///C:/Users/Carl/Documents/AutoIt/Monk%20Season%201/1/VLC-Playlist.xspf'. Check the log for details.

 

I will check the log tomorrow morning to see what other things I can do.  You've worked hard today . . . you can take the rest of the day off  . . .

 

It looks like AutoIt doesn't accept the F5 key (Go) until after the file is saved with a filename.  I tested this with a blank file - File/New, then hit F5 - nothing happened.  File/Save (give arbitrary filename) then F5 performs the Go action on the empty (but named) file.

Thanks for all the help,
Carl

 

[CYCho]

@carlvanwormer, Please upload the contents of VLC-Playlist.xspf. The error log looks very strange.

[carlvanwormer]

I found that I could make it work if I changed my folder structure to remove spaces.  I set out to "fix" the problem by changing the line:

$fh = FileOpen(@ScriptDir & "\VLC-Playlist.xspf", 2)

to 

$newstring = '"' & @ScriptDir & "\VLC-Playlist.xspf" & '"'
    $fh = FileOpen($newstring, 2)
    ConsoleWrite  (" $newstring is " )
    ConsoleWrite  ($newstring)
    ConsoleWrite  (" $newstring" )

when I run this code I still get the same error results, and the console window shows the quoted string as sent to the system:

 $newstring is "C:\Users\Carl\Documents\AutoIt\Monk Season 1\VLC-Playlist.xspf" $newstring

When I copy this quoted string to the windows console (with or without quotes), it runs the video file.

I've attached the playlists from the working (no spaces) and non-working (spaces) runs (removed spaces from folder path).

It looks like the VLC program doesn't cope with spaces very well.

 

I can solve the problem by making my directory structure (and probably my filenames) without any spaces.

Aside from that problem, your VLC implementation works well.  I cannot fully express my gratitude for the help you have given me.  I will try to pay it forward.

Thanks!

Carl

 

VLC-Playlist.xspf VLC-Playlist.xspf

[carlvanwormer]

I added some variables for defining the button sizes and locations to allow for quick modification when my tablet arrives next week.  Things seem to be working well with VLC player mods you made.  I found that I could manually run VLC from its install folder, selecting the language and captioning channels and they would stick for subsequent defaults. 

I've attached my updated code for your viewing pleasure.

As I was working out the details, I found that the "file location memory" capability of the original program was no longer available.  The zPlayer.ini file is not referenced in the new code version.  I've spent some time trying to hack that function into the new code from the old system, but I've been unsuccessful.  Do you have any suggestions as to the minimum "necessary and sufficient" items from the old code that need to be added to allow the program to restart where it left off from the previous run?

 

Thanks,
Carl

 

BigPause-10.au3

[CYCho]

 

16 hours ago, carlvanwormer said:

to allow the program to restart where it left off from the previous run

During the relatively short time after my last post I looked into that possibility. Since I am new to VLC and I am not using API commands, what I could do was very much limited. One thing I tried for returning to the previous file was to change the order of files in playlist believing that VLC would start playing the first file first. But my belief was betrayed by VLC with its default xspf playlist. Just by a sheer luck I found that an m3u playlist did the trick. What i did was to rearrange the playlist at Exit time so that the current file comes on the top. Please try the code below. Returning to the exact timeline is a task which cannot be achieved without going into API level of VLC.

BigPause-10-m3u.au3

Edited August 22, 2021 by CYCho

[carlvanwormer]

WOW!  That worked as expected.  I was going to upload my latest failure that "almost worked" (except I didn't know how to correctly parse the VLC file), but your working file was waiting for me.  I'll pound on it tomorrow to see if I can break anything else, and then I'll probably be able to run it on the tablet on Tuesday.  I really appreciate the time you've invested in helping me.  Contact me if you ever need any electronics troubleshooting help.

Thanks,

Carl

 

[carlvanwormer]

I found an interesting quirk, but it is something I can get around.  After a computer reboot (current win-10 system) I can run the script, but it always exits.  If I manually run VLC and then exit vlc before running the script I get the expected script behavior.  In tracing the reason, I was following the mainloop code and found that the code was taking the exit the first time through the loop because of the "if not winexists($hwnd) at the end of the loop.  

I added a loop at the definition of $hWnd:
Run($vlcPath & " " & @ScriptDir & "\VLC-Playlist.m3u")
for $x=1 to 10
Sleep(1000)
$hWnd = WinGetHandle("[CLASS:Qt5QWindowIcon]", "VLC")  ; Please check if your VLC window class matches with this
ConsoleWrite (" Counting - " & $x & " " & $hWnd )
if $hWnd  <> 0x00000000 then ExitLoop
Next

first run after reboot I got:
Counting - 1 0x00000000 Counting - 2 0x00000000 Counting - 3 0x00000000 Counting - 4 0x00000000 Counting - 5 0x00000000 Counting - 6 0x00000000 Counting - 7 0x00000000 Counting - 8 0x00000000 Counting - 9 0x00000000 Counting - 10 0x00000000 
and the script exited.

After the second run, I got:
Counting - 1 0x0001098C 
and the scrip ran perfectly.

I see your comment about checking my vlc window class, and the summary of that window info is:

>>>> Window <<<<
Title:    8x01 La serie favorita del Sr. Monk - VLC media player
Class:    Qt5QWindowIcon
Position:    203, 58
Size:    1137, 741
Style:    0x96CF0000
ExStyle:    0x00000100
Handle:    0x0000000000020970

>>>> Control <<<<
Class:    VLC video output 000001EA20BE85D0
Instance:    1
ClassnameNN:    VLC video output 000001EA20BE85D01
Name:    
Advanced (Class):    [CLASS:VLC video output 000001EA20BE85D0; INSTANCE:1]
ID:    
Text:    
Position:    1, 21
Size:    1118, 629
ControlClick Coords:    589, 142
Style:    0x50000000
ExStyle:    0x00000000
Handle:    0x0000000000040926

>>>> Visible Text <<<<
QWidgetClassWindow
ControlsWidgetClassWindow
InputControlsWidgetClassWindow
QStackedWidgetClassWindow
VideoWidgetClassWindow
QWidgetClassWindow
VLC (Direct3D11 output)
QMenuBarClassWindow

>>>> Hidden Text <<<<
QStatusBarClassWindow
BackgroundWidgetClassWindow
QWidgetClassWindow

There is something going on here, but I don't know enough to fix it.

thanks,
Carl
 

[CYCho]

It seems that the computer somehow fails to load either VLC.exe or the playlist. Maybe Sleep(1000) after the Run command is too short. You can try this code and find the optimum sleep time.
 

Global $pid, $seconds
While 1
    $pid = Run($vlcPath & " " & @ScriptDir & "\VLC-Playlist.m3u")
    $seconds += 1
    Sleep($seconds * 1000)
    If $pid <> "" Then
        MsgBox(0, "", "It took " & $seconds & " seconds to run VLC.exe", 0, $vcGUI)
        ExitLoop
    EndIf
    If $seconds > 10 Then Exit MsgBox(0, "", "VLC.exe could not be run.")
WEnd

 

Edited August 22, 2021 by CYCho