[Solved] Custom context menus for edit controls

[qwert]

I've been trying to fashion a custom context menu for an edit control. The help file for context menus clearly states that a direct method is not supported. So I've been trying alternative methods to intercept the right mouse click and take an action. So far, nothing has panned out. The code below shows a method that seems very close. The mouse click is detected, but the menu doesn't display.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIDlg.au3>

$hGUI = GUICreate("GUI Context Menu Test", 300, 200)
$label = GUICtrlCreateLabel("", 20, 20, 260, 120)      ; label control solely to support context menu
$edit = GUICtrlCreateEdit("Test", 20, 20, 260, 120)
$button = GUICtrlCreateButton("OK", 120, 170, 70, 20)

$buttoncontext = GUICtrlCreateContextMenu($button)
GUICtrlCreateMenuItem("About button", $buttoncontext)

$idDummy = GUICtrlCreateDummy()                         ; created for a dummy control, because you
$contextmenu = GUICtrlCreateContextMenu($idDummy)       ; can't create a context menu for an edit control
$case_0 = GUICtrlCreateMenuItem("Case 0", $contextmenu)
$case_1 = GUICtrlCreateMenuItem("Case 1", $contextmenu)

GUISetState()

GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

While 1
$nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            MsgBox(0, "Button", "The button was clicked.")
        Case $case_0
            MsgBox(0, "Case 0", "This is Case 0")
        Case $case_1
            MsgBox(0, "Case 1", "This is Case 1")
    EndSwitch
WEnd

Func WM_CONTEXTMENU($hWnd, $iMsg, $iwParam, $ilParam)
    Local $IDCtrl = _WinAPI_GetDlgCtrlID($iwParam)
    Local $x = BitAND($ilParam, 0x0000FFFF), $y = BitShift($ilParam, 16)
    Switch $IDCtrl
        Case $label             ; because $edit doesn't seem to work
            TrackPopupMenu($hWnd, $contextmenu, $x, $y)
    EndSwitch
EndFunc

Func TrackPopupMenu($hWnd, $hMenu, $x, $y)
    ConsoleWrite($x & @CRLF)                ; confirms that the menu is requested
    ConsoleWrite($y & @CRLF)
    DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hMenu, "int", 0, "int", $x, "int", $y, "hwnd", $hWnd, "ptr", 0)
EndFunc

I've seen topics on other forums that seem to indicate that this is possible, but I haven't seen a clear example. (BTW, I'll mention that it's fairly important to me to keep things simple.)

Has anyone been successful at implementing such a menu? ... or maybe have ideas of what to try?

Thanks in advance for any assistance.

 

Edited January 28, 2019 by qwert

[BrewManNH]

1 hour ago, qwert said:

BTW, I'll mention that it's fairly important to me to keep things simple

Unfortunately, I don't think any answer to this is going to be simple.

Here's one discussion on how to do it on StackOverflow, and it's definitely not a simple process.

[qwert]

Thanks for your response. Yes, I had seen that one ... and, yes, that's the complexity I'm trying to avoid.

But here's a post that implies simpler ways: post (... although it won't be the first time I've misinterpreted such things.)

[Subz]

The following old post works, you need to download the DllCallback.au3 and remove the @Unicode references for it to work.

 

[qwert]

Whoa! ... that's a great solution. I picked up the example on page 2 of that thread and my initial test indicates it does exactly what I need.

FWIW, my take is that subclassing lets you reassign a control (in this case, the edit control) away from the standard processing ... and (if your want) to your own processing.

It's hard to believe that this isn't more widely known/used (I've never seen it, before) because the standard context menu for edit/input controls is so poor (too many unneeded choices!)

Thanks very much!

[pixelsearch]

Hi qwert,
The solution we talked about :

expandcollapse popup

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("GUI Context Menu Test", 300, 200)
$edit = GUICtrlCreateEdit("Test", 20, 20, 260, 120)

$button = GUICtrlCreateButton("OK", 120, 170, 70, 20)
$buttoncontext = GUICtrlCreateContextMenu($button)
GUICtrlCreateMenuItem("About button", $buttoncontext)

$label = GUICtrlCreateLabel("", 1, 1, 1, 1)
$contextmenu = GUICtrlCreateContextMenu($label)
$case_0 = GUICtrlCreateMenuItem("Case 0", $contextmenu)
$case_1 = GUICtrlCreateMenuItem("Case 1", $contextmenu)
$hcontextmenu = GUICtrlGetHandle($contextmenu)

GUISetState()

While 1
    $aInfo = GUIGetCursorInfo()
    If not @error And $aInfo[3] = 1 And $aInfo[4] = $edit Then
        $mPos = MouseGetPos()
        DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hcontextmenu, _
            "int", 0, "int", $mPos[0], "int", $mPos[1], "hwnd", $hGUI, "ptr", 0)
    EndIf

    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            MsgBox(0, "Button", "The button was clicked.")
        Case $case_0
            MsgBox(0, "Case 0", "This is Case 0")
        Case $case_1
            MsgBox(0, "Case 1", "This is Case 1")
    EndSwitch
WEnd

Good luck

[qwert]

@pixelsearch, thanks for keeping after this and posting the simplest solution!

What I was after all along was a way to have different context menus for different edit controls. Your method does that, nicely.

Here's an example with two edit controls set up with different menus ... and without subclassing or registered message processing:

expandcollapse popup

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("GUI Context Menu Test", 300, 350)
$edit = GUICtrlCreateEdit("Test", 20, 20, 260, 120)
$edit2 = GUICtrlCreateEdit("Also", 20, 180, 260, 120)

$button = GUICtrlCreateButton("OK", 120, 320, 70, 20)
$buttoncontext = GUICtrlCreateContextMenu($button)
GUICtrlCreateMenuItem("About button", $buttoncontext)

$label = GUICtrlCreateLabel("", 1, 1, 1, 1)
$contextmenu = GUICtrlCreateContextMenu($label)
$case_0 = GUICtrlCreateMenuItem("Case 0", $contextmenu)
$case_1 = GUICtrlCreateMenuItem("Case 1", $contextmenu)
$hcontextmenu = GUICtrlGetHandle($contextmenu)

$label2 = GUICtrlCreateLabel("", 1, 1, 1, 1)
$context2 = GUICtrlCreateContextMenu($label2)
$case_2 = GUICtrlCreateMenuItem("Case 2", $context2)
$case_3 = GUICtrlCreateMenuItem("Case 3", $context2)
$hcontext2 = GUICtrlGetHandle($context2)

GUISetState()

While 1
    $aInfo = GUIGetCursorInfo()
    If not @error And $aInfo[3] = 1 And $aInfo[4] = $edit Then
        $mPos = MouseGetPos()
        DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hcontextmenu, _
            "int", 0, "int", $mPos[0], "int", $mPos[1], "hwnd", $hGUI, "ptr", 0)
    EndIf

    If not @error And $aInfo[3] = 1 And $aInfo[4] = $edit2 Then
        $mPos = MouseGetPos()
        DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hcontext2, _
            "int", 0, "int", $mPos[0], "int", $mPos[1], "hwnd", $hGUI, "ptr", 0)
    EndIf

$nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            MsgBox(0, "Button", "The button was clicked.", 1)
        Case $case_0
            MsgBox(0, "Case 0", "This is Case 0", 1)
        Case $case_1
            MsgBox(0, "Case 1", "This is Case 1", 1)
        Case $case_2
            MsgBox(0, "Case 2", "This is Case 2", 1)
        Case $case_3
            MsgBox(0, "Case 3", "This is Case 3", 1)
    EndSwitch
WEnd

I'm impressed. (Sorry I couldn't see the forest amongst the trees in your first script!)

Thanks, again!

 

[pixelsearch]

yw qwert, always a pleasure to help friendly people