RegEnumVal Error -1 :(

[caramen]

Hi guys

 

Local $cKey ="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"
    Local $sSubKey = "", $sEnumKey = $cKey & @CRLF & @CRLF , $sEnumKeyFTV
    For $i = 1 To 10
        MsgBox(0, "debug $i:", $i)
        MsgBox(0, "debug $cKey:", $cKey)
        $sSubKey = RegEnumVal( $cKey , $i)
            If @error Then
               MsgBox(0,"Debug error",""&@error)
               ExitLoop
            EndIf
            MsgBox(0, "debug $sSubKey:", $sSubKey)
        $sEnumKey &= "#" & $i & @TAB & $sSubKey & @CRLF
        $sEnumKeyFTV = $cKey & "\" & $sSubKey & @TAB  & @CRLF
     Next
    $ScanDemarrage = 1

My Goal is to get all key's values in "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"

 

I keep getting error -1

This sample is prepared for you so you can test and try to help me to solve this.

Btw i dont know how to solve this :

-1 = unable to retrieve requested value name (value instance out of range) Tryed with #requireAdmin   And maybe that help : The exact same sample of code is working with "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"

Edited January 29, 2019 by caramen

[Subz]

Maybe something like:

#include <Array.au3>
Global $aRegRun[0][3]
_RegRunValues("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run")
_RegRunValues("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run")
_RegRunValues("HKLM64\SOFTWARE\Microsoft\Windows\CurrentVersion\Run")
_ArrayDisplay($aRegRun)

Func _RegRunValues($cKey)
    Local $i = 1, $sSubKey
    While 1
        $sSubKey = RegEnumVal($cKey, $i)
            If @error Then ExitLoop
        _ArrayAdd($aRegRun, $cKey & "|" & $sSubKey & "|" & RegRead($cKey, $sSubKey))
        $i += 1
    WEnd
EndFunc

 

[caramen]

Thanks got it.

Edited January 29, 2019 by caramen

[Subz]

I suspect that you don't have any values under the 32 bit key "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Run", which you are referencing in your code.  Can you check the key to see if it has any values?

To access the 64 bit key "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" you need to use HKLM64 (only if compiled as 32 bit) as my example above and remember that HKLM references the 32 bit keys.  If you compile your script as 64 bit then you'll can use: HKEY_LOCAL_MACHINE\Software and HKEY_LOCAL_MACHINE\Software\WOW6432Node