Log in GUICtrlCreateEdit

[lokatylokacz]

Hello!

How to create something like GUI script log.

I made GUICtrlCreateEdit (read only) and I wanna add there new msg depending on that was is going on with the script.

My problem is that if I use GUICtrlSetData it cleans msg that was there b4 so I can just see last change in log. How to deal with it ?

[JLogan3o13]

@lokatylokacz there are several ways to do it (as with most things in AutoIt). In essence, you need to read in what text is in the edit control and add that to your GUICtrlSetData. Something like this perhaps:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Local $hGUI = GUICreate("Test", 300, 300)
Local $hEdit = GUICtrlCreateEdit("", 10, 10, 280, 200)
Local $btnGo = GUICtrlCreateButton("Go", 250, 250, 40, 40)

GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btnGo
                GUICtrlSetData($hEdit, @TAB & "========Initializing Program========" & @CRLF)
                    For $a = 1 To 10
                        GUICtrlSetData($hEdit, GUICtrlRead($hEdit) & "===Executing Line " & $a & " of Program===" & @CRLF)
                    Next
                GUICtrlSetData($hEdit, GUICtrlRead($hEdit) & @TAB & "========Program Complete========")
        EndSwitch
    WEnd

 

[FrancescoDiMuro]

@JLogan3o13

Couldn't he just use the default parameter of GUICtrlSetData() set as non-empty value to append data to the Edit control instead of reading and concatenating each time the new data?

[lokatylokacz]

@FrancescoDiMuro

Can you show me how it should look pls ?

[FrancescoDiMuro]

@lokatylokacz

GUICtrlSetData($youreditcontrol, "Line 1" & @CRLF, -1)
GUICtrlSetData($youreditcontrol, "Line 2" & @CRLF, -1)

 

[lokatylokacz]

@JLogan3o13

Thx for the answer.

@FrancescoDiMuro

This is what I was looking for  I think.
"-1" ... why I can't read F1 help like I should...
THX again

Yep This is it 

Thx!

Edited November 27, 2018 by lokatylokacz

[FrancescoDiMuro]

@lokatylokacz

Happy to have helped

[JLogan3o13]

@FrancescoDiMuro you are 100% correct, I made something of a Rube Goldberg machine there 

Edited November 27, 2018 by JLogan3o13