To select item by sending letter in TreeView

[Belini]

In ListView I can send letters to select the row but with TreeView does not work, does anyone have a tip for me?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

Test()

Func Test()
    Local $treeview, $i, $letter[27]
    GUICreate("Treeview", 210, 420)
    $treeview = GUICtrlCreateTreeView(0, 0, 210, 420, BitOR($TVS_HASLINES, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)
    For $i = 1 To 26
        $letter[$i] = StringUpper(Chr(64 + $i))
        GUICtrlCreateTreeViewItem($letter[$i], $treeview)
    Next
    _GUICtrlTreeView_SelectItem($treeview, _GUICtrlTreeView_GetFirstItem($treeview))
    GUISetState()

    While 1
        For $i = 1 To 26
            Send($letter[$i]); select item when sending letter does not work
            sleep(100)
        Next
    WEnd
EndFunc   ;==>Test

 

Edited November 15, 2018 by Belini

[mLipok]

Letter enter Letter enter

... fast answer on smartphone 

Edited November 15, 2018 by mLipok

[Belini]

I tried using "ENTER" and it did not work too

While 1
        For $i = 1 To 26
            Send($letter[$i] & "{enter}")
            Sleep(100)
            Send("{" & $letter[$i] & "}")
            Send("{enter}")
        Next
    WEnd

 

[mLipok]

Did you try ControlSend ?

[Belini]

Yes I already tried ControlSend as well

ControlSend("Treeview", '', "SysTreeView32", $letter[$i])
sleep(100)
ControlSend("Treeview", '', "Treeview", $letter[$i])

 

Edited November 15, 2018 by Belini

[InnI]

@Belini

You need to use Sleep(1000) at least. Otherwise, treeview tries to find and highlight text instead of a letter, such as "ABC" item.

[Belini]

@Innl with sleep(1000) really worked but this time is too big, I will spend 26 seconds to search all letters of the alphabet, is there no way to do this search with sleep maximum of 200 milliseconds?

Edited November 15, 2018 by Belini

[InnI]

@Belini

This is a built-in implementation of manual search for SysTreeView32 from Microsoft.
For a quick search, use the functions to work with the treeview. For example

For $i = 1 To 26
    ControlTreeView("Treeview", "", $treeview, "Select", $letter[$i])
    sleep(11)
Next

 

[Belini]

@Innl this was what I needed, thanks for helping.

[Belini]

I spoke very early that it was working because it only selects if there is only one letter in each line, the alphabet was just an example and what I really need is to go to the first letter of the word on the line.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

Test_1()
Test_2()

Func Test_1()
    Local $treeview, $i, $Gui, $letter[27]
    $Gui = GUICreate("Treeview", 210, 420)
    $treeview = GUICtrlCreateTreeView(0, 0, 210, 420, BitOR($TVS_HASLINES, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)
    For $i = 1 To 26
        $letter[$i] = StringUpper(Chr(64 + $i))
        GUICtrlCreateTreeViewItem($letter[$i], $treeview)
    Next
    _GUICtrlTreeView_SelectItem($treeview, _GUICtrlTreeView_GetFirstItem($treeview))
    GUISetState()

    For $i = 1 To 26
        ControlTreeView("Treeview", "", $treeview, "Select", $letter[$i]); It works
        Sleep(11)
    Next
    GUIDelete($Gui)
EndFunc   ;==>Test_1

Func Test_2()
    Local $treeview, $i, $Gui, $letter[27]
    $Gui = GUICreate("Treeview", 210, 420)
    $treeview = GUICtrlCreateTreeView(0, 0, 210, 420, BitOR($TVS_HASLINES, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)
    For $i = 1 To 26
        $letter[$i] = StringUpper(Chr(64 + $i))
        GUICtrlCreateTreeViewItem($letter[$i] & $i, $treeview)
    Next
    _GUICtrlTreeView_SelectItem($treeview, _GUICtrlTreeView_GetFirstItem($treeview))
    GUISetState()

    While 1
        For $i = 1 To 26
            ControlTreeView("Treeview", "", $treeview, "Select", $letter[$i]); Does not work
            Sleep(11)
        Next
    WEnd
EndFunc   ;==>Test_2

 

Edited November 16, 2018 by Belini

[Belini]

Duplicate sorry 

 

Edited November 16, 2018 by Belini

[InnI]

; full match
ControlTreeView("Treeview", "", $treeview, "Select", $letter[$i] & " Test")

; partial match (StringInStr used)
_GUICtrlTreeView_SelectItem($treeview, _GUICtrlTreeView_FindItem($treeview, $letter[$i] & " ", True))

; condition match (use any function to work with strings)
For $j = 0 To ControlTreeView("Treeview", "", $treeview, "GetItemCount") - 1
  $text = ControlTreeView("Treeview", "", $treeview, "GetText", "#" & $j)
  If StringLeft($text, 1) == $letter[$i] Then ; <= use your own condition
    ControlTreeView("Treeview", "", $treeview, "Select", $text)
    ExitLoop
  EndIf
Next

 

[Belini]

Now all is well, thanks again.