Mouse click plus UDF

[ibrahem]

Can anyone give me an example for _MouseClickPlus() UDF.. it doesn't work for me 😞

expandcollapse popup

;===============================================================================
;
; Function Name:  _MouseClickPlus()
; Version added:  0.1
; Description:    Sends a click to window, not entirely accurate, but works 
;                 minimized.
; Parameter(s):   $Window     =  Title of the window to send click to
;                 $Button     =  "left" or "right" mouse button
;                 $X          =  X coordinate
;                 $Y          =  Y coordinate
;                 $Clicks     =  Number of clicks to send
; Remarks:        You MUST be in "MouseCoordMode" 0 to use this without bugs.
; Author(s):      Insolence <insolence_9@yahoo.com>
;
;===============================================================================
Func _MouseClickPlus($Window, $Button = "left", $X = "", $Y = "", $Clicks = 1)
  Local $MK_LBUTTON       =  0x0001
  Local $WM_LBUTTONDOWN   =  0x0201
  Local $WM_LBUTTONUP     =  0x0202
  
  Local $MK_RBUTTON       =  0x0002   
  Local $WM_RBUTTONDOWN   =  0x0204
  Local $WM_RBUTTONUP     =  0x0205

  Local $WM_MOUSEMOVE     =  0x0200
  
  Local $i                = 0
  
  Select 
  Case $Button = "left"
     $Button     =  $MK_LBUTTON
     $ButtonDown =  $WM_LBUTTONDOWN
     $ButtonUp   =  $WM_LBUTTONUP
  Case $Button = "right"
     $Button     =  $MK_RBUTTON
     $ButtonDown =  $WM_RBUTTONDOWN
     $ButtonUp   =  $WM_RBUTTONUP
  EndSelect
  
  If $X = "" OR $Y = "" Then
     $MouseCoord = MouseGetPos()
     $X = $MouseCoord[0]
     $Y = $MouseCoord[1]
  EndIf
  
  For $i = 1 to $Clicks
     DllCall("user32.dll", "int", "SendMessage", _
        "hwnd",  WinGetHandle( $Window ), _
        "int",   $WM_MOUSEMOVE, _
        "int",   0, _
        "long",  _MakeLong($X, $Y))
        
     DllCall("user32.dll", "int", "SendMessage", _
        "hwnd",  WinGetHandle( $Window ), _
        "int",   $ButtonDown, _
        "int",   $Button, _
        "long",  _MakeLong($X, $Y))
        
     DllCall("user32.dll", "int", "SendMessage", _
        "hwnd",  WinGetHandle( $Window ), _
        "int",   $ButtonUp, _
        "int",   $Button, _
        "long",  _MakeLong($X, $Y))
  Next
EndFunc




Func _MakeLong($LoWord,$HiWord)
  Return BitOR($HiWord * 0x10000, BitAND($LoWord, 0xFFFF))
EndFunc

 

[BrewManNH]

What doesn't work, you didn't post your code?

[Nine]

well. I checked the list of the functions in user32.dll and SendMessage doesn't exist.

[Jos]

3 minutes ago, Nine said:

well. I checked the list of the functions in user32.dll and SendMessage doesn't exist.

Maybe you need to look again?  

https://docs.microsoft.com/en-us/windows/desktop/api/winuser/nf-winuser-sendmessage

Jos

Edited November 18, 2018 by Jos

[Nine]

strange i got SendMessageA, SendMessageW, but not SendMessage...

Maybe it is the tool that I used 

[Jos]

Doesn't matter, assume the UDF is correct for the moment and let the OP post something more than "it doesn't work" without any description or script.

Jos 

[Nine]

https://www.win7dll.info/user32_dll.html

http://www.softspecialists.com/library/genlib/vistasp1/user32.htm

 

[hawloong]

open notepad and use this code 

$Window = ControlGetHandle("Untitled - Notepad","","Edit1")
_MouseClickPlus($Window, "right",974, 776,1)

[Nine]

1 hour ago, hawloong said:

open notepad and use this code 

$Window = ControlGetHandle("Untitled - Notepad","","Edit1")
_MouseClickPlus($Window, "right",974, 776,1)

 

Working. You can use SendMessageA, SendMessageW AND SendMessage.  But I still do not understand why SendMessage is not reported as a valid function in user32.dll from all the tools I used and all the documents I found on the web. But nothing works with WinGetHandle tho !

Edited November 19, 2018 by Nine

[caramen]

Can someone lead me to the souce page of this UDF ? 

 

Dont find it here https://www.autoitscript.com/wiki/User_Defined_Functions

In pm or here .

1000 Thanks before. 

 

Edit: So you earn 1thanks  

Edited November 19, 2018 by caramen

[BrewManNH]

17 minutes ago, caramen said:

Can someone lead me to the souce page of this UDF ? 

https://github.com/pokerregion/pokerstars-autoit/blob/master/MouseClickPlus.au3 

I found what looks like the original version of this, although game hackers are using it on various different gaming sites.

[caramen]

I whould like to have an UDF like that. 

Seem like not working  

[BrewManNH]

2 minutes ago, caramen said:

Seem like not working

That's about as useless as the OP's post, what's not working and where is YOUR code?

[caramen]

#include <_MouseClickPlus.au3>

$Window = ControlGetHandle("[Active]","","Scintilla1")
_MouseClickPlus($Window, "left",974, 776,1)

This code is clicking random spot in SCitE

[caramen]

I have a sendmessage left mouseclick but i cant figure out how to manage the coord. i ll try more later i like that UDF 10 000% i have a lot of installation with mouseclick i was not able to controlclick. this is awesome...

@BrewManNH If you have somthing better   I TAKE

Edited November 19, 2018 by caramen

[BrewManNH]

That's because the function uses title of the window as the first parameter, you're sending it a handle of a control.

[caramen]

That's also a problem i ll try more later  

Remarks:        You MUST be in "MouseCoordMode" 0 to use this without bugs.

 

[ibrahem]

On ١٩‏/١١‏/٢٠١٨ at 1:43 AM, hawloong said:

open notepad and use this code 

$Window = ControlGetHandle("Untitled - Notepad","","Edit1")
_MouseClickPlus($Window, "right",974, 776,1)

Thanks! it is working 👌

Edited November 20, 2018 by ibrahem

[caramen]

Can you explain  ?

[Nine]

Finally found how to do it !

expandcollapse popup

#include <Constants.au3>
#include <WinAPISysWin.au3>
#include <WinAPIError.au3>
#include <WinAPIConv.au3>

_Main ()

Func _Main ()
Local $ctrl_handle

  Run ("notepad.exe")
  Local $hWnd = WinWaitActive ("[CLASS:Notepad]", "")

  Local $tPoint = DllStructCreate($tagPOINT)
  DllStructSetData($tPoint, "X", 500)
  DllStructSetData($tPoint, "Y", 500)

  _WinAPI_ScreenToClient ($hWnd, $tPoint)

  MsgBox (0,"Test",DllStructgetData($tPoint, "X") & "/" & DllStructGetData($tPoint, "Y"))

  Local $thWnd = $hWnd
  While True
    $ctrl_handle = _WinAPI_ChildWindowFromPointEx ($hWnd, $tPOINT)
    if not $ctrl_handle then
      MsgBox (0,"Error","Failure in finding the child window")
      Exit
    endif
    if $ctrl_handle = $thWnd then ExitLoop
    $thWnd = $ctrl_handle
  Wend

  MsgBox (0,"Handle", $thWnd)

  _MouseClickPlus($thWnd, "right", DllStructgetData($tPoint, "X"), DllStructGetData($tPoint, "Y"), 1)

  $tPoint = 0

EndFunc

Func _MouseClickPlus($hWnd, $sButton = 'left', $vX = '', $vY = '', $iClicks = 1)
    Local $MK_LBUTTON = 0x0001
    Local $WM_LBUTTONDOWN = 0x0201
    Local $WM_LBUTTONUP = 0x0202

    Local $MK_RBUTTON = 0x0002
    Local $WM_RBUTTONDOWN = 0x0204
    Local $WM_RBUTTONUP = 0x0205

    Local $WM_MOUSEMOVE = 0x0200

    If $sButton = 'left' Then
        $Button = $MK_LBUTTON
        $ButtonDown = $WM_LBUTTONDOWN
        $ButtonUp = $WM_LBUTTONUP
    ElseIf $sButton = 'right' Then
        $Button = $MK_RBUTTON
        $ButtonDown = $WM_RBUTTONDOWN
        $ButtonUp = $WM_RBUTTONUP
    EndIf

    If $vX = "" Or $vY = "" Then
        $MouseCoord = MouseGetPos()
        $vX = $MouseCoord[0]
        $vY = $MouseCoord[1]
    EndIf

    Local $stPoint = _MakeLong($vX, $vY)

    Local $i = 0
    For $i = 1 To $iClicks
        _PostMessage($hWnd, $WM_MOUSEMOVE, 0, $stPoint)
        _PostMessage($hWnd, $ButtonDown, $Button, $stPoint)
        _PostMessage($hWnd, $ButtonUp, $Button, $stPoint)
    Next
EndFunc

Func _MakeLong($LoWord,$HiWord)
  Return BitOR($HiWord * 0x10000, BitAND($LoWord, 0xFFFF))
EndFunc

Func _PostMessage($hWnd, $iMsg, $iwParam, $ilParam)
  Local $aResult, $err
  $aResult = DllCall("User32.dll", "bool", "PostMessageA", "hwnd", $hWnd, "int", $iMsg, "int", $iwParam, "int", $ilParam)
  $err = _WinAPI_GetLastError ()
  if $err or not $aResult[0] then
    MsgBox (0,"Error","Access denied in post message with error " & $err)
    Exit
  endif
  Return $aResult[0]
EndFunc