Variable is object and is not object

[maniootek]

I have very weird problem. Please check the screenshot:

I am working on some object stored in variable called $oSubiekt. I perform some method on it with invaild values for test. Afther the method is called I receive the result stored in variable called $oProforma. Now, when I use VarGetType() function on the new variable $oProforma I receive result "Object" but IsObj() function return "0". So variable is object data type but in fact it is not object?

Moreover, in this case my Com Error Handler does not catch the error. It says "The requested action with this object has failed."

Is it normal?

Edited: Is it possible to catch this kind of error by error handler?

Edited February 28, 2019 by maniootek

[BrewManNH]

Where's your script? You've been here long enough to know that no one is going to be able to answer your question because you didn't post a script demonstrating the issue. Also, don't post screenshots of scripts, post the script.

 

[water]

Usually methods or properties are written in English. If this is true I sugest to try:

$oSubiekt.Identificator

BTW: Can you please post the code for the COM error handler you use?

[maniootek]

 

16 hours ago, BrewManNH said:

Where's your script? You've been here long enough to know that no one is going to be able to answer your question because you didn't post a script demonstrating the issue. Also, don't post screenshots of scripts, post the script.

I didn't post the code because you will not be able to test it on your side as it require to install some app to make this object work. I assumed that my screenshot is enough to show the problem. Anyway, this is the reproduced code:

Example()
Func Example()
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
    Local $oInsertGT = ObjCreate("Insert.GT")
    $oInsertGT.Produkt = 1 ;1 = subiekt
    $oInsertGT.Wczytaj("C:\ProgramData\InsERT\InsERT GT\Subiekt.xml")
    Local $oSubiekt = $oInsertGT.Uruchom(0, 0)
    ConsoleWrite("VarGetType($oSubiekt)=" & VarGetType($oSubiekt) & ", IsObj($oSubiekt)=" & IsObj($oSubiekt) & @CRLF)
    Local $oProforma = $oSubiekt.Dokumenty.Wczytaj("this string suppose to be valid document number")
    ConsoleWrite("VarGetType($oProforma)=" & VarGetType($oProforma) & ", IsObj($oProforma)=" & IsObj($oProforma) & @CRLF)
    Local $oErrorHandlerTest
    $oErrorHandlerTest.Test ;Com error called with success (msgbox appeared with scripline number)
    $oProforma.Identyfikator  ;Com error called with no success (msgbox with scriptline number not appeared)
EndFunc   ;==>Example

Func _ErrFunc($oError)
    MsgBox(16, @ScriptName, "COM ERROR OCCURED! Check script line number " & $oError.ScriptLine)
EndFunc   ;==>_ErrFunc

and console output:

Quote

... 
--> Press Ctrl+Alt+Break to Restart or Ctrl+Break to Stop
VarGetType($oSubiekt)=Object, IsObj($oSubiekt)=1
VarGetType($oProforma)=Object, IsObj($oProforma)=0
"C:\Example" (13) : ==> The requested action with this object has failed.:
$oProforma.Identyfikator
$oProforma^ ERROR
->12:14:18 AutoIt3.exe ended.rc:1
+>12:14:18 AutoIt3Wrapper Finished.
>Exit code: 1    Time: 1.798

 

12 hours ago, water said:

Usually methods or properties are written in English.

In my case, all methods are called in my local polish language (this is how author of this app designed it) and they are correct.

By the way, I found a solution to avoid this script breaking by checking if variable is object with IsObj() function. Now I am just curious why error handler does not catch this kind of error.

[water]

Maybe because the ErrorHandler is blocked by MsgBox.
Could you please try:

Func _ErrFunc($oError)
    ConsoleWrite("COM ERROR OCCURED! Check script line number " & $oError.ScriptLine & @CRLF)
EndFunc   ;==>_ErrFunc

 

[mLipok]

15 minutes ago, water said:

Maybe because the ErrorHandler is blocked by MsgBox.

 

I do not think so :

29 minutes ago, maniootek said:

$oProforma.Identyfikator  ;Com error called with no success (msgbox with scriptline number not appeared)

@maniootek  try this code:

.......
    ConsoleWrite("! VarGetType($oProforma) = " & VarGetType($oProforma) & @CRLF)
    ConsoleWrite("! ObjName($oProforma)=" & ObjName($oProforma) & @CRLF)
    $oProforma.Identyfikator  ;Com error called with no success (msgbox with scriptline number not appeared)
EndFunc   ;==>Example

What did you get in Console?

[water]

How does he know that it doesn’t get called as the only statement is the MsgBox?

[maniootek]

MsgBox() function in the error handler function has nothing to do with the problem I guess.

56 minutes ago, water said:

Maybe because the ErrorHandler is blocked by MsgBox.
Could you please try:

Func _ErrFunc($oError)
    ConsoleWrite("COM ERROR OCCURED! Check script line number " & $oError.ScriptLine & @CRLF)
EndFunc   ;==>_ErrFunc

 

Result is the same as before. Here is the console output:

Quote

...

--> Press Ctrl+Alt+Break to Restart or Ctrl+Break to Stop
VarGetType($oSubiekt)=Object, IsObj($oSubiekt)=1
VarGetType($oProforma)=Object, IsObj($oProforma)=0
COM ERROR OCCURED! Check script line number 12
"C:\Example.au3" (13) : ==> The requested action with this object has failed.:
$oProforma.Identyfikator
$oProforma^ ERROR
->13:28:50 AutoIt3.exe ended.rc:1
+>13:28:50 AutoIt3Wrapper Finished.
>Exit code: 1    Time: 0.7323

 

45 minutes ago, mLipok said:

What did you get in Console?

Quote

ObjName($oSubiekt) = Subiekt
ObjName($oProforma) = 

 

[water]

I have created this reproducer script and it displays two MsgBoxes - works as designed and expected!

Example()
Func Example()
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
    Local $oDictionary = ObjCreate("Scripting.Dictionary")
    Local $oErrorHandlerTest
    $oErrorHandlerTest.Test ; Com error called with success (msgbox appeared with scripline number)
    $oDictionary.Identyfikator  ; Com error called with no success (msgbox with scriptline number not appeared)
EndFunc   ;==>Example

Func _ErrFunc($oError)
    MsgBox(16, @ScriptName, "COM ERROR OCCURED! Check script line number " & $oError.ScriptLine)
EndFunc   ;==>_ErrFunc

Which version of AutoIt do you run?

[maniootek]

8 minutes ago, water said:

I have created this reproducer script and it displays two MsgBoxes - works as designed and expected!

Your code also show me two MsgBoxes.

 

9 minutes ago, water said:

Which version of AutoIt do you run?

v3.3.14.5

I think my object (SUBIEKT) is special and is not fully compatible

[jchd]

Here's what I use to dump variables and, for your paticular concern, details about objects:

Case "Object"
            $tmp = 'Object' & @LF & '    Name:             ' & ObjName($vVar, $OBJ_NAME)
            $ret = ObjName($vVar, $OBJ_STRING)
            If Not @error Then $tmp &= @LF & $sMore & $sIndent & '    Description:      ' & $ret
            $ret = ObjName($vVar, $OBJ_PROGID)
            If Not @error Then $tmp &= @LF & $sMore & $sIndent & '    ProgID:           ' & $ret
            $ret = ObjName($vVar, $OBJ_FILE)
            If Not @error Then $tmp &= @LF & $sMore & $sIndent & '    Associated file:  ' & $ret
            $ret = ObjName($vVar, $OBJ_MODULE)
            If Not @error Then $tmp &= @LF & $sMore & $sIndent & '    Owner/marshaller: ' & $ret
            $ret = ObjName($vVar, $OBJ_CLSID)
            If Not @error Then $tmp &= @LF & $sMore & $sIndent & '    CLSID:            ' & $ret
            $ret = ObjName($vVar, $OBJ_IID)
            If Not @error Then $tmp &= @LF & $sMore & $sIndent & '    InterfaceID:      ' & $ret
            Return $tmp

$tmp is a string that accumulates out data, $vVar is the variable containing the object. Constants are from AutoItConstants.au3

Maybe this could give more info about the issue you encounter.

Edited March 1, 2019 by jchd

[maniootek]

5 minutes ago, jchd said:

Here's what I use to dump vairables and, in for tour paticular concern, details about objects:

I tried your code but I just received empty Object name

[jchd]

So call that a ghost!

[mLipok]

2 hours ago, maniootek said:

I tried your code but I just received empty Object name

to be sure that this is or not a  ghost 👻 

This is very interesting so, try this concept:

expandcollapse popup

#include <AutoItConstants.au3>
.......
.......
    .......
    .......
    .......
    ObjName_FlagsValue($oProforma)
    $oProforma.Identyfikator  ;Com error called with no success (msgbox with scriptline number not appeared)
EndFunc   ;==>Example

Func ObjName_FlagsValue(ByRef $oObj)
    Local $sInfo = _
            '-' & @TAB & "VarGetType($oObj) = " & VarGetType($oObj) & @CRLF & _
            '-' & @TAB & "IsObj($oObj) = " & IsObj($oObj) & @CRLF & @CRLF

    $sInfo &= '+' & @TAB & 'ObjName($oObj, $OBJ_NAME) {The name of the Object} =' & @CRLF & @TAB & ObjName($oObj, $OBJ_NAME)
    If @error Then $sInfo &= @CRLF & '!' & @TAB & '@error = ' & @error
    $sInfo &= @CRLF & @CRLF

    ; HELPFILE REMARKS: Not all Objects support flags 2 to 7. Always test for @error in these cases.
    $sInfo &= '+' & @TAB & 'ObjName($oObj, $OBJ_STRING) {Description string of the Object} =' & @CRLF & @TAB & ObjName($oObj, $OBJ_STRING)
    If @error Then $sInfo &= @CRLF & '!' & @TAB & '@error = ' & @error
    $sInfo &= @CRLF & @CRLF

    $sInfo &= '+' & @TAB & 'ObjName($oObj, $OBJ_PROGID) {The ProgID of the Object} =' & @CRLF & @TAB & ObjName($oObj, $OBJ_PROGID)
    If @error Then $sInfo &= @CRLF & '!' & @TAB & '@error = ' & @error
    $sInfo &= @CRLF & @CRLF

    $sInfo &= '+' & @TAB & 'ObjName($oObj, $OBJ_FILE) {The file that is associated with the object in the Registry} =' & @CRLF & @TAB & ObjName($oObj, $OBJ_FILE)
    If @error Then $sInfo &= @CRLF & '!' & @TAB & '@error = ' & @error
    $sInfo &= @CRLF & @CRLF

    $sInfo &= '+' & @TAB & 'ObjName($oObj, $OBJ_MODULE) {Module name in which the object runs (WIN XP And above). Marshaller for non-inproc objects.} =' & @CRLF & @TAB & ObjName($oObj, $OBJ_MODULE)
    If @error Then $sInfo &= @CRLF & '!' & @TAB & '@error = ' & @error
    $sInfo &= @CRLF & @CRLF

    $sInfo &= '+' & @TAB & 'ObjName($oObj, $OBJ_CLSID) {CLSID of the object''s coclass} =' & @CRLF & @TAB & ObjName($oObj, $OBJ_CLSID)
    If @error Then $sInfo &= @CRLF & '!' & @TAB & '@error = ' & @error
    $sInfo &= @CRLF & @CRLF

    $sInfo &= '+' & @TAB & 'ObjName($oObj, $OBJ_IID) {IID of the object''s interface} =' & @CRLF & @TAB & ObjName($oObj, $OBJ_IID)
    If @error Then $sInfo &= @CRLF & '!' & @TAB & '@error = ' & @error
    $sInfo &= @CRLF & @CRLF

    ConsoleWrite($sInfo & @CRLF)
EndFunc   ;==>ObjName_FlagsValue

 

Edited March 1, 2019 by mLipok

[mLipok]

I was sure that this problem was asked before.
A quick search and:

 

You can also see this in my rewritten XML.au3 UDF 

Func _XML_SelectSingleNode(ByRef $oXmlDoc, $sXPath)
    ; Error handler, automatic cleanup at end of function
    Local $oXML_COM_ErrorHandler = ObjEvent("AutoIt.Error", __XML_ComErrorHandler_InternalFunction)
    #forceref $oXML_COM_ErrorHandler

    __XML_IsValidObject_DOMDocumentOrElement($oXmlDoc)
    If @error Then Return SetError(@error, @extended, $XML_RET_FAILURE)

    Local $oNode_Selected = $oXmlDoc.selectSingleNode($sXPath)
    If @error Then
        Return SetError($XML_ERR_XPATH, $XML_EXT_DEFAULT, $XML_RET_FAILURE)
    ElseIf $oNode_Selected = Null Then
        Return SetError($XML_ERR_NONODESMATCH, $XML_EXT_DEFAULT, $XML_RET_FAILURE)
    ElseIf Not IsObj($oNode_Selected) Then ; https://www.autoitscript.com/forum/topic/177176-why-isobj-0-and-vargettype-object/
        ; $XML_ERR_EMPTYOBJECT
        Return SetError($XML_ERR_NONODESMATCH, $XML_EXT_DEFAULT, $XML_RET_FAILURE)
    EndIf

    Return SetError($XML_ERR_SUCCESS, $XML_EXT_DEFAULT, $oNode_Selected)
EndFunc   ;==>_XML_SelectSingleNode

 

Edited March 1, 2019 by mLipok

[maniootek]

51 minutes ago, mLipok said:

This is very interesting so, try this concept:

Quote

...

-    VarGetType($oObj) = Object
-    IsObj($oObj) = 0

+    ObjName($oObj, $OBJ_NAME) {The name of the Object} =
    
!    @error = 1

+    ObjName($oObj, $OBJ_STRING) {Description string of the Object} =
    
!    @error = 1

+    ObjName($oObj, $OBJ_PROGID) {The ProgID of the Object} =
    
!    @error = 1

+    ObjName($oObj, $OBJ_FILE) {The file that is associated with the object in the Registry} =
    
!    @error = 1

+    ObjName($oObj, $OBJ_MODULE) {Module name in which the object runs (WIN XP And above). Marshaller for non-inproc objects.} =
    
!    @error = 1

+    ObjName($oObj, $OBJ_CLSID) {CLSID of the object's coclass} =
    
!    @error = 1

+    ObjName($oObj, $OBJ_IID) {IID of the object's interface} =
    
!    @error = 1

"C:\Example.au3" (17) : ==> The requested action with this object has failed.:
$oProforma.Identyfikator
$oProforma^ ERROR

 

51 minutes ago, mLipok said:

I was sure that this problem was asked before.

So this is all about object which is empty. In this case Com Error Handler will not catch the error. I will just use IsObj() function to catch the error. Thank you

[mLipok]

@maniootek thanks for the HelpFile (CHM file in PM).

The problem is how you manage your code here:

Local $oProforma = $oSubiekt.Dokumenty.Wczytaj("this string suppose to be valid document number")

Spoiler

 

in InsertGT HelpFile:

Quote

Jeśli dokument nie istnieje w bazie danych, metoda zwraca w VB wartość Nothing (dla innych implementacji obiekt NULL). Celem sprawdzenia, czy dokument istnieje w bazie danych zaleca się użycie metody Istnieje.

 

Quote

If the document does not exist in the database, the method returns the Nothing value in VB (for other implementations, the NULL object). In order to check whether a document exists in the database, it is recommended to use the Istnieje method.

 

 

 

Public Sub WczytanieIWyswietlenieDokumentu()
    On Error Resume Next
 
    Dim oSgt As InsERT.Subiekt
    Dim oDok As InsERT.SuDokument
    Dim CzyIstnieje As Boolean
    
    'Uruchomienie Subiekta GT
    Set oSgt = UruchomSubiekta()
 
    'Sprawdzenie, czy dokument istnieje w bazie
    CzyIstnieje = oSgt.Dokumenty.Istnieje("FS 28/MAG/2005")
    If CzyIstnieje = False Then
        MsgBox "Dokument nie istnieje w bazie danych"
        Exit Sub
    Else
        'Wczytuje dokument
        Set oDok = oSgt.Dokumenty.Wczytaj("FS 28/MAG/2005")
    End If
    
    'Ukrycie okna Subiekta GT i wyświetlenie okna dokumentu
    oSgt.Okno.Widoczne = False
    oDok.Wyswietl
    
End Sub

 

 

 

so you should try this:

Local $oProforma = Null
If $oSubiekt.Dokumenty.Istnieje("this string suppose to be valid document number") then
    $oProforma = $oSubiekt.Dokumenty.Wczytaj("this string suppose to be valid document number")
    .........
EndIf

 

Edited March 1, 2019 by mLipok

[mLipok]

btw. 
"If the document does not exist in the database, the method returns the Nothing value in VB (for other implementations, the NULL object). "

What is "Null Object" ?
Is it something other than Null Keyword in AutoIt ?

[maniootek]

1 hour ago, mLipok said:

so you should try this:

This is something similar I already have in my script.

This all is about that I just wanted to know why empty object is not catched by com error handler. That's it. If there is no simple answer then I am fine too.

1 hour ago, mLipok said:

What is "Null Object" ?

I don't know. I never check if object is null. I just check with IsObj() function now