The definition of the keyboard keys

[Proton]

Hello.

 I have two keyboards on my computer.
 One is connected via the PS2 port, the second is connected via the USB port.

 I press the "Q" key first - on one keyboard, then a similar key - on the second keyboard.

 How can the autoit script recognize - from which keyboard - were these presses made?
 If I press Q - on the PS2 keyboard - then Msgbox shows the message - "PS2 Keyboard"
 If I press Q - on the USB keyboard - then Msgbox shows the message - "USB Keyboard"

[careca]

Maybe it's possible, but i think you have to go deep under the hood, low level stuff, to be able to distinguish what is what.

can for example, _ispressed recognize the presses on the ps2 also?

[Proton]

careca, I did not find examples of the keyboard on the link.

[Nine]

the real question is why the hell you want 2 keyboards, and what the hell is the use of it ?  Then maybe we will be able to help your ?

[Proton]

Nine, I want to have a lot of hotkeys on the second keyboard.
 Therefore, I ask this question.

[careca]

9 hours ago, Proton said:

careca, I did not find examples of the keyboard on the link.

_ispressed

I didn't post a link, the objective was that you would search in the help file, sry i should've been more specific.

Now it is a link, if that's better for you.

Edited November 22, 2018 by careca

[caramen]

7 hours ago, Proton said:

I want to have a lot of hotkeys on the second keyboard.

Good idea I like.

If i can help I will.

 

Starting Search for you.

[caramen]

From what i readed. you can do that if you play with the device driver. If your ps2 keyboard got one. Or usb...

If one of your keyboard got a driver then the other keyboard dont need one. 

You just have to detect the incoming input with the driver. 

 

The problem is i realy dont know how to play with AutoIT and Drivers/dll. So i cannot help you. But if someone help with something too hard for you and not for me.  I will help you to understand. if i can of course  . 

 

I wish you good luck and i ll keep this topic in mind.

 

 

[Nine]

@proton, you know that you can define a lot of hotkeys with a single kb

for example with the Fx keys

F1-F12

Shift F1-F12

Ctrl F1-F12

Alt F1-F12

Shift+Ctrl F1-F12

Shift+Alt F1-F12

Ctrl-Alt F1-F12

Shift+Ctrl+Alt F1-F12

Almost 100 hotkeys...Not enough ?  You can double it by checking Caps Lock, you can quad it by also checking Num Lock !

Edited November 22, 2018 by Nine

[caramen]

@Nine Everything is true. 

BUT 

I totaly understand the OP when he try to make a keyboard reserved ONLY for shordcut. 

It can be a very good thing to have a shordcut keyboard to start applications, to use macros on some software, or whatever. Autologin etc... 

 

But yes seem like to be very hard to do.

 

[Melba23]

Hi,

Perhaps this thread might be of interest.

M23

[Proton]

Melba23, This information is of interest.
 Thanks you.

[Proton]

Then I want to ask a question.

This code responds to buttons on different keyboards.

expandcollapse popup

;Bilgus 2018
;Determine which keyboard was pressed

#include <Array.au3>
#include <WinAPISys.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global Const $HWND_MESSAGE = (-3) ;create a message-only window when set as Parent

;RAWINPUTDEVICE Constants
Global Const $HID_USAGE_PAGE_GENERIC = 0x1
Global Const $HID_USAGE_GENERIC_KEYBOARD = 0x6

Global $ghSelectedDevice

Global $gaKeyboards = EnumRawKeyboards("\HID")
If IsArray($gaKeyboards) And $gaKeyboards[0][0] >= 1 Then $ghSelectedDevice = $gaKeyboards[1][0] ; hard coded change to suit

_ArrayDisplay($gaKeyboards, '_WinAPI_EnumRawInputDevices', "", 0, Default, "Handle|Type|VID|Keys") ;Not Needed...

Global $hTarget = GUICreate("main", 10, 10, Default, Default, Default, Default, $HWND_MESSAGE) ;Dummy window to recieve messages

Register_RawInput($HID_USAGE_PAGE_GENERIC, $HID_USAGE_GENERIC_KEYBOARD, $RIDEV_INPUTSINK, $hTarget) ;$RIDEV_INPUTSINK recieves input when not foreground

; Register WM_INPUT message
GUIRegisterMsg($WM_INPUT, 'WM_INPUT')

HotKeySet("{ESC}", _Exit)

While 1
    Sleep(1000)
WEnd

Func Device_Pressed()
    ConsoleWrite("Device Pressed" & @CRLF)
EndFunc   ;==>Device_Pressed

Func _Exit()
    Exit
EndFunc   ;==>_Exit

Func Register_RawInput($iUsagePage, $iUsage, $iFlags, $hTargetHwnd)
    Local $tRID = DllStructCreate($tagRAWINPUTDEVICE)
    DllStructSetData($tRID, 'UsagePage', $iUsagePage)
    DllStructSetData($tRID, 'Usage', $iUsage)
    DllStructSetData($tRID, 'Flags', $iFlags)
    DllStructSetData($tRID, 'hTarget', $hTargetHwnd)

    ; Register HID input to obtain info from devices
    _WinAPI_RegisterRawInputDevices($tRID)
EndFunc   ;==>Register_RawInput

Func WM_INPUT($hWnd, $iMsg, $wParam, $lParam) ;Callback from RawInput
    #forceref $iMsg, $wParam

    ;'struct;dword Type;dword Size;handle hDevice;wparam wParam;endstruct'
    Local $tRIH = DllStructCreate($tagRAWINPUTHEADER)

    If _WinAPI_GetRawInputData($lParam, $tRIH, DllStructGetSize($tRIH), $RID_HEADER) And DllStructGetData($tRIH, "Type") = $RIM_TYPEKEYBOARD Then
        ConsoleWrite("0x" & Hex(DllStructGetData($tRIH, "hDevice")) & @CRLF)
        If $ghSelectedDevice = DllStructGetData($tRIH, "hDevice") Then
            Device_Pressed()
        Else
            ;Different Device
            ConsoleWrite("Different Device Pressed" & @CRLF)
        EndIf
    EndIf

    Return $GUI_RUNDEFMSG ;Pass on to default winproc
EndFunc   ;==>WM_INPUT

Func EnumRawKeyboards($sDeviceNameMatch = "")
    ;Returns array of keyboard device IDs
    Local $tInfo, $aData = _WinAPI_EnumRawInputDevices()

    If IsArray($aData) Then
        Local $aKeyboards[$aData[0][0] + 1][4]

        ;'dword Size;dword Type;';'struct;dword KbType;dword KbSubType;dword KeyboardMode;dword NumberOfFunctionKeys;dword NumberOfIndicators;dword NumberOfKeysTotal;endstruc'
        Local $_tagRID_INFO_KEYBOARD = $tagRID_INFO_KEYBOARD

        If StringRight($_tagRID_INFO_KEYBOARD, 1) <> "t" Then $_tagRID_INFO_KEYBOARD &= "t" ; t is missing from endstruct

        Local $iCt = 0, $iSz
        Local $tInfo, $tDeviceName, $sDeviceName

        For $i = 1 To $aData[0][0]
            $tInfo = DllStructCreate($_tagRID_INFO_KEYBOARD)

            If _WinAPI_GetRawInputDeviceInfo($aData[$i][0], $tInfo, DllStructGetSize($tInfo), $RIDI_DEVICEINFO) And $aData[$i][1] = $RIM_TYPEKEYBOARD Then
                $iSz = _WinAPI_GetRawInputDeviceInfo($aData[$i][0], 0, 0, $RIDI_DEVICENAME) ;Get bytes needed
                $tDeviceName = DllStructCreate('wchar[' & $iSz + 1 & ']') ;Holds device name string

                If _WinAPI_GetRawInputDeviceInfo($aData[$i][0], $tDeviceName, DllStructGetSize($tDeviceName), $RIDI_DEVICENAME) Then
                    $sDeviceName = DllStructGetData($tDeviceName, 1)

                    If $sDeviceNameMatch <> "" And Not StringInStr($sDeviceName, $sDeviceNameMatch) Then ContinueLoop

                    $iCt += 1
                    $aKeyboards[$iCt][0] = $aData[$i][0] ;Handle
                    $aKeyboards[$iCt][1] = $aData[$i][1] ;Type
                    $aKeyboards[$iCt][2] = $sDeviceName
                    $aKeyboards[$iCt][3] = DllStructGetData($tInfo, "NumberOfKeysTotal")
                EndIf

            EndIf
        Next
        $aKeyboards[0][0] = $iCt ; Write count of keyboard devices to array
        ReDim $aKeyboards[$iCt + 1][4] ;Resize array
    EndIf
    Return $aKeyboards
EndFunc   ;==>EnumRawKeyboards

 The code is written in the console for the PS2-keyboard:

0х00010049
Different Device Pressed

 The code is written to the console via a USB keyboard:

0х280112C7
Device Pressed

 But this code does not determine which key is pressed.

 

How to make autoit script to define different keys "Q" ?

 

 If I press Q - on the PS2 keyboard - then Msgbox (or console) shows the message - "Key Q, PS2 Keyboard"
 If I press Q - on the USB keyboard - then Msgbox shows the message - "Key Q, USB Keyboard"

[Melba23]

Proton,

Please read this announcement before you post again.

M23

[Proton]

 

21 minutes ago, Proton said:

Then I want to ask a question.

This code responds to buttons on different keyboards.

https://www.autoitscript.com/forum/topic/193675-given-multiple-keyboards-determine-which-was-pressed/

 The code is written in the console for the PS2-keyboard:

0х00010049
Different Device Pressed

 The code is written to the console via a USB keyboard:

0х280112C7
Device Pressed

 But this code does not determine which key is pressed.

 

How to make autoit script to define different keys "Q" ?

 

 If I press Q - on the PS2 keyboard - then Msgbox (or console) shows the message - "Key Q, PS2 Keyboard"
 If I press Q - on the USB keyboard - then Msgbox shows the message - "Key Q, USB Keyboard"

Melba23, 

I understood.
 This is protection against hackers.

[Melba23]

Proton,

Quote

This is protection against hackers

No, this is to protect the reputation of AutoIt and is, as explained in the announcement, by direct command of the site owner and author of AutoIt.

M23

[careca]

See this bit and modify for your needs.

In this case, 0x0000000000010041 corresponds to my kb, change this to your kb, then press A to validate the conditions.

If _WinAPI_GetRawInputData($lParam, $tRIH, DllStructGetSize($tRIH), $RID_HEADER) And DllStructGetData($tRIH, "Type") = $RIM_TYPEKEYBOARD Then
        ;ConsoleWrite("0x" & Hex(DllStructGetData($tRIH, "hDevice")) & @CRLF)
        If $ghSelectedDevice = DllStructGetData($tRIH, "hDevice") Then
            ;ConsoleWrite("Device Pressed" & @CRLF)
        Else
            ;ConsoleWrite("Different Device Pressed" & @CRLF)
        EndIf
        If _ispressed('41') = 1 And DllStructGetData($tRIH, "hDevice") = 0x0000000000010041 Then
            ConsoleWrite('Yes A' &@CRLF)
        EndIf
    EndIf

 

Edited November 22, 2018 by careca

[Proton]

careca, Thanks you

[Aether]

I do not understand why someone would want to have 2 kbs on his desk.  But since you seem to insist, you could get the vkey from the rawinput like :

<snip>

That will get you all keys pressed/unpressed.  Flags : 0 = pressed / 1 = unpressed.

Edited November 23, 2018 by Melba23
Keylogger code removed

[Proton]

One more question.

This code temporarily freezes the key after it is activated.

If _ispressed('41') = 1 And DllStructGetData($tRIH, "hDevice") = 0x00010049 Then
            _BlockInputEx(3, "", "[a]")
             AdlibRegister("_Quit", 10000)
             MsgBox(64, 'Result', 'key А - PS2')
EndIf

How to prevent entering text from the keyboard (with handle number 0x00010049) from the moment the code is run ?

 

 

Edited November 23, 2018 by Proton