HotKeySet while the app window is active !!!

[AlienStar]

hello everybody 

I'm using HotKeySet  for ENTER but then I'm not able to use ENTER in other programs 

to solve I set it only when the windows is active but it failed 

$title = "hello"

$hGUI = GUICreate($title, 500, 500)

While 1
   $GUIMsg = GUIGetMsg()
   Select
   Case $GUIMsg = $GUI_EVENT_CLOSE
      Exit
   Case WinActive($GUI_ttl)= False
      HotKeySet("{ENTER}", "ENTER_KEY")
   EndSelect
WEnd


Func ENTER_KEY()
    Msgbox(0,"OK","Entered")
EndFunc

where is the wrong in my code ?

please help

Edited November 10, 2018 by AlienStar

[BrewManNH]

You can set it up using GUISetAccelerators instead of Hotkeys.

[AlienStar]

24 minutes ago, BrewManNH said:

You can set it up using GUISetAccelerators instead of Hotkeys.

here is the code I edit

$title = "hello"

$hGUI = GUICreate($title, 500, 500)

Local $aAccelKeys[1][1] = [["{ENTER}", ENTER_KEY()]]
GUISetAccelerators($aAccelKeys)

GUISetState(@SW_SHOW)

While 1
   $GUIMsg = GUIGetMsg()
   Select
   Case $GUIMsg = $GUI_EVENT_CLOSE
      Exit
   EndSelect
WEnd


Func ENTER_KEY()
    Msgbox(0,"OK","Entered")
 EndFunc

where is the wrong ?

the function ENTER_KEY() is executed without press ENTER !!!!

[BrewManNH]

Something like this (untested)

$title = "hello"

$hGUI = GUICreate($title, 500, 500)
$cDummy = GUICtrlCreateDummy()
Local $aAccelKeys[1][1] = [["{ENTER}", $cDummy]]
GUISetAccelerators($aAccelKeys, $hGUI)

GUISetState(@SW_SHOW)

While 1
    $GUIMsg = GUIGetMsg()
    Select
        Case $GUIMsg = $GUI_EVENT_CLOSE
            Exit
        Case $cDummy
            ENTER_KEY()
    EndSelect
WEnd


Func ENTER_KEY()
    MsgBox(0, "OK", "Entered")
EndFunc   ;==>ENTER_KEY

 

[AlienStar]

it sent me this error 

"C:\Users\Master\Desktop\New AutoIt v3 Script (14).au3" (12) : ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
Local $aAccelKeys[1][1] = [["{ENTER}", $cDummy]]
Local $aAccelKeys[1][1] = [["{ENTER}", ^ ERROR

 

[BrewManNH]

I told you it was untested, how are you going to fix it? Think of it as a learning experience.

 

I have included the corrected version that works right, but you should try to fix it for yourself first, minor problem in the code.

Spoiler

#include <GUIConstantsEx.au3>
$title = "hello"

$hGUI = GUICreate($title, 500, 500)
$cDummy = GUICtrlCreateDummy()
Local $aAccelKeys[1][2] = [["{ENTER}", $cDummy]]
GUISetAccelerators($aAccelKeys, $hGUI)

GUISetState(@SW_SHOW)

While 1
    $GUIMsg = GUIGetMsg()
    Select
        Case $GUIMsg = $GUI_EVENT_CLOSE
            Exit
        Case $GUIMsg = $cDummy
            ENTER_KEY()
    EndSelect
WEnd


Func ENTER_KEY()
    MsgBox(0, "OK", "Entered")
EndFunc   ;==>ENTER_KEY

 

 

[Nine]

you can do it like :

HotKeySet("{ENTER}", "ENTER_KEY")

You GUI code here

Func Enter_Key ()
if not WinActive($GUI_ttl) then
  HotKeySet("{ENTER}")
  Send ("{ENTER}")
  HotKeySet("{ENTER}", "ENTER_KEY")
endif
EndFunc

 

[BrewManNH]

1 minute ago, Nine said:

you can do it like

If you use accelerators, you don't have to.

[Nine]

1 minute ago, BrewManNH said:

If you use accelerators, you don't have to.

agree, that is 2 different ways to go...

[Bert]

I remember having to deal with this problem in an app of mine. I've used both solutions above and either one works well. 

[AlienStar]

finally it succeeded 

$cDummy = GUICtrlCreateDummy()
Local $aAccelKeys[2][2] = [["{ENTER}", $cDummy],["{ENTER}", $cDummy]]

GUISetAccelerators($aAccelKeys)

GUISetState(@SW_SHOW)

While 1
    $GUIMsg = GUIGetMsg()
    Select
        Case $GUIMsg = $GUI_EVENT_CLOSE
            Exit
        Case $GUIMsg = $cDummy
            ENTER_KEY()
    EndSelect
WEnd


Func ENTER_KEY()
    MsgBox(0, "OK", "Entered")
EndFunc   ;==>ENTER_KEY

but I don't know why it failed whit the array below !!

Local $aAccelKeys[1][1] = [["{ENTER}", $cDummy]]

 

[Nine]

4 minutes ago, AlienStar said:

but I don't know why it failed whit the array below !!

Local $aAccelKeys[1][1] = [["{ENTER}", $cDummy]]

because it only defines one cell and you declare 2 cells 

$aAccelKeys[1][2] = ... 

should work

[AlienStar]

4 hours ago, Nine said:

because it only defines one cell and you declare 2 cells 

$aAccelKeys[1][2] = ... 

should work

thanks so much it works