_GUICtrlListView_

[caramen]

Hello guys  , 

 

I am making a smal tool that i will share in the exemple forum. 

I was thinking about one thing. 

During 25 years i am usings computers everything have changed. Every single things exept one. The copy past fonction. 

I'm gonna make a tool to copy past yeah nothing new yet... The new function is just a simple idea. Keep track of all precedent pasted item to let them able to be selected to going back in the clipBoard. 

 

I am sure i t will be powerfull for all king of work. For everyone... 

I will share it opensource. 

Welll... Just a question. I am doing the code actualy. 

 

I searched in the help file. But i found only one thing to do my goal. 

I know _IsChecked 

I know _IsPressed 

Do we have similar function ? like _IsSelected ?

The purpose is simple. Select an item in my listView -> when the item is selected starting my condition. Or does i have to hard code it ?

 

 

Ah btw i found that : 

#include <GuiListView.au3>
_GUICtrlListView_GetItemState ( $hWnd, $iIndex, $iMask )

I guess it s the most apropriate ATM... any suggestion ?

Edited November 14, 2018 by caramen

[FrancescoDiMuro]

@caramen
I think that _GUICtrlListView_GetItemSelected() would be more appropriate

[caramen]

I watched... How i missed that one... 

 

Thx Francesco  

Edited November 14, 2018 by caramen

[FrancescoDiMuro]

[Subz]

Not to discourage but there are multiple clipboard managers already around example https://www.techspot.com/guides/1665-windows-clipboard-managers-tested/

[caramen]

Well

1-I do not made them

2-Thx that gave me the idea to add search function  .

3- good way to add new things

 

May you got an idea about what to add inside? 

If you guys help i ll add credit inside code. 

[caramen]

@FrancescoDiMuro

_GUICtrlListView_GetItemSelected Is not reacting as _IsPressed 

If i do : 

$Gui1 = GUICreate("CaraCopyPast" , 400 , 240)   
$ConsoleArea = GUICtrlCreateListView("___________________History__________________", 10 , 20 , 380 , 215 , $LVS_REPORT)
_GUICtrlListView_SetColumnWidth ($ConsoleArea , 0 , 800 )
_GUICtrlListView_SetExtendedListViewStyle($ConsoleArea, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState ( @SW_SHOW , $Gui1 )

    _GUICtrlListView_AddItem($ConsoleArea,"C'est parti !" )
    _GUICtrlListView_EnsureVisible($ConsoleArea, _GUICtrlListView_GetItemCount($ConsoleArea)-1)

While (1)
   $msg = GUIGetMsg ()
   Switch $msg
         Case $GUI_EVENT_CLOSE
            Exit
         Case _GUICtrlListView_GetItemSelected($ConsoleArea , 1 )
            $Textindex0 = _GUICtrlListView_GetItemText ( $ConsoleArea , 1 )
            MsgBox ( 0 ,  "" , "test réussi"&$Textindex0 )
         Case _GUICtrlListView_SetItemSelected($ConsoleArea , 1 )
            $Textindex0 = _GUICtrlListView_GetItemText ( $ConsoleArea , 1 )
            MsgBox ( 0 ,  "" , "test réussi"&$Textindex0 )
   EndSwitch
   Sleep (50)
WEnd

 

It spaming me "test réussi" in each case ( if i disable one the other is spaming too ) Without selecting the item.  

[Subz]

Look at _GUICtrlListView_Create and take note of WM_NOTIFY events

[caramen]

Well it s a function from the help file. Can you explain me the purpose ? 

 

[BrewManNH]

You're using _GUICtrlListview_GetItemSelected incorrectly. You can't put it into your message handler like that. Read the help file about the function, and what it returns. Comparing a true or false to a GUImsg value isn't what you want to do.

[caramen]

@BrewManNH

Yeah i changed that already. But is that better ? i still doing a check on true false. 

I should do something else? 

 

expandcollapse popup

Global $NextPaste , $tData , $sData

$Gui1 = GUICreate("CaraCopyPast" , 400 , 240)   
$ConsoleArea = GUICtrlCreateListView("___________________History__________________", 10 , 20 , 380 , 215 , $LVS_REPORT)
_GUICtrlListView_SetColumnWidth ($ConsoleArea , 0 , 800 )
_GUICtrlListView_SetExtendedListViewStyle($ConsoleArea, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState ( @SW_SHOW , $Gui1 )

;~ ==========================================Console============================================
                           _GUICtrlListView_AddItem($ConsoleArea,"C'est parti !" )
;~                         _GUICtrlListView_EnsureVisible($ConsoleArea, _GUICtrlListView_GetItemCount($ConsoleArea)-1)
;~ ==========================================/Console============================================
;~ ==========================================Console============================================
                           _GUICtrlListView_AddItem($ConsoleArea,"C'est fini !" )
;~                         _GUICtrlListView_EnsureVisible($ConsoleArea, _GUICtrlListView_GetItemCount($ConsoleArea)-1)
;~ ==========================================/Console============================================

$Height = @DesktopHeight - 250
$Width = @DesktopWidth - 300
$Height2 = @DesktopHeight - 20

Winmove ("CaraCopyPast" , "" , $Width , -20 , 300 , $Height2  )

While (1)
$ListIndex = _GUICtrlListView_GetItemCount ( $ConsoleArea )
$ListIndexCount = $ListIndex
   Do
   $Selected = _GUICtrlListView_GetItemSelected ( $ConsoleArea , $ListIndexCount )
   $ListIndexCount -= 1
      If $ListIndexCount = -1 Then
      $ListIndexCount = $ListIndex
      ExitLoop
      EndIf
   $WantedIndex = $ListIndexCount
   $NextPaste = _GUICtrlListView_GetItemText ( $ConsoleArea , $WantedIndex )
   Until $Selected = True
$msg = GUIGetMsg ()
   Switch $msg
      Case $GUI_EVENT_CLOSE
         Exit
   EndSwitch
   Sleep (50)
WEnd

Func Escape ()
   Exit
EndFunc

Func SendMyNewClipData ()
   Send ("^v")
EndFunc

Func Rechercher ()
   _GUICtrlListView_FindText
EndFunc

What do you think about this ? 

Edited November 14, 2018 by caramen

[Subz]

Why not use ClipGet/Put functions rather than send keys?

Here is example using WM_NOTIFY

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Global $g_hListView, $g_bListView = False, $g_iListView = ""
$Gui1 = GUICreate("CaraCopyPast" , 400 , 240)
$g_hListView = GUICtrlCreateListView("___________________History__________________", 10 , 20 , 380 , 215 , $LVS_REPORT)
_GUICtrlListView_SetColumnWidth ($g_hListview , 0 , 800 )
_GUICtrlListView_SetExtendedListViewStyle($g_hListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState ( @SW_SHOW , $Gui1 )

    _GUICtrlListView_AddItem($g_hListview,"C'est part1 !" )
    _GUICtrlListView_AddItem($g_hListview,"C'est part2 !" )
    _GUICtrlListView_AddItem($g_hListview,"C'est part3 !" )
    _GUICtrlListView_EnsureVisible($g_hListview, _GUICtrlListView_GetItemCount($g_hListview)-1)

    AdlibRegister("_ListView_Select")
    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While (1)
   $msg = GUIGetMsg ()
   Switch $msg
         Case $GUI_EVENT_CLOSE
            Exit
   EndSwitch
WEnd

Func _ListView_Select()
    If $g_bListView Then
        MsgBox(4096, "ListView Item Selected", _GUICtrlListView_GetItemText ($g_hListView, $g_iListView))
        $g_bListView = False
    EndIf
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    ; Local $tBuffer
    $hWndListView = $g_hListView
    If Not IsHWnd($g_hListView) Then $hWndListView = GUICtrlGetHandle($g_hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_COLUMNCLICK ; A column was clicked
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                    _DebugPrint("$LVN_COLUMNCLICK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Item:" & @TAB & DllStructGetData($tInfo, "Item") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->Param:" & @TAB & DllStructGetData($tInfo, "Param"))
                Case $LVN_KEYDOWN ; A key has been pressed
                    $tInfo = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    _DebugPrint("$LVN_KEYDOWN" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->VKey:" & @TAB & DllStructGetData($tInfo, "VKey") & @CRLF & _
                            "-->Flags:" & @TAB & DllStructGetData($tInfo, "Flags"))
                Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    $g_iListView = DllStructGetData($tInfo, "Index")
                    $g_bListView = True
                    _DebugPrint("$NM_CLICK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
                Case $NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _DebugPrint("$NM_DBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
                Case $NM_KILLFOCUS ; The control has lost the input focus
                    _DebugPrint("$NM_KILLFOCUS" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode)
                    ; No return value
                Case $NM_RCLICK ; Sent by a list-view control when the user clicks an item with the right mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _DebugPrint("$NM_RCLICK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ;Return 1 ; not to allow the default processing
                    Return 0 ; allow the default processing
                Case $NM_RDBLCLK ; Sent by a list-view control when the user double-clicks an item with the right mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _DebugPrint("$NM_RDBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
                Case $NM_RETURN ; The control has the input focus and that the user has pressed the ENTER key
                    _DebugPrint("$NM_RETURN" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode)
                    ; No return value
                Case $NM_SETFOCUS ; The control has received the input focus
                    _DebugPrint("$NM_SETFOCUS" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode)
                    ; No return value
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_Text, $sLine = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @CRLF & _
            "+======================================================" & @CRLF & _
            "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text & @CRLF & _
            "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint

 

[caramen]

I am using clipboard the code is just reproducer. 

Hmmm

I got it working by my way by using 

_GUICtrlListView_GetItemState

And loop until item stat is 1 but the fail is: it is always pasting item 0 

 

@Subz Mate ok i try it now.

Edited November 14, 2018 by caramen

[Subz]

Here is a better example

Double Left Click Item - Adds to Clipboard
Double Right Click Item - Deletes from Listview

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Global $g_hListView
$Gui1 = GUICreate("CaraCopyPast" , 400 , 440)
$g_hListView = GUICtrlCreateListView("___________________History__________________", 10 , 20 , 380 , 215 , $LVS_REPORT)
_GUICtrlListView_SetColumnWidth ($g_hListview , 0 , 800 )
_GUICtrlListView_SetExtendedListViewStyle($g_hListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUICtrlCreateEdit("Double Left Click to copy text to clipboard" & @CRLF & "Double Right Click to delete line item" & @CRLF, 10, 250, 380, 170)
GUISetState ( @SW_SHOW , $Gui1 )

    _GUICtrlListView_AddItem($g_hListview,"C'est part1 !" )
    _GUICtrlListView_AddItem($g_hListview,"C'est part2 !" )
    _GUICtrlListView_AddItem($g_hListview,"C'est part3 !" )
    _GUICtrlListView_EnsureVisible($g_hListview, _GUICtrlListView_GetItemCount($g_hListview)-1)

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While (1)
   $msg = GUIGetMsg ()
   Switch $msg
         Case $GUI_EVENT_CLOSE
            Exit
   EndSwitch
WEnd

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    ; Local $tBuffer
    $hWndListView = $g_hListView
    If Not IsHWnd($g_hListView) Then $hWndListView = GUICtrlGetHandle($g_hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _DebugPrint("$NM_CLICK" & @CRLF & _
                            _GUICtrlListView_GetItemText($g_hListView, DllStructGetData($tInfo, "Index")) & _
                            "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
                Case $NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    ClipPut(_GUICtrlListView_GetItemText($g_hListView, DllStructGetData($tInfo, "Index")))
                    _DebugPrint("$NM_DBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
                Case $NM_RDBLCLK ; Sent by a list-view control when the user double-clicks an item with the right mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _GUICtrlListView_DeleteItem($g_hListView, DllStructGetData($tInfo, "Index"))
                    _DebugPrint("$NM_RDBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_Text, $sLine = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @CRLF & _
            "+======================================================" & @CRLF & _
            "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text & @CRLF & _
            "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint

 

[caramen]

Woot i like 500%

Thanks

[caramen]

@Subz Adapted to my needs. Thank you. 

 

I whould like to know just for my understanding. Since i meet an error i dont solve with sucess. 

 

Can you help me figure out what is going wwrong here? 

 

While (1) ; my while
$ListIndex = _GUICtrlListView_GetItemCount ( $ConsoleArea )                                         ;counting number of row/items
MsgBox (0 , "" , $ListIndex )                                                                       ;Testing = OK
$ListIndexCount = $ListIndex                                                                        ;Adding new va$ so my initial var remain unchanged (needed for for...next but no more needed
MsgBox (0 , "" , $ListIndexCount )                                                                  ;Checking the value = OK
   Do                                                                                               ;Starting loop
   $Selected = _GUICtrlListView_GetItemState ( $ConsoleArea , $ListIndexCount , $LVIS_FOCUSED )     ;getting item stat inside a var
   MsgBox (0 , "" , $Selected )                                                                     ;Checking the value = OK
   $ListIndexCount -= 1                                                                             ;So i synchronise on the correct row. Based 0 = -1  
   MsgBox (0 , "" , $ListIndexCount )                                                               ;Checking = OK
      If $ListIndexCount = "-1" Then                                                                ;If i am under the index 0 then i restart checking all items. 
      $ListIndexCount = $ListIndex                                                                  ;Restarting index
      MsgBox (0 , "" , $ListIndexCount )                                                            ;Checking = OK
      ExitLoop                                                                                      ;Exiting loop if oh just figured i am exiting loop for no reson... 
      EndIf
   $WantedIndex = $ListIndexCount
   MsgBox (0 , "" , $WantedIndex )
   $NextPaste = _GUICtrlListView_GetItemText ( $ConsoleArea , $WantedIndex )
   MsgBox (0 , "" , $NextPaste )
   Until $Selected = "1"
MsgBox(0, "Test réussi", "Item 1 State: "&$Selected )
$msg = GUIGetMsg ()
   Switch $msg
      Case $GUI_EVENT_CLOSE
         Exit
   EndSwitch
   Sleep (50)
WEnd

 

Oh well while i am explaining my code i figure out where is my fail. 

I guess if i remove the exitloop my method will work. I ll try more tomorow. Thx all.

[caramen]

@Subz This code is realy realy powerfull and great... 

 

Do you understand everything ? To explain me how he did that ? 

[Subz]

WM_NOTIFY will monitor events for a particular control  and send that information back to the gui, please see the following for more information: https://docs.microsoft.com/en-us/windows/desktop/controls/wm-notify

Also I see in the other thread, you're trying to monitor Ctrl+C, it would be better to just monitor ClipPut for basic example below:

If you Ctrl+c or Right Click Copy the data will automatically appear in the listview, it only accepts strings.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Global $g_hListView, $g_sClipInfo = ""
$Gui1 = GUICreate("CaraCopyPast" , 400 , 440)
$g_hListView = GUICtrlCreateListView("___________________History__________________", 10 , 20 , 380 , 215 , $LVS_REPORT)
_GUICtrlListView_SetColumnWidth ($g_hListview , 0 , 800 )
_GUICtrlListView_SetExtendedListViewStyle($g_hListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUICtrlCreateEdit("Double Left Click to copy text to clipboard" & @CRLF & "Double Right Click to delete line item" & @CRLF, 10, 250, 380, 170)
GUISetState ( @SW_SHOW , $Gui1 )

    _GUICtrlListView_AddItem($g_hListview,"C'est part1 !" )
    _GUICtrlListView_AddItem($g_hListview,"C'est part2 !" )
    _GUICtrlListView_AddItem($g_hListview,"C'est part3 !" )
    _GUICtrlListView_EnsureVisible($g_hListview, _GUICtrlListView_GetItemCount($g_hListview)-1)

    AdlibRegister("_MonitorClip")
    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While (1)
   $msg = GUIGetMsg ()
   Switch $msg
         Case $GUI_EVENT_CLOSE
            Exit
   EndSwitch
WEnd

Func _MonitorClip()
    ;~ Check if ClipBoard data is a string
    If Not IsString(ClipGet()) Then Return
    ;~ Check if Clipboard string has already been processed
    If ClipGet() = $g_sClipInfo Then Return
    ;~ Assign Clipboard string to global variable
    $g_sClipInfo = ClipGet()
    ;~ Check to see data hasn't been added previously to the listview
    If _GUICtrlListView_FindText($g_hListView, $g_sClipInfo) = -1 And $g_sClipInfo <> "" Then _GUICtrlListView_AddItem($g_hListView, $g_sClipInfo)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    ; Local $tBuffer
    $hWndListView = $g_hListView
    If Not IsHWnd($g_hListView) Then $hWndListView = GUICtrlGetHandle($g_hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _DebugPrint("$NM_CLICK" & @CRLF & _
                            _GUICtrlListView_GetItemText($g_hListView, DllStructGetData($tInfo, "Index")) & _
                            "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
                Case $NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    ClipPut(_GUICtrlListView_GetItemText($g_hListView, DllStructGetData($tInfo, "Index")))
                    _DebugPrint("$NM_DBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
                Case $NM_RDBLCLK ; Sent by a list-view control when the user double-clicks an item with the right mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _GUICtrlListView_DeleteItem($g_hListView, DllStructGetData($tInfo, "Index"))
                    _DebugPrint("$NM_RDBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_Text, $sLine = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @CRLF & _
            "+======================================================" & @CRLF & _
            "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text & @CRLF & _
            "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint

 

[caramen]

58 minutes ago, Subz said:

it only accepts strings.

With CTRL  + C i can record JPG ? 

files ?

I am not here yet. I am finishing all functions

Subz you helped me too much i ll add you in the credits. After posting on exemple forum

Edited November 15, 2018 by caramen

[Subz]

But you can't add images/files to the listview, not really sure how you would handle files or images in clipboard.