Sort a 2D array on column with Numbers

[myspacee]

Hello,
I try to automate ranking sort. Usually my classifications have votes at the end of line, eg:

Bat - 0
Bear - 3
Red Fox - 2
Fox - 1
Lion - 4
Cat - 1
Armadillo - 3
Monkey - 10

 my users want to order it and obtain

Monkey - 10
Lion - 4
Armadillo - 3
Bear - 3
Red Fox - 2
Cat - 1
Fox - 1
Bat - 0

You can notice, that list is double sorted :
- before numeric column
-  then rows with same vote (eg: cat -> fox)

I assemble some code :

#include <Array.au3>
#include<array.au3>
#include<file.au3>

Local $aArray_Base[0][2]

$file = FileOpen(@DesktopDir & '\animals.txt', 0)

While 1
   $line = FileReadLine($file)
   If @error = -1 Then ExitLoop

   $line_number = StringRegExp($line, '\d+', 1)

   if @error then
      $sFill = "" & "|" & $line
      _ArrayAdd($aArray_Base, $sFill)
   else
      $sFill = Number($line_number[0]) & "|" & $line
      _ArrayAdd($aArray_Base, $sFill)
   endif

WEnd
FileClose($file)

_ArrayDisplay($aArray_Base, "$avArray BEFORE _ArraySort()")
_ArraySort($aArray_Base, 0, 0, 0, 0)
_ArrayDisplay($aArray_Base, "$avArray AFTER _ArraySort() ascending column 0")
_ArraySort($aArray_Base, 0, 0, 0, 1)
_ArrayDisplay($aArray_Base, "$avArray AFTER _ArraySort() ascending column 1")
_ArraySort($aArray_Base, 0, 0, 0, 2)
_ArrayDisplay($aArray_Base, "$avArray AFTER _ArraySort() ascending column 2")

But I can't understand how use _arraysort...

Can you help me, please ?

thank you,
m.
 

Edited March 7, 2019 by myspacee

[Nine]

Try this : 

#include <File.au3>
#include <Array.au3>

Opt ("MustDeclareVars", 1)

Local $array
_FileReadToArray ("animals.txt", $array, $FRTA_ENTIRESPLIT, " - ")
For $i = 0 to UBound ($array)-1
  $array[$i][1]=Number($array[$i][1])
Next
_ArraySort ($array, 0, 0, 0, 1)

Local $value = $array[0][1], $start = 0
For $i = 1 to UBound ($array)-1
  if $value = $array[$i][1] then ContinueLoop
  $value = $array[$i][1]
  if $i - $start > 1 then _ArraySort ($array, 0, $start, $i-1, 0)
  $start = $i
Next
if UBound ($array) - $start > 1 then _ArraySort ($array, 0, $start, Ubound($array)-1, 0)

_ArrayDisplay ($array)

 

Edited March 7, 2019 by Nine

[myspacee]

Adapt to my case :

expandcollapse popup

#include <Array.au3>
#include<file.au3>

Local $Array[0][2]

$file = FileOpen(@DesktopDir & '\animals.txt', 0)

While 1
   $line = FileReadLine($file)
   If @error = -1 Then ExitLoop

   $line_number = StringRegExp($line, '\d+', 1)

   if @error then
      $sFill =  $line & "|" & ""
      _ArrayAdd($Array, $sFill)
   else
      $sFill = $line & "|" & Number(StringRegExpReplace($line_number[0], "[^0-9]", ""))
      _ArrayAdd($Array, $sFill)
   endif

WEnd
FileClose($file)


For $i = 0 to UBound ($array)-1
  $array[$i][1]=Number($array[$i][1])
Next
_ArraySort ($array, 1, 0, 0, 1)

Local $value = $array[0][1], $start = 0
For $i = 1 to UBound ($array)-1
  if $value = $array[$i][1] then ContinueLoop
  $value = $array[$i][1]
  if $i - $start > 1 then _ArraySort ($array, 0, $start, $i-1, 0)
  $start = $i
Next
if UBound ($array) - $start > 1 then _ArraySort ($array, 1, $start, Ubound($array)-1, 0)
_ArraySort ($array, 1, $start, Ubound($array)-1, 0)
_ArrayDisplay ($array)

Thank you!

m.

[Nine]

@myspacee  Why are you not using FileReadToArray ? And why are sorting 2 times at the end ? 

Edited March 7, 2019 by Nine

[myspacee]

hello, I need this script as part of onother one. Bigger and with its 'structure'.
My fault double sort at end. Thank you again, your solution is more simple than others i try.

m.
 

Edited March 7, 2019 by myspacee

[iamtheky]

yall are wild

#include<array.au3>

local $a[8][2] = [['Bat' , 0],['Bear' , 3],['Red Fox' , 2],['Fox' , 1],['Lion' , 4],['Cat' , 1],['Armadillo' , 3],['Monkey' , 10]]
_ArraySort($a , 0 , 0 , 0 , 0 , 1)
_ArraySort($a , 1 , 0 , 0 , 1)
_ArrayDisplay($a)

 

[Nine]

1 hour ago, iamtheky said:

yall are wild

Have you even test your code ? -1 if I could...

[iamtheky]

 

 

 

Edited March 8, 2019 by iamtheky
..i.,

[Melba23]

myspacee,

You could also use my ArrayMultiColSort UDF (the link is in my sig):

#include<ArrayMultiColSort.au3>

Local $aList[8][2] = [['Bat' , 0],['Bear' , 3],['Red Fox' , 2],['Fox' , 1],['Lion' , 4],['Cat' , 1],['Armadillo' , 3],['Monkey' , 10]]

; Set sort order = First col 1 descending, second col 0 ascending
Local $aSortData[2][2] = [[1, 1], [0, 0]]

_ArrayMultiColSort($aList, $aSortData)

_ArrayDisplay($aList, "", Default, 8)

M23