Prevent ScreenSaver to turn off monitor - SPI_SETBLOCKSENDINPUTRESETS

[mLipok]

I was searching for solution to "Prevent ScreenSaver".
I know this was disscused before, for example in the following topic's:

 

 

But today I was reading this:

https://docs.microsoft.com/en-us/windows/desktop/api/winuser/nf-winuser-systemparametersinfoa

Quote

SPI_SETBLOCKSENDINPUTRESETS 0x1027

Determines whether an application can reset the screensaver's timer by calling the SendInput function to simulate keyboard or mouse input. The uiParam parameter specifies TRUE if the screensaver will not be deactivated by simulated input, or FALSE if the screensaver will be deactivated by simulated input.

....
....
....

And I'm wondering if somebody could provide example how to use this parameter together with this:

https://docs.microsoft.com/en-us/windows/desktop/api/winuser/nf-winuser-sendinput

 

Regards,
mLipok

 

[Danyfirex]

You can use _WinAPI_SetThreadExecutionState.

Remarks say: This function does not stop the screen saver from executing.

 

But actually You could do this to prevent screen saver execution.

_WinAPI_SetThreadExecutionState(BitOR($ES_DISPLAY_REQUIRED, $ES_CONTINUOUS))

 

Saludos

[Bert]

do what I do to prevent the screensaver- open a YouTube video and give it focus. Have your script run in the background. Its messy but it works. 

[BigDaddyO]

I've been using this for years.  works great!  I'm sure I got it from this site, but I can't remember who posted it.

$aRet = DllCall('kernel32.dll', 'long', 'SetThreadExecutionState', 'long', 0x80000003)    ;Disable windows sleep mode by making it think it's playing a movie in full screen

$aRet=DllCall('kernel32.dll','long','SetThreadExecutionState','long',0x80000000)         ;Remove the always on so it will go to sleep
 

[mLipok]

Will check later. 

Going sleep.

 

[caramen]

Read the defaut stat of registry of the current user screen saver value,

Then put it at the defaut stat after script end. Does not working ?

Edited October 12, 2018 by caramen

[mLipok]

On 11.10.2018 at 4:11 PM, Danyfirex said:

You can use _WinAPI_SetThreadExecutionState.  Remarks say: This function does not stop the screen saver from executing.

But actually You could do this to prevent screen saver execution.
_WinAPI_SetThreadExecutionState(BitOR($ES_DISPLAY_REQUIRED, $ES_CONTINUOUS))

Confirmed as working.

[mLipok]

20 hours ago, BigDaddyO said:

I've been using this for years.  works great!  I'm sure I got it from this site, but I can't remember who posted it.

$aRet = DllCall('kernel32.dll', 'long', 'SetThreadExecutionState', 'long', 0x80000003)    ;Disable windows sleep mode by making it think it's playing a movie in full screen

$aRet=DllCall('kernel32.dll','long','SetThreadExecutionState','long',0x80000000)         ;Remove the always on so it will go to sleep
 

Works too.

 

[KaFu]

Works for years for me, adjust the sleep accordingly.

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=mm.exe
#AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

TraySetToolTip("Mousemove - Exit = WIN + ESC")
HotKeySet("#{ESC}", "_Exit") ; WIN + ESC

Local $i = 1
While Sleep(60 * 1000)
    $aPos = MouseGetPos()
    If $i = 1 Then
        $i = 0
        MouseMove($aPos[0], $aPos[1] + 1, 0)
    Else
        MouseMove($aPos[0], $aPos[1] - 1, 0)
        $i = 1
    EndIf
WEnd

Func _Exit()
    Exit
EndFunc   ;==>_Exit

 

Edited October 12, 2018 by KaFu

[BigDaddyO]

looks like what Dannyfirex posted was really close to what I had.  I looked at the WinAPIProc.au3 and APIProcConstants.au3 and it's off by just a little.

it looks like using these 3 items will do the same as what I was using.
Global Const $ES_CONTINUOUS = 0x80000000
Global Const $ES_DISPLAY_REQUIRED = 0x00000002
Global Const $ES_SYSTEM_REQUIRED = 0x00000001

So do a BitOR on these 3 and it will be the 0x80000003

#include <WinAPIProc.au3>
_WinAPI_SetThreadExecutionState(BitOR($ES_CONTINUOUS, $ES_DISPLAY_REQUIRED, $ES_SYSTEM_REQUIRED))
 

I'll just keep using my direct DLL calls though since I know what they are.

[mLipok]

It look like yours version is more complementary than @Danyfirex solution which is not using $ES_SYSTEM_REQUIRED.

 

Edited October 12, 2018 by mLipok
typo

[mLipok]

On 11.10.2018 at 4:11 PM, Danyfirex said:

You can use _WinAPI_SetThreadExecutionState.

Remarks say: This function does not stop the screen saver from executing.

related content:

 

Edited October 12, 2018 by mLipok

[mLipok]

oh crap, again - forum makes surprises ... the URL link to post changed to URL link to Topic ...... fixed/edited previous post.

 

Edited October 12, 2018 by mLipok

[mLipok]

Finally I end with this following example:

#include <MsgBoxConstants.au3>
#include <WinAPIProc.au3>

_Example()

Func _Example()
    ; disable ScreenSaver and other windows sleep features
    _WinAPI_SetThreadExecutionState(BitOR($ES_DISPLAY_REQUIRED, $ES_CONTINUOUS, $ES_SYSTEM_REQUIRED, $ES_AWAYMODE_REQUIRED))
    MsgBox($MB_OK, 'Testing', 'Close this tester window when you be sure that your ScreeSaver not runing.')

    ; back to normal windows behavior
    _WinAPI_SetThreadExecutionState($ES_CONTINUOUS)
EndFunc   ;==>_Example

Already added to HelpFile - should be available along with one of the future versions of AutoIt.

[Danyfirex]

This part from remarks 

"This function does not stop the screen saver from executing."

It was wrong because it was obtained from Examples reference on MSDN. But It was refering to the C++ example witch use (ES_CONTINUOUS | ES_SYSTEM_REQUIRED | ES_AWAYMODE_REQUIRED) as it was not using ES_DISPLAY_REQUIRED is not resetting the display idle timer.

 

Saludos

 

[mLipok]

Could you provied link ?

[Danyfirex]

https://docs.microsoft.com/en-us/windows/desktop/api/winbase/nf-winbase-setthreadexecutionstate#examples

check the line above Examples It's what I mean. It says This function does not stop the screen saver from executing. referring to the Example with the parameters (ES_CONTINUOUS | ES_SYSTEM_REQUIRED | ES_AWAYMODE_REQUIRED).

Saludos

[Deye]

The others are legacy components thus :

$akeep = _WinAPI_SetThreadExecutionState(BitOR($ES_DISPLAY_REQUIRED, $ES_CONTINUOUS))
RunWait(@ComSpec & " /k powercfg -requests")
_WinAPI_SetThreadExecutionState($akeep)

Now as a full system component you get all the options + object queries using   _POWER_REQUEST

Deye

[junkew]

Turn numlock on off every n seconds will also prevent screensaver to come.

Send

send("{numlock on}")
send("{numlock off}")