Close multiple processes in Array

[RestrictedUser]

Hello AutoIt Scriptwriters❤️👋

I had searched many times about this topic's title but i didn't found any useful information to solve my question

I want to close multiple processes in one string by Array

I want to be similar to this:

_Process()

Func _Process()

While 1

$iPID = ("notepad.exe", "word.exe", "firefox.exe", "chrome.exe")

If ProcessExists($iPID) Then

ProcessClose($iPID)

Else

MsgBox(64, "", "Favorite processes aren't exist")

ExitLoop

WEnd

Exit

EndFunc

Edited March 12, 2019 by Colduction

[FrancescoDiMuro]

@Colduction

Global $arrProcess[4] = ["notepad.exe", "word.exe", "firefox.exe", "chrome.exe"]

For $i = 0 To UBound($arrProcess) - 1 Step 1
    If ProcessExists($arrProcess[$i]) Then
        ConsoleWrite("Closing process '" & $arrProcess[$i] & "'" & @CRLF)
        If ProcessClose($arrProcess[$i]) Then
            ConsoleWrite("Process closed." & @CRLF)
        Else
            ConsoleWrite("Cannot close the process." & @CRLF)
        EndIf
    Else
        ConsoleWrite("The process '" & $arrProcess[$i] & "' doesn't exist." & @CRLF)
    EndIf
Next

You can find more about arrays here, and, youo don't need to make all those loops.

[Subz]

Slightly modified version, to close all instances:

Global $aProcess
Global $arrProcess[4] = ["notepad.exe", "word.exe", "firefox.exe", "chrome.exe"]

For $i = 0 To UBound($arrProcess) - 1 Step 1
    If ProcessExists($arrProcess[$i]) Then
        ConsoleWrite('Closing process "' & $arrProcess[$i] & '"' & @CRLF)
        $aProcess = ProcessList($arrProcess[$i])
        For $j = 1 To $aProcess[0][0]
            If ProcessClose($aProcess[$j][1]) Then
                ConsoleWrite(" - Instance: " & $j & " closed." & @CRLF)
            Else
                ConsoleWrite(" - Instance: " & $j & " cannot be closed." & @CRLF)
            EndIf
        Next
    Else
        ConsoleWrite('The process "' & $arrProcess[$i] & '"' & " doesn't exist." & @CRLF)
    EndIf
Next

 

Edited March 12, 2019 by Subz

[RestrictedUser]

2 hours ago, FrancescoDiMuro said:

don't need to make all those loops

Thanks for answering to my Question👍❤️

 

But infinite loop needed!, because i want check if that process exists, then close that! 

[RestrictedUser]

1 hour ago, Subz said:

Slightly modified version, to close all instances:

Global $aProcess
Global $arrProcess[4] = ["notepad.exe", "word.exe", "firefox.exe", "chrome.exe"]

For $i = 0 To UBound($arrProcess) - 1 Step 1
    If ProcessExists($arrProcess[$i]) Then
        ConsoleWrite('Closing process "' & $arrProcess[$i] & '"' & @CRLF)
        $aProcess = ProcessList($arrProcess[$i])
        For $j = 1 To $aProcess[0][0]
            If ProcessClose($aProcess[$j][1]) Then
                ConsoleWrite(" - Instance: " & $j & " closed." & @CRLF)
            Else
                ConsoleWrite(" - Instance: " & $j & " cannot be closed." & @CRLF)
            EndIf
        Next
    Else
        ConsoleWrite('The process "' & $arrProcess[$i] & '"' & " doesn't exist." & @CRLF)
    EndIf
    $iInstance = 1
Next

 

Thanks bro❤️

[RestrictedUser]

2 hours ago, FrancescoDiMuro said:

You can find more about arrays here

Thanks for helping!❤️❤️

[FrancescoDiMuro]

@Colduction

You're welcome