Help With StringSplit

[AutoPM]

is there any way to Split String At Particular Occurrence Of A Symbol.

For Example   

//www.autoitscript.com/forum/forum/2-autoit-general-help-and-support/

How to Split Above String At Third Occurrence of "/"

After Split Two strings should be //www.autoitscript.com   &  forum/forum/2-autoit-general-help-and-support/

 

[Melba23]

AutoPM,

I would do it this way:

$sText = "//www.autoitscript.com/forum/forum/2-autoit-general-help-and-support/"

; Look for third /
$iIndex = StringInStr($sText, "/", 0, 3)
; Split string at that point
$sSplit_1 = StringMid($sText, 1, $iIndex - 1)
$sSplit_2 = StringMid($sText, $iIndex + 1)

ConsoleWrite($sSplit_1 & @CRLF & $sSplit_2 & @CRLF)

M23

[FrancescoDiMuro]

@AutoPM
You can use SRE too:

#include <Array.au3>
#include <StringConstants.au3>

Global $arrStrings[5] = ["//www.autoitscript.com/forum/forum/2-autoit-general-help-and-support/", _
                         "www.autoitscript.com/forum/forum/2-autoit-general-help-and-support/", _
                         "www.abcd.efgh.com/", _
                         "//www.somethingelse.com.de.eu.com/abcdefgh", _
                         "www.a.b.c.d.e.f.g.h.com/something/somethingelse/anythingelse"], _
       $strPattern = "^(?:\/\/)?([^\/]+)(?:\/)(.+)$", _
       $arrResult

For $strString In $arrStrings
    $arrResult = StringRegExp($strString, $strPattern, $STR_REGEXPARRAYGLOBALMATCH)
    _ArrayDisplay($arrResult)
Next

Edited January 25, 2019 by FrancescoDiMuro

[AutoPM]

@Melba23  Thank you So Much.

[AutoPM]

@FrancescoDiMuro  

Can you Please Explain What Exactly your Regex pattern Is Matching.

I'm Little Confused. 

[FrancescoDiMuro]

  @AutoPM
The pattern is described as follows:
^: anchor to match from the start of the string;
(?:\/\/)?: non-capturing group. It doesn't "capture" (but matches!) the starting //, which need to be escaped with / (each of them), but their existance it's optional (?);
([^\/]+): capturing group. It "captures" anything that is not a slash, from 1 to anything;
(?:\/): non-capturing group. It doesn't "capture" (but matches!) the slash;
(.+): capturing group. It "captures"everything, except the new line (without the modifier ?s ("DotAll")), from 1 to anything;
$: anchor to match at the end of the string.



 

Edited January 25, 2019 by FrancescoDiMuro

[AutoPM]

Understood , Thank you 

[FrancescoDiMuro]

@AutoPM
You're welcome
P.S.: By the way, if you want to use an online RegEx editor, try to use this website (it tells almost everything your pattern does with your test string).

Edited January 25, 2019 by FrancescoDiMuro