Trouble Looping Script

[red0fireus]

Hello. So I have this code and It works when you run it once but I cant seem to get it to loop correctly so it runs without lagging my system or just loop in general. I know I need to put the loop somewhere around the $stdout but it doesn't seem to like it. This is probably really stupid but I'm really stumped and would appreciate help with this.

 

Thank you!

 

Basically I want it to check the service over and over again.

 

#RequireAdmin
Opt("TrayAutoPause",0)


$servicename = "dnscrypt-proxy"

$chrome = "chrome.exe"


$stdout = Run('sc.exe query ' & $servicename, '', @SW_HIDE, 2)
$data = _StdOut($stdout)

Func _StdOut($stdout)
    Local $data
    While 1
        $data = StdOutRead($stdout)
        If $data Then
            If StringInStr($data, 'Running') Then
                If ProcessExists($chrome) Then
                    run("cmd.exe /c sc stop dnscrypt-proxy", "", @SW_HIDE)
                EndIf
            ElseIf StringInStr($data, 'Stopped') Then
                If Not ProcessExists($chrome) Then
                    run("cmd.exe /c sc start dnscrypt-proxy", "", @SW_HIDE)
                EndIf
            EndIf
        Else
            Sleep(10)
        EndIf
    WEnd
EndFunc

 

Edited September 6, 2018 by red0fireus

[Gianni]

... maybe like this (not checked)

#RequireAdmin
Opt("TrayAutoPause",0)

$servicename = "dnscrypt-proxy"
$chrome = "chrome.exe"

While 1

    $data = "" ; empty $data
    $stdout = Run('sc.exe query ' & $servicename, '', @SW_HIDE, 2)
    Do; collect sc.exe process output
        $data &= StdOutRead($stdout) ; output goes to $data
    Until @error ; @error means that the process has terminated and has closed

    If StringInStr($data, 'Running') Then
        If ProcessExists($chrome) Then
            run("cmd.exe /c sc stop dnscrypt-proxy", "", @SW_HIDE)
        EndIf
    ElseIf StringInStr($data, 'Stopped') Then
        If Not ProcessExists($chrome) Then
            run("cmd.exe /c sc start dnscrypt-proxy", "", @SW_HIDE)
        EndIf
    EndIf

    Sleep(1000) ; one sec delay between next run of sc.exe

WEnd

 

Edited September 6, 2018 by Chimp
added $data = "" ; empty $data

[red0fireus]

Okay, that seems to work!

Thank you

[HankHell]

couldn't you also do something like this?

Func _StdOut($stdout)
    Local $data
    While 1
        $data = StdOutRead($stdout)
        If $data Then
            If StringInStr($data, 'Running') Then
                If ProcessExists($chrome) Then
                    run("cmd.exe /c sc stop dnscrypt-proxy", "", @SW_HIDE)
                EndIf
            ElseIf StringInStr($data, 'Stopped') Then
                If Not ProcessExists($chrome) Then
                    run("cmd.exe /c sc start dnscrypt-proxy", "", @SW_HIDE)
                EndIf
            EndIf
        Else
            Sleep(10)
        EndIf
            _StdOut() ;<-----
    WEnd
EndFunc

 

Edited September 6, 2018 by HankHell

[markyrocks]

6 hours ago, HankHell said:

couldn't you also do something like this?

Func _StdOut($stdout)
    Local $data
    While 1
        $data = StdOutRead($stdout)
        If $data Then
            If StringInStr($data, 'Running') Then
                If ProcessExists($chrome) Then
                    run("cmd.exe /c sc stop dnscrypt-proxy", "", @SW_HIDE)
                EndIf
            ElseIf StringInStr($data, 'Stopped') Then
                If Not ProcessExists($chrome) Then
                    run("cmd.exe /c sc start dnscrypt-proxy", "", @SW_HIDE)
                EndIf
            EndIf
        Else
            Sleep(10)
        EndIf
            _StdOut() ;<-----
    WEnd
EndFunc

 

This is probably a bad idea.  you're calling _StdOut() with zero parameters,  even if you would add any value to that particular call it would never change.  For other parts of the script to update variable data this loop needs to exit eventually.   The only way this would even break is through like a hotkey press.  If you want to loop a function just 

While 1

Func()

Wend

Func Func()

;stuff to do

Endfunc

Obviously this would never break either but it's just an example 

Edited September 6, 2018 by markyrocks

[Gianni]

@HankHell, ok what @markyrocks sayd, and further more, what you should avoid there, is the use of the recursive call in that way.
If you call that function, AutoIt will quickly stop the execution of the script with a "recursion level has been exceeded" error to prevent a ruinous "stack/overflow" crash.

Have a look to the following link for more info about recursive calls: https://www.autoitscript.com/wiki/Recursion

Edited September 7, 2018 by Chimp