Activate Excel Window

[AnonymousX]

Hello,

I'm trying to be able to switch back and forth between multiple excel spreadsheets and I can't seem to get the WinActivate function to work, and bring the desired window the be the active window.

Could I please get some assistance, I've tried a few things and nothing seems to work quite right. Below is a test case where I'm just trying to make the first excel sheet that was opened become the active window, and testing it by grabbing a cell value off that workbook. The message box produces the correct answer if both files are closed before running but the 2nd test file will appear to be the active window. If the code is run again without closing the excel files, nothing works (file does not appear to be active and message box will not give an answer).

 

#include <Excel.au3>

Opt("WinTitleMatchMode", 2)     ;1=start, 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase

;Open Test1 Excel Workbook
local $oExcel = _Excel_open()
Local $ofile = @ScriptDir & "\test1.xlsx"
Local $oWorkbook = _Excel_BookOpen($oExcel,$ofile)


;Open Test2 Excel Workbook
local $mExcel = _Excel_open()
Local $mfile =  @ScriptDir & "\test2.xlsx"
Local $mWorkbook = _Excel_BookOpen($mExcel,$mfile) ; This workbook is completely blank


WinActivate($oWorkbook); should make Test1 the active window
local $read1 = _Excel_RangeRead($oWorkbook,Default,"B2"); Cell B1 in Test1 workbook contains the word Test
MsgBox(0,0,$read1);Should returns the word test

 

[Subz]

Look at _Excel_BookList and _Excel_BookAttach functions.

[JoHanatCent]

Do _Excel_Open once

Then the WorkBooks.

Don't need to switch Windows to get the values:

#include <Excel.au3>
Local $oExcel = _Excel_Open()
;Open Test1 Excel Workbook
Local $ofile = @ScriptDir & "\test1.xlsx"
Local $oWorkbook = _Excel_BookOpen($oExcel, $ofile)
;Open Test2 Excel Workbook
Local $mfile = @ScriptDir & "\test2.xlsx"
Local $mWorkbook = _Excel_BookOpen($oExcel, $mfile)
;Read Workbook data and display
Local $read1 = _Excel_RangeRead($oWorkbook, Default, "B2") ; Cell B1 in Test1 workbook contains the word Test1
Local $read2 = _Excel_RangeRead($mWorkbook, Default, "B2") ; Cell B1 in Test2 workbook contains the word Test2
MsgBox(0, 0, $read1 & @CR & $read2) ;Returns the correct values.

 

[Subz]

To check if the workbook is already opened you can use the following:

#include <Excel.au3>

Local $sFileName1 = @ScriptDir & "\test1.xlsx"
Local $sFileName2 = @ScriptDir & "\test2.xlsx"

Local $oExcel = _Excel_Open()

Local $oWorkbook1, $oWorkbook2

;Open Test1 Excel Workbook
$oWorkbook1 = _Excel_BookAttach($sFileName1)
    If @error Then $oWorkbook1 = _Excel_BookOpen($oExcel, $sFileName1)

;Open Test2 Excel Workbook
 $oWorkbook2 = _Excel_BookAttach($sFileName2)
    If @error Then $oWorkbook2 = _Excel_BookOpen($oExcel, $sFileName2)

;Read Workbook data and display
Local $sWB1CellB2, $sWB2CellB2
$sWB1CellB2 = IsObj($oWorkbook1) ? _Excel_RangeRead($oWorkbook1, Default, "B2") : "" ; Cell B2 in Test1 workbook contains the word Test1, if $oWorkbook1 is not an object then return empty string
$sWB2CellB2 = IsObj($oWorkbook2) ? _Excel_RangeRead($oWorkbook2, Default, "B2") : "" ; Cell B2 in Test2 workbook contains the word Test2, if $oWorkbook2 is not an object then return empty string
MsgBox(0, 0, $sWB1CellB2 & @CR & $sWB2CellB2) ;Returns the correct values.

 

[Nine]

if you still need to activate a worksheet you can use :

$Worksheets("Sheet1").Activate

 

[AnonymousX]

Thanks everyone! I'll give those a try later today

[AnonymousX]

@JoHanatCent That didn't work, I just get back the value from 2nd workbook

@Nine Couldn't get that to work either, kept getting an error

@Subz Works great for being able to grab values from both workbooks. I was able to use your code to figure out how write between workbooks.

How could I go from here to copy over charts?

 

I found from you Subz on another forum this code for copying charts into Outlook and got it to work:

#include <Excel.au3>

Local $oExcel = _Excel_Open()
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Chart.xlsx")
Local $oRange = $oWorkbook.ActiveSheet.Range("A1:G34").Select
    $oExcel.CopyObjectsWithCells = True
    $oExcel.Selection.Copy

Local $oOutlook = ObjCreate("Outlook.Application")
Local $oMail = $oOutlook.CreateItem(0)
    $oMail.Display
    $oMail.To = "sample@example.com"
    $oMail.Subject = "Sample Subject"

Local $sBodyHeader = "Hello" & @CRLF & @CRLF & "Please find charts below." & @CRLF & @CRLF
Local $sBodyFooter = @CRLF & @CRLF & "Regards Subz"

Local $oWordEditor = $oOutlook.ActiveInspector.wordEditor
    $oWordEditor.Range(0, 0).Select
    $oWordEditor.Application.Selection.TypeText($sBodyHeader)
    $oWordEditor.Application.Selection.Paste
    $oWordEditor.Application.Selection.TypeText($sBodyFooter)

$oMail.Display

But I can't seem to get it to work with Excel WB1 to WB2.

Local $oRange = $oWorkbook1.ActiveSheet.Range("A7:H20").Select    creates an error, It probably would be better just to call Chart 1 but since I can't get it to compile I can't test to see if something like Local $oRange = $oWorkbook1.ActiveSheet.Charts("Chart 1").Select would work.

#include <Excel.au3>

Local $sFileName1 = @ScriptDir & "\test1.xlsx"
Local $sFileName2 = @ScriptDir & "\test2.xlsx"

Local $oExcel = _Excel_Open()

Local $oWorkbook1, $oWorkbook2

;Open Test1 Excel Workbook
$oWorkbook1 = _Excel_BookAttach($sFileName1)
    If @error Then $oWorkbook1 = _Excel_BookOpen($oExcel, $sFileName1)

Local $oRange = $oWorkbook1.ActiveSheet.Range("A7:H20").Select
    $oExcel.CopyObjectsWithCells = True
    $oExcel.Selection.Copy


;Open Test2 Excel Workbook
 $oWorkbook2 = _Excel_BookAttach($sFileName2)
    If @error Then $oWorkbook2 = _Excel_BookOpen($oExcel, $sFileName2)

;Read Workbook data and display
Local $sWB1CellB2, $sWB2CellB2
$sWB1CellB2 = IsObj($oWorkbook1) ? _Excel_RangeRead($oWorkbook1, Default, "B2") : "" ; Cell B2 in Test1 workbook contains the word Test1, if $oWorkbook1 is not an object then return empty string
;$sWB2CellB2 = IsObj($oWorkbook2) ? _Excel_RangeRead($oWorkbook2, Default, "B2") : "" ; Cell B2 in Test2 workbook contains the word Test2, if $oWorkbook2 is not an object then return empty string
MsgBox(0, 0, $sWB1CellB2 & @CR & $sWB2CellB2) ;Returns the correct values.

;_Excel_RangeWrite($oWorkbook1,$oWorkbook1.activesheet,"test","C4")
$oWorkbook2.ActiveSheet.Range("A7:H20").paste

 

 

 

[Subz]

Just the last line doesn't wok, unfortunately don't have a lot of time, but just replace the last line with:

$oWorkbook2.ActiveSheet.Range("A7").Select
$oWorkbook2.ActiveSheet.Paste

 

[AnonymousX]

@Subz

Thanks Mate!!!

Feel dumb I wasn't able to figure that one out