Parse String based on multiple conditions to array

[Marnie]

Hello everyone,

 

I desperately need help with parsing the string.

"+" is delimiter, but "/" is telling you the number of variants 

Example of string (input): +AA1+BB1+CC1/CC2/CC3+DD4

Array should look like (output):  

 

 

Thanks

[FrancescoDiMuro]

@Marnie

What did you try so far?

[Marnie]

So far i have this and I am lost. It might be trivial ... how to proceed with For cycle and am I right at all ?

 

expandcollapse popup

#include <Array.au3>
#include <String.au3>

Global $word = "+AA1+BB1+CC1/CC2/CC3+DD4"

Local $positionSlash = StringInStr($word,"/")
if $positionSlash = 0 Then
   ConsoleWrite($word & @CRLF)
   ;pripadne arrayexplode podle +
Else
   Local $firstPart = StringMid($word,1,$positionSlash-1)
   Local $positionPlus = StringInStr($word,"+",0,1,$positionSlash)
   if $positionPlus = 0 Then
      Null
   Else
      Local $followingPart1 = StringMid($word,$positionPlus,4)
   EndIf
EndIf

ConsoleWrite($firstPart & $followingPart1)
ConsoleWrite($followingPart1)

Local $FirstView = _StringExplode($word,"+")

;let's split to array according "+" sign
_ArrayDisplay($FirstView)

;but how to proceed next - no idea ?


Local $DivideSlash = _StringExplode($FirstView[4],"/")
_ArrayDisplay($DivideSlash)

;StringRegExp($ZakladniBattle

For $i=1 to UBound($FirstView)
   ConsoleWrite(StringRegExp($FirstView[$i],"/",2))
Next

 

[iamtheky]

based off your input how did you infer there was a CC4 entry?

[Melba23]

Marnie,

And can you have multiple variants in the same line - such as: +AA1+BB1/BB2+CC1/CC2/CC3+DD4 ?

And if so, what is the required output?

M23

[Davidowicza]

Assuming that you cannot have multiple variants as @Melba23 has asked, (because that would just be a huge headache). This code should work, but may need some tweaking to fit into your script. Or if it does not work for what you want, it will point you in the right direction.

;but how to proceed next - no idea ?

; Trim any blank values in the array
; Move backwards through the array deleting the blank lines
For $i = UBound($FirstView) - 1 To 0 Step -1
    If $FirstView[$i] = "" Then
        _ArrayDelete($FirstView, $i)
    EndIf
Next

;Find where you need to duplicate and split that duplication into another array
for $x = 0 to UBound($FirstView)-1 Step 1
    if Not StringInStr($FirstView[$x], "/") = 0 Then
        $location = $x
        $aData = _StringExplode($FirstView[$x], "/")
        ExitLoop
    EndIf
Next

;Make a new array with bounds you have found
$col = UBound($FirstView)
$row = UBound($aData)
local $FinalArray[$row][$col]

;double for loop to fill in the array
For $x = 0 to UBound($FirstView)-1 Step 1
    for $t = 0 to UBound($aData)-1 Step 1
        if $x = $location Then
            $FinalArray[$t][$x] = $aData[$t]
        Else
            $FinalArray[$t][$x] = $FirstView[$x]
        EndIf
    Next
Next

_ArrayDisplay($FinalArray)

 

[Marnie]

38 minutes ago, iamtheky said:

based off your input how did you infer there was a CC4 entry?

sorry, that's a mistake

[Marnie]

33 minutes ago, Melba23 said:

Marnie,

And can you have multiple variants in the same line - such as: +AA1+BB1/BB2+CC1/CC2/CC3+DD4 ?

And if so, what is the required output?

M23

Yes, right. You can have multiple variants. In this case output would be look like this:

[Davidowicza]

If you use my code as a base, since it works with one variant, you should be able to add to it to look for multiple variants. It will be more complicated, but doable.

[mikell]

Funny challenge 

#Include <Array.au3>

$str = "+AA1/AA2/AA3+BB1/BB2+CC1/CC2/CC3/CC4+DD4"

$a = StringRegExp($str, '[^+]+', 3)
Local $aRes[0][UBound($a)], $string, $sRes

_LetsGo(0, "")

_ArrayAdd($aRes, StringTrimRight($sRes, 2))
_ArrayDisplay($aRes)


Func _LetsGo($k, $string)
    Local $tmp = StringSplit($a[$k], "/", 2)
    For $i = 0 to UBound($tmp) -1
        If $k = UBound($a) -1 Then
            $sRes &= $string & $tmp[$i] & @crlf
        Else
            _LetsGo($k + 1, $string & $tmp[$i]  & "|")
        EndIf
    Next
EndFunc

 

Edited November 14, 2018 by mikell
typo...

[Marnie]

2 minutes ago, mikell said:

Funny challenge 

#Include <Array.au3>

$str = "+AA1/AA2/AA3+BB1/BB2+CC1/CC2/CC3/CC4+DD4"

$a = StringRegExp($str, '[^+]+', 3)
Local $aRes[0][UBound($a)], $string = "", $sRes

_LetsGo(0, "")

_ArrayAdd($aRes, StringTrimRight($sRes, 2))
_ArrayDisplay($aRes)


Func _LetsGo($k, $string)
    Local $tmp = StringSplit($a[$k], "/", 2)
    For $i = 0 to UBound($tmp) -1
        If $k = UBound($a) -1 Then
            $sRes &= $string & $tmp[$i] & @crlf
        Else
            _LetsGo($k + 1, $string & $tmp[$i]  & "|")
        EndIf
    Next
EndFunc

 

Wow, thank you mate. Works like a charm