Serialize and Activate Windows 10 Ent - (Moved)

[jestoner]

Hello

I am trying to create a script that will serialize and activate Windows 10.  I have an enterprise license so all of my pcs have the same license.  I have gotten the script going and it gets to the "Enter a product key" screen and just stops.  I have tried the send command with the key, and it will not pass it to the screen, I have tried the ("^v")  command and it will not paste, although if I manually hit the ctrl-v it will paste.  This is just the first step in trying to get me a script that will completely finish my configuration process.  I have searched and searched for help but haven't found anything that works for me.  I do see that this group is very helpful with this stuff.  I appreciate any response.

[BrewManNH]

Wouldn't it be easier to just create an image once and then reimage the PCs as needed?

 

[Danp2]

Why not use slmgr.vbs instead of trying to automate a GUI?

[Melba23]

Moved to the appropriate forum.

Moderation Team

[AdamUL]

Here's a function that I wrote for our imaging script to activate windows with the product key stored in a file on a server share.  This allows us update the product key without having to recompile the script.  This uses slmgr.vbs, as Danp2 mentioned.  Edit the function to your needs.  

expandcollapse popup

Func _ActivateWin($sUserName, $sPassword, $sServerShare) ;Activate Windows, get activation code from the server.
    $sUserName = StringStripWS($sUserName, $STR_STRIPALL)
    If Not StringInStr($sUserName, "AD\") Then $sUserName = "AD\" & StringStripWS($sUserName, $STR_STRIPALL)

    Local $iPIDDli = Run("cscript c:\windows\system32\slmgr.vbs /dli", $sSystemDir, @SW_HIDE, $STDERR_MERGED) ;Check Windows Activation
    ProcessWaitClose($iPIDDli)
    Local $sDliOutput = StringStripWS(StdoutRead($iPIDDli), $STR_STRIPLEADING + $STR_STRIPTRAILING)
    If StringInStr($sDliOutput, "License Status: Licensed") Then Return True
    
    ;Find out Windows Version
    Local $sWinVersion = ""
    Switch @OSVersion
        Case "WIN_7"
            $sWinVersion = "7"
        Case "WIN_8"
            $sWinVersion = "8"
        Case "WIN_81"
            $sWinVersion = "81"
        Case "WIN_10"
            $sWinVersion = "10"
        Case Else 
            Return SetError(1, 0, False)
    EndSwitch   
    
    DriveMapDel($sServerShare)
    DriveMapAdd("", $sServerShare, 0, $sUserName, $sPassword)
    If @error Then Return SetError(Number("100" & @error), @extended, False)
    
    Local $sWinProductKeyFile = $sServerShare & "\Win" & $sWinVersion & "ProductKey.dat"
    Local $sWinProductKey = ""
    If FileExists($sWinProductKeyFile) Then
        $sWinProductKey = StringStripWS(FileRead($sWinProductKeyFile), $STR_STRIPALL)
    EndIf

    If $sWinProductKey <> "" And Not StringInStr($sDliOutput, StringRegExp($sWinProductKey, "-([A-Z1-9]{5})$", 1)) Then
        Local $iPIDIpk = Run("cscript c:\windows\system32\slmgr.vbs /ipk " & $sWinProductKey, $sSystemDir, @SW_HIDE, $STDERR_MERGED) ;Install Windows Product Key
        ProcessWaitClose($iPIDIpk)
        Local $sIpkOutput = StringStripWS(StdoutRead($iPIDIpk), $STR_STRIPLEADING + $STR_STRIPTRAILING)
        If Not StringInStr($sIpkOutput, "Installed product key " & $sWinProductKey & " successfully.") Then Return SetError(2, 0, False)
    EndIf

    Local $iPIDAto = Run("cscript c:\windows\system32\slmgr.vbs /ato", $sSystemDir, @SW_HIDE, $STDERR_MERGED) ;Activate Windows Product Key
    ProcessWaitClose($iPIDAto)
    Local $sAtoOutput = StringStripWS(StdoutRead($iPIDato), $STR_STRIPLEADING + $STR_STRIPTRAILING)
    If StringInStr($sAtoOutput, "Error: 0xC004C020 The activation server reported that the Multiple Activation Key has exceeded its limit") Then Return SetError(3, 0, False)
    If Not StringInStr($sAtoOutput, "Product activated successfully") Then Return SetError(4, 0, False)

    Return True
EndFunc   ;==>_ActivateWin

 

Adam

 

[jestoner]

Thank you all for the input. I finally came up with a weird but successful approach to this.  I use an input box and paste the info manually.  Not ideal, but it is working for me.