SciTE - Lexer for console pane

[mLipok]

I work on some project for my client programs and I was in hope to use default SciLexer.dll as a my output window using this UDF:

 

I was searching for a list of lexer in SciTE.

This is what I found: https://foicica.com/scintillua/LexerList.html

Now I'm wondering:
Which lexer I should use to have the same highlighting style like in SciTE Console Panel ?

I mean I want to use above UDF to display text with this lexer setting: style.errorlist.X

Regards,
mLipok

 

 

Edited October 30, 2018 by mLipok

[Jos]

The SciTE-Lite only uses the lmAU3(LexAU3.cxx)  and lmErrorList (LexErrorList.cxx)  lexers. The last one does the lexing of the SciTE outputpane.

Jos
 

[mLipok]

I'm not so familiar with C++ project and with scintilla .

I ask by example:
I was trying to use KIP _SciLexer.au3  and _Sci_SetLexer()

Func Sci_SetLexer($Sci, $iLexer)
    Return SendMessage($Sci, $SCI_SETLEXER, $iLexer, 0)
EndFunc   ;==>Sci_SetLexer

But I think this is not good way or I miss something.

so... whether Output Pane is a Lexer which could be set by using SCI_SETLEXER ? If yes , then: Which lexer should I choose for this scenario ?

 

[Jos]

I loaded one of the found examples with this UDF and added this to use the Error lexer:

SendMessage($Sci, $SCI_SETLEXER, $SCLEX_ERRORLIST, 0)

I believe that is working but have not looked any further, so please share some sort of runnable script  that you want to work on that I can play with and modify as required.

Jos

Edited October 30, 2018 by Jos

[mLipok]

1 hour ago, mLipok said:

This is what I found: https://foicica.com/scintillua/LexerList.html

ah so this above link shows me a wrong path.

Proper const are in : SciLexer.h

For my little project I was suppose to use this lexer

#define SCLEX_HTML 4
#define SCLEX_XML 5
#define SCLEX_SQL 7
#define SCLEX_ERRORLIST 10
#define SCLEX_AU3 60
#define SCLEX_JSON 120
 

but I'm wondering where are INI ?

 

[Jos]

Not sure what you mean by ini?

[mLipok]

You know ... INI Files.

I know I was very short in my statement:

20 minutes ago, mLipok said:

but I'm wondering where are INI ?

So I try to be more specyfic, here I have very well know INI file called:    Tidy.ini

Quote

[ProgramSettings]
 * * *  Update Functions/Keywords/Macros/UDFs to Proper case
proper=1

 * * * Update Constants defined in the "constant Include files"
properconstants=1
 

I was asking about:    Which Lexer is valid to show content of INI files ?

 

[Jos]

1 hour ago, mLipok said:

Which Lexer is valid to show content of INI files

Ha... that is a clear question: I think it is SCLEX_PROPERTIES.

file.patterns.props=*.properties;*.session;*.ini;*.inf;*.url;*.cfg;*.cnf;*.aut

lexer.$(file.patterns.props)=props

So it's the LexProps.cxx.

Jos

[mLipok]

1 hour ago, Jos said:

I loaded one of the found examples with this UDF and added this to use the Error lexer:

SendMessage($Sci, $SCI_SETLEXER, $SCLEX_ERRORLIST, 0)

I believe that is working but have not looked any further, so please share some sort of runnable script  that you want to work on that I can play with and modify as required

Thanks.
Long time ago I ask @Kip if he have any update for:

I also asked him if I can take this project from him and maintain them.

I'm working on Rewrite Refactoring etc ...
I was go throught the forum and find many related UDF's example ....
I think It will take me maximum few days to publish new version.

 

[mLipok]

6 minutes ago, Jos said:

Ha... that is a clear question: I think it is SCLEX_PROPERTIES..... So it's the LexProps.cxx.

Thanks.

 

[mLipok]

Here is a good example:

 

[Jos]

I have build a script based on a download from Prog@ndy, modified for lexing the SciTEOutput like happens in SciTE.
Just add SciLexer.dll to the directory and run _Scilexer_Output.au3 to so an example output.

_SciLexer-SciTEOutput.zip

Jos

[mLipok]

Nice - works well, will look closer.

In a mean time I create this:

Func _Example_ERRORLIST($__g_pSciTE)
    #Tidy_ILC_Pos=100
    Sci_SetLexer($__g_pSciTE, $SCLEX_ERRORLIST)                                                    ; ErrorList
    Sci_StyleSet($__g_pSciTE, 4, _RGB2BGR(0x50A0FF), _RGB2BGR(0x272822), 1)                        ; Microsoft Error >>> AU3 CONSOLE PURPLE"
    Sci_StyleSet($__g_pSciTE, 10, _RGB2BGR(0xFF3020), _RGB2BGR(0x272822), 1, -1, 1)                ; diff changed !  >>> AU3 CONSOLE RED
    Sci_StyleSet($__g_pSciTE, 11, _RGB2BGR(0x00AF00), _RGB2BGR(0x272822), 1)                       ; diff addition + >>> AU3 CONSOLE GREEN
    Sci_StyleSet($__g_pSciTE, 12, _RGB2BGR(0xFF8F50), _RGB2BGR(0x272822), 1)                       ; diff deletion -  >>> AU3 CONSOLE ORANGE
    Sci_StyleSet($__g_pSciTE, 12, _RGB2BGR(0xFF8F50), _RGB2BGR(0x272822), 1)                       ; diff deletion -  >>> AU3 CONSOLE ORANGE
    Sci_StyleSet($__g_pSciTE, 32, -1, _RGB2BGR(0x272822), 1)                                       ; line numbers in the margin
    Sci_StyleSet($__g_pSciTE, 33, _RGB2BGR(0x0000BB), _RGB2BGR(0xA0E0F0), 1)                       ; line numbers in the margin
    Local $sContent = @CRLF & _
            "! Red" & @CRLF & _
            "> Blue" & @CRLF & _
            "- Orange" & @CRLF & _
            "+ Green" & @CRLF & _
            ""
    Sci_AddLines($__g_pSciTE, $sContent, 0)

EndFunc   ;==>_Example_ERRORLIST

 

[Jos]

The example script files need to be further strippeddown to a bare minimum since it only needs to show output. 

[mLipok]

1 minute ago, Jos said:

The example script files need to be further strippeddown to a bare minimum since it only needs to show output. 

A very wise statement, but I do not know what you mean, does it mean I'm dumb ? 
**** self criticism ****

[Jos]

I meant that the example is too complex as it is based on a option to edit the script which is not needed for output lexing.
I started stripping the code and this is not the example that only needs _SciLexer.au3 to be included and all/most bloat is removed:

expandcollapse popup

;
; Script that demonstartes the scite output pane lexing
; Based on a script from Prog@ndy
#include "_SciLexer.au3"
;
Global Const $tagSCNotification = "hwnd hWndFrom;int IDFrom;int Code;" & _
        "int position;" & _ ;  // SCN_STYLENEEDED, SCN_DOUBLECLICK, SCN_MODIFIED, SCN_DWELLSTART, SCN_DWELLEND, SCN_CALLTIPCLICK, SCN_HOTSPOTCLICK, SCN_HOTSPOTDOUBLECLICK
        "int ch;" & _             ;// SCN_CHARADDED, SCN_KEY
        "int modifiers;" & _      ;// SCN_KEY, SCN_DOUBLECLICK, SCN_HOTSPOTCLICK, SCN_HOTSPOTDOUBLECLICK
        "int modificationType;" & _ ;// SCN_MODIFIED
        "ptr text;" & _  ;const char *text ;// SCN_MODIFIED, SCN_USERLISTSELECTION, SCN_AUTOCSELECTION
        "int length;" & _         ;// SCN_MODIFIED
        "int linesAdded;" & _     ;// SCN_MODIFIED
        "int message;" & _        ;// SCN_MACRORECORD
        "dword wParam;" & _      ;// SCN_MACRORECORD
        "dword lParam;" & _      ;// SCN_MACRORECORD
        "int line;" & _           ;// SCN_MODIFIED, SCN_DOUBLECLICK
        "int foldLevelNow;" & _   ;// SCN_MODIFIED
        "int foldLevelPrev;" & _  ;// SCN_MODIFIED
        "int margin;" & _         ;// SCN_MARGINCLICK
        "int listType;" & _       ;// SCN_USERLISTSELECTION, SCN_AUTOCSELECTION
        "int x;" & _              ;// SCN_DWELLSTART, SCN_DWELLEND
        "int y;"                  ;// SCN_DWELLSTART, SCN_DWELLEND

; define some initial test text for output lexing
Global $DefaultText = '>"C:\Program Files (x86)\AutoIt3\SciTE\..\AutoIt3.exe" "C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.au3" /Prod /AU3check /in "D:\Development\AutoIt3\programs\test\test.au3"' & @CRLF & _
        '+>15:42:49 Starting AutoIt3Wrapper v.18.708.1148.3 SciTE v.4.1.2.0   Keyboard:00020409  OS:WIN_10/  CPU:X64 OS:X64  Environment(Language:0413)  CodePage:0  utf8.auto.check:4' & @CRLF & _
        '+>         SciTEDir => C:\Program Files (x86)\AutoIt3\SciTE   UserDir => C:\Users\jvdza\AppData\Local\AutoIt v3\SciTE\AutoIt3Wrapper   SCITE_USERHOME => C:\Users\jvdza\AppData\Local\AutoIt v3\SciTE' & @CRLF & _
        '>Running AU3Check (3.3.14.5)  from:C:\Program Files (x86)\AutoIt3  input:D:\Development\AutoIt3\programs\test\test.au3' & @CRLF & _
        '"D:\Development\AutoIt3\programs\test\test.au3"(16,10) : error: ExitLoo(): undefined function.' & @CRLF & _
        'ExitLoo' & @CRLF & _
        '~~~~~~~^' & @CRLF & _
        'D:\Development\AutoIt3\programs\test\test.au3 - 1 error(s), 0 warning(s)' & @CRLF & _
        '+>15:42:49 AU3Check ended. Press F4 to jump to next error.rc:2' & @CRLF & _
        '->15:42:49 AU3Check ended. Press F4 to jump to next error.rc:2' & @CRLF & _
        '!>15:42:49 AU3Check ended. Press F4 to jump to next error.rc:2' & @CRLF & _
        '--->15:42:49 AU3Check ended. Press F4 to jump to next error.rc:2' & @CRLF & _
        '+>15:42:49 AutoIt3Wrapper Finished.' & @CRLF & _
        '>Exit code: 0    Time: 0.7428' & @CRLF

$Gui = GUICreate("SciOutput", 1200, 700)
$Sci = SCI_CreateEditorErr($Gui, 10, 10, 1180, 680, 0)
Sci_AddLines($Sci, $DefaultText, 0)

GUIRegisterMsg(0x004E, "MY_WM_NOTIFY")
GUISetState(@SW_SHOW)

While 1

    $Msg = GUIGetMsg(1)
    Switch $Msg[0]
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch

WEnd

Func MY_WM_NOTIFY($hWndGUI, $MsgID, $wParam, $lParam)
    Local $Return
    ; Add alll handlers like the following :)
    $Return = SCI_WM_NOTIFY($hWndGUI, $MsgID, $wParam, $lParam)
    If $Return <> 'GUI_RUNDEFMSG' Then Return $Return
    ; End Handler

    Return 'GUI_RUNDEFMSG'
EndFunc   ;==>MY_WM_NOTIFY


;modified by Jos for Outputpane
Func SCI_InitEditorErr($Sci)
    SendMessage($Sci, $SCI_SETLEXER, $SCLEX_ERRORLIST, 0)
    Local $bits = SendMessage($Sci, $SCI_GETSTYLEBITSNEEDED, 0, 0)
    SendMessage($Sci, $SCI_SETSTYLEBITS, $bits, 0)

    SendMessage($Sci, $SCI_SETTABWIDTH, 4, 0)
    SendMessage($Sci, $SCI_SETINDENTATIONGUIDES, True, 0)

    SendMessage($Sci, $SCI_SETMARGINTYPEN, $MARGIN_SCRIPT_NUMBER, $SC_MARGIN_NUMBER)
    SendMessage($Sci, $SCI_SETMARGINWIDTHN, $MARGIN_SCRIPT_NUMBER, SendMessageString($Sci, $SCI_TEXTWIDTH, $STYLE_LINENUMBER, "_99999"))

    SendMessage($Sci, $SCI_SETMARGINWIDTHN, $MARGIN_SCRIPT_ICON, 16)

    SendMessage($Sci, $SCI_AUTOCSETSEPARATOR, Asc(@CR), 0)
    SendMessage($Sci, $SCI_AUTOCSETIGNORECASE, True, 0)

    SetStyle($Sci, $STYLE_DEFAULT, 0x000000, 0xFFFFFF, 8, "Courier New")
    SendMessage($Sci, $SCI_STYLECLEARALL, 0, 0)

    SetStyle($Sci, $STYLE_BRACEBAD, 0x009966, 0xFFFFFF, 0, "", 0, 1)

    SetStyle($Sci, $SCE_ERR_DEFAULT, 0x000000, 0xFFFFFF)
    SetStyle($Sci, $SCE_ERR_PYTHON, 0x0000FF, 0xFFFFFF)
    SetStyle($Sci, $SCE_ERR_GCC, 0x8000ff, 0xFFFFFF)
    SetStyle($Sci, $SCE_ERR_MS, 0x0080ff, 0xFFFFFF, 0, "", 1)             ; used for errors in AU3CHECK/AutoIt3/Tidy

    SetStyle($Sci, $SCE_ERR_CMD, 0xFF0000, 0xFFFFFF, 0, "", 1, 1)

    SetStyle($Sci, $SCE_ERR_BORLAND, 0x0060B0, 0xFFFFFF, 0, "", 1)
    SetStyle($Sci, $SCE_ERR_PERL, 0x0000FF, 0xFFFFFF, 0, "", 1)
    SetStyle($Sci, $SCE_ERR_NET, 0x0000FF, 0xFFFFFF, 0, "", 1)
    SetStyle($Sci, $SCE_ERR_LUA, 0x0000FF, 0xFFFFFF, 0, "", 1)
    SetStyle($Sci, $SCE_ERR_CTAG, 0xFF00FF, 0xFFFFFF, 0, "", 1)

    SetStyle($Sci, $SCE_ERR_DIFF_CHANGED, 0x0000F7, 0xFFFFFF, 0, "", 1)    ;  9 !
    SetStyle($Sci, $SCE_ERR_DIFF_ADDITION, 0x007F00, 0xFFFFFF, 0, "", 1)   ; 10 +
    SetStyle($Sci, $SCE_ERR_DIFF_DELETION, 0x0088FF, 0xFFFFFF, 0, "", 1)   ; 11 -
    SetStyle($Sci, $SCE_ERR_DIFF_MESSAGE, 0x00007F, 0xFFFFFF, 0, "", 1)    ; 12 ---

    SetStyle($Sci, $SCE_ERR_PHP, 0xF000FF, 0xFFFFFF, 0, "", 0, 0)
    SetStyle($Sci, $SCE_ERR_ELF, 0xA00FF0, 0xFFFFFF, 0, "", 0, 1)
    SetStyle($Sci, $SCE_ERR_IFC, 0xFF0000, 0xFFFFFF, 0, "", 0, 1)
    SetStyle($Sci, $SCE_ERR_IFORT, 0x0000FF, 0xFFFFFF, 0, "", 1, 1)
    SetStyle($Sci, $SCE_ERR_ABSF, 0x0080FF, 0xFFFFFF, 0, "", 1, 1)
    SetStyle($Sci, $SCE_ERR_TIDY, 0x0080FF, 0xFFFFFF, 0, "", 1, 1)
    SetStyle($Sci, $SCE_ERR_JAVA_STACK, 0x0080FF, 0xFFFFFF, 0, "", 1, 1)

    If @error Then
        Return 0
    Else
        Return 1
    EndIf
EndFunc   ;==>SCI_InitEditorErr

Func SCI_CreateEditorErr($hWnd, $X, $Y, $W, $H, $RegisterWM_NOTIFY = True) ; The return value is the hwnd of the window, and can be used for Win.. functions
    Local $Sci = SCI_CreateEditor($hWnd, $X, $Y, $W, $H)
    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    SCI_InitEditorErr($Sci)
    If @error Then
        Return SetError(2, 0, 0)
    Else
        If $RegisterWM_NOTIFY = True Then GUIRegisterMsg(0x4E, "SCI_WM_NOTIFY")
        Return $Sci
    EndIf


EndFunc   ;==>SCI_CreateEditorErr

Func SCI_WM_NOTIFY($hWndGUI, $MsgID, $wParam, $lParam)
    #forceref $hWndGUI, $MsgID, $wParam
    Local $structNMHDR = DllStructCreate("hwnd hWndFrom;int IDFrom;int Code", $lParam) ; tagNMHDR
    Local $sClassName = DllCall("User32.dll", "int", "GetClassName", "hwnd", DllStructGetData($structNMHDR, 1), "str", "", "int", 512)
    $sClassName = $sClassName[2]
    If $sClassName <> "Scintilla" Then Return 'GUI_RUNDEFMSG'
    $structNMHDR = DllStructCreate($tagSCNotification, $lParam)
    If @error Then Return 'GUI_RUNDEFMSG'

    Local $hwndFrom = DllStructGetData($structNMHDR, 1)
    Local $idFrom = DllStructGetData($structNMHDR, 2)
    Local $event = DllStructGetData($structNMHDR, 3)
    Local $position = DllStructGetData($structNMHDR, 4)
    Local $ch = DllStructGetData($structNMHDR, 5)
    Local $modifiers = DllStructGetData($structNMHDR, 6)
    Local $modificationType = DllStructGetData($structNMHDR, 7)
    Local $char = DllStructGetData($structNMHDR, 8)
    Local $length = DllStructGetData($structNMHDR, 9)
    Local $linesAdded = DllStructGetData($structNMHDR, 10)
    Local $message = DllStructGetData($structNMHDR, 11)
    Local $uptr_t = DllStructGetData($structNMHDR, 12)
    Local $sptr_t = DllStructGetData($structNMHDR, 13)
    Local $Line = DllStructGetData($structNMHDR, 14)
    Local $foldLevelNow = DllStructGetData($structNMHDR, 15)
    Local $foldLevelPrev = DllStructGetData($structNMHDR, 16)
    Local $margin = DllStructGetData($structNMHDR, 17)
    Local $listType = DllStructGetData($structNMHDR, 18)
    Local $X = DllStructGetData($structNMHDR, 19)
    Local $Y = DllStructGetData($structNMHDR, 20)
    Local $Sci = $hwndFrom
    If Not IsHWnd($Sci) Then $Sci = HWnd($Sci)
;~  ConsoleWrite("lll" & _WinAPI_GetClassName($Sci) & @CRLF)
    Local $line_number = SendMessage($Sci, $SCI_LINEFROMPOSITION, $position, 0)
    Local $Word, $WordPos, $CurrentLine, $PreviousLine, $Tabs, $TabsAdd, $style, $CurrentPos, $pos, $Replace, $AllVariables, $AllVariablesSplit, $AllWords, $err, $Variable
    Switch $event
        Case $SCN_CALLTIPCLICK
        Case $SCN_CHARADDED
        Case $SCN_MARGINCLICK
        Case $SCN_SAVEPOINTREACHED
        Case $SCN_SAVEPOINTLEFT

    EndSwitch
    $structNMHDR = 0
    $event = 0
    $lParam = 0
    Return 'GUI_RUNDEFMSG'
EndFunc   ;==>SCI_WM_NOTIFY

 

[mLipok]

A ... you mean CleanUp and Refactoring.

 

[mLipok]

I was trying to use:
 

Func Sci_SetReadOnly($Sci, $bReadOnly)
    SendMessage($Sci, $SCI_SETREADONLY, $bReadOnly, 0)
    If @error Then Return SetError(@error, @extended, 0)
    Return 1
EndFunc   ;==>Sci_SetReadOnly

But SCI_SETREADONLY is blocking also SCI_ADDTEXT

I'm wondering how to set ReadOnly status only for end-user and still keep possibility to use SCI_ADDTEXT in the script ?
I mean I want to push new messages but block input for end-user.

 

[Jos]

I don't know but this probably should be a workaround: 

SendMessage($Sci, $SCI_SETREADONLY, 0, 0)
Sci_AddLines($Sci, $DefaultText, 0)
SendMessage($Sci, $SCI_SETREADONLY, 1, 0)

Jos

[mLipok]

Good point.