Read Numbers in a line and add them

[Vikramjeet]

I am reading a specific line in a log file. I need help to extract the numbers after specific text and then add these numbers. Another option would be to read the last 12 characters of the line, extract only numbers and then add them

 AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213

From this line I want to extract 12, 20 and 213 and then add them 12+20+213=245

1- I can read the last 12 characters, extract only numbers and then add them

2- I can read the text after 'TIM XON LIST' , extract only numbers and then add them

Thank you 

[iamtheky]

$str = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213"

msgbox(0, '' , Execute(StringRegExpReplace(stringmid($str , stringinstr($str , " " , 0 , -1) + 1) , "\D" , "+")))

 

[Melba23]

Vikramjeet,

Not difficult at all. What have YOU tried that has not worked?

M23

P.S. If you get stuck:

Spoiler

#include <StringConstants.au3>
#include <MsgBoxConstants.au3>

$sLine = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213 "
; Extract digits from the final 12 characters
$aRet = StringRegExp(StringRight($sLine, 12), "(\d+)", $STR_REGEXPARRAYGLOBALMATCH)
; Declare variable to hold total
$iTotal = 0
; Loop through the array to add the values
For $i = 0 To UBound($aRet) - 1
    $iTotal += $aRet[$i]
Next
; And here it is
MsgBox($MB_SYSTEMMODAL, "Total", $iTotal)

 

Edit:

iamtheky - nice!

Edited October 25, 2018 by Melba23

[FrancescoDiMuro]

@iamtheky

Global $strString = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213", _
       $arrResult, _
       $strNumbers = "", _
       $fltSum = 0.0


$arrResult = StringRegExp($strString, ".{1}(\d{2}).{1}(\d{2}).{1}(\d{3})", 1)

For $i = 0 To UBound($arrResult) - 1 Step 1
    If $i < UBound($arrResult) - 1 Then
        $strNumbers &= $arrResult[$i] & "+"
    Else
        $strNumbers &= $arrResult[$i]
    EndIf

    $fltSum += $arrResult[$i]
Next

ConsoleWrite("Sum of " & $strNumbers & " = " & $fltSum & @CRLF)

What do you think about?
Please, let me know

[Vikramjeet]

33 minutes ago, Melba23 said:

Vikramjeet,

Not difficult at all. What have YOU tried that has not worked?

M23

P.S. If you get stuck:

  Reveal hidden contents

#include <StringConstants.au3>
#include <MsgBoxConstants.au3>

$sLine = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213 "
; Extract digits from the final 12 characters
$aRet = StringRegExp(StringRight($sLine, 12), "(\d+)", $STR_REGEXPARRAYGLOBALMATCH)
; Declare variable to hold total
$iTotal = 0
; Loop through the array to add the values
For $i = 0 To UBound($aRet) - 1
    $iTotal += $aRet[$i]
Next
; And here it is
MsgBox($MB_SYSTEMMODAL, "Total", $iTotal)

 

Edit:

iamtheky - nice!

I was able to extract ALL numbers from the string. However i was not able to extract the specific numbers 

[Vikramjeet]

3 hours ago, iamtheky said:

$str = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213"

msgbox(0, '' , Execute(StringRegExpReplace(stringmid($str , stringinstr($str , " " , 0 , -1) + 1) , "\D" , "+")))

 

Many thanks iamtheky

[Vikramjeet]

3 hours ago, FrancescoDiMuro said:

@iamtheky

Global $strString = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213", _
       $arrResult, _
       $strNumbers = "", _
       $fltSum = 0.0


$arrResult = StringRegExp($strString, ".{1}(\d{2}).{1}(\d{2}).{1}(\d{3})", 1)

For $i = 0 To UBound($arrResult) - 1 Step 1
    If $i < UBound($arrResult) - 1 Then
        $strNumbers &= $arrResult[$i] & "+"
    Else
        $strNumbers &= $arrResult[$i]
    EndIf

    $fltSum += $arrResult[$i]
Next

ConsoleWrite("Sum of " & $strNumbers & " = " & $fltSum & @CRLF)

What do you think about?
Please, let me know

Thank you so much Francesco

[Malkey]

Another method.

Local $str = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213"
Local $sRet = StringRegExpReplace($str, ".+[A-Z](\d+)[A-Z](\d+)[A-Z](\d+)$", "\1 + \2 + \3")
; The RE pattern is anchored to the end of the string, "$".

MsgBox(0, 'Results', $sRet & " = " & Execute($sRet))

; Returns:-
;          12 + 20 + 213 = 245

 

[gruntydatsun]

looks like you're spoiled for choice today Vikramjeet

Local $string = "AX  123 26OCT   ABC 23   1800  UHS TIM XON LIST   A12B20C213"
Local $sum = 0

$array = StringRegExp($string,"A(\d*?)B(\d*?)C(\d*?)$",3)

for $element in $array
    $sum += $element
Next

msgbox(1,"SUM",$sum)