Logging and stop script running on any error

[KiTKaT]

Hi,

How can I log and stop may script buring any error? 

For example I use this my code:

If ControlSetText( $hWndTreeView, "", $sEdtHostName, $sHostIP) = 0 Then "Error message" and exit
If ControlSetText( $hWndTreeView, "", $sEdtUserName, $sUsername) = 0 Then "Error message" and exit
If ControlClick($hWndTreeView, "", $sBtnSave) = 0 Then "Error message" and exit

 

How can I do if any ControlText or ControlClick failed (return error) my Error Func called?

THX

KiTKaT

[abberration]

 

If ControlSetText( $hWndTreeView, "", $sEdtHostName, $sHostIP) = 0 Then 
    MsgBox(0, "", "Error message")
    exit
EndIf
If ControlSetText( $hWndTreeView, "", $sEdtUserName, $sUsername) = 0 Then
    MsgBox(0, "", "Error message")
    exit
EndIf
If ControlClick($hWndTreeView, "", $sBtnSave) = 0 Then 
    MsgBox(0, "", "Error message")
    exit
EndIf    

 

Edited February 28, 2019 by abberration
put the code in code format

[KiTKaT]

Hi Abberration,

I know this but I don't wanna write IF ... THEN for every CommandCLick, CommandSetText, CommandControl ... etc. I have more than 300. I'd like a Func that "monitoring" apps and stop it if detect any error.

THX

KiTKaT

[Nine]

@KiTKaT It is not possible to monitor those functions like we can with a COM error handler.  But you could write a generic function that would CALL () the targeted functions you want.  And all error handling could be done inside that generic function.  Look in help file at Call () function.

[caramen]

11 hours ago, Nine said:

@KiTKaT It is not possible to monitor those functions like we can with a COM error handler.  But you could write a generic function that would CALL () the targeted functions you want.  And all error handling could be done inside that generic function.  Look in help file at Call () function.

Can you repeat this with more detailed info please it s interesting  

[mLipok]

20 hours ago, KiTKaT said:

I have more than 300

Such a small number...

Edited March 1, 2019 by mLipok

[Nine]

8 hours ago, caramen said:

Can you repeat this with more detailed info please it s interesting

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Opt ("MustDeclareVars", 1)

Local $Form1 = GUICreate("Form1", 319, 217, 192, 124)
Local $Label1 = GUICtrlCreateLabel("Label1", 32, 32, 36, 17)
Local $Input1 = GUICtrlCreateInput("Input1", 80, 30, 145, 21)
Local $Button1 = GUICtrlCreateButton("Button1", 80, 96, 97, 33)
GUISetState(@SW_SHOW)

; without error
GCC(ControlSend,$Form1,"",$Input1,"First")
GCC(ControlClick,$Form1,"",$Button1,"Left",1)
Sleep (2000)
GCC(ControlSetText,$Form1,"",$Input1,"Second")

; with errors
; GCC(XYZ,1,1,1,1)
; GCC(ControlCommand,$Form1,"",$Input1,"Third")
GCC(ControlSetText,"Test","",99,1)

Local $nMsg

While 1
  $nMsg = GUIGetMsg()
  Switch $nMsg
    Case $GUI_EVENT_CLOSE
      Exit

  EndSwitch
WEnd


Func GCC ($Func, $p1, $p2, $p3, $p4, $p5 = "", $p6 = "", $p7 = "")
Local Const $aFunc [3][3] = [[ControlClick,7,"Click"],[ControlSend,5,"Send"],[ControlSetText,5,"SetText"]]
Local $aArg [1] = ["CallArgArray"], $iFunc = -1

  For $i = 0 to Ubound ($aFunc)-1
    if $Func = $aFunc[$i][0] then
      $iFunc = $i
      ExitLoop
    EndIf
  Next
  If $iFunc < 0 then Exit MsgBox (0,"Error","Unknown Function")
  Redim $aArg[$aFunc[$iFunc][1]+1]
  For $i = 1 to $aFunc[$iFunc][1]
    $aArg [$i] = Eval ("p" & $i)
  Next
  Local $sRet = Call ($Func, $aArg)
  If @error = 0xDEAD and @extended = 0xBEEF then Exit MsgBox (0,"Fatal Error", "Invalid function call")
  If not $sRet then Exit MsgBox (0,"Error", "Error calling " & $aFunc[$iFunc][2] & " with param " & $p1 & "/" & $p2 & "/" & $p3 & "/" & $p4 & "/" & $p5 & "/" & $p6 & "/" & $p7)

EndFunc

Something like that for example