JSON Decode using AutoIT - (Moved)

[vpervenditti]

Im trying to decode a json string using this function:

Func json_decode($sJson)
   $oSC = ObjCreate("ScriptControl")
   $oSC.Language = "JScript"
   $oSC.AddCode("var obj = " & $sJson)
   If IsObj($oSC.Eval("obj")) Then
      Return $oSC.Eval("obj")
   Else
      Return False
   EndIf
EndFunc

So, for exemple, i try to decode this:

$test = '{"oksdd":true,"result":[{"ss":34}, {"sdes":"332"}]}'
$oUpdates = JSON_DECODE($test)

If i read "oksdd" it work:
 

$sText = $oUpdates.oksdd

But when i try to read 

$sText = $oUpdates.result.(0).ss

It fails. Why? How can I read that?

[Melba23]

Moved to the appropriate forum.

Moderation Team

[BigDaddyO]

Use this UDF, it's used by the WebDriver UDF so I know it's pretty awesome:  

 

[Gianni]

you could get values directly from within javascript using the ScriptControl itself:

Global $oSC = ObjCreate("ScriptControl")
$oSC.Language = "JScript"

$test = '{"oksdd":true,"result":[{"ss":34}, {"sdes":"332"}]}'
$oUpdates = json_decode($test)

ConsoleWrite($oSC.Eval('obj.oksdd') & @CRLF)
ConsoleWrite($oSC.Eval("obj.result[0].ss") & @CRLF)
ConsoleWrite($oSC.Eval("obj.result[1].sdes") & @CRLF)

Func json_decode($sJson)
    $oSC.AddCode("var obj = " & $sJson)
    If IsObj($oSC.Eval("obj")) Then
        Return $oSC.Eval("obj")
    Else
        Return False
    EndIf
EndFunc   ;==>json_decode

or, even better, by enabling a fetching of array items with a custom javascript function, say as example Array.Peek, as shown in this nice example by the good @genius257 (https://www.autoitscript.com/forum/topic/176731-autoit-javascript-roundtrip/?do=findComment&comment=1329179).

here a possible way:

Global $oSC = ObjCreate("ScriptControl")
$oSC.Language = "JScript"

; see here https://www.autoitscript.com/forum/topic/176731-autoit-javascript-roundtrip/?do=findComment&comment=1329179
$oSC.Eval("Array.prototype.Peek = function(i){return this[i];}"); enable fetching of array item with Array.Peek function

$test = '{"oksdd":true,"result":[{"ss":34}, {"sdes":"332"}]}'
$oUpdates = json_decode($test)

ConsoleWrite($oUpdates.oksdd & @CRLF) ; read oksdd

$myArray = $oUpdates.result ; get the 'map'

MsgBox(0,"Debug",  "there are " & $myArray.length & " elements in 'result'" & @CRLF & _
        $myArray.Peek(0).ss & @CRLF & _
        $myArray.Peek(1).sdes)

Func json_decode($sJson)
    $oSC.AddCode("var obj = " & $sJson)
    If IsObj($oSC.Eval("obj")) Then
        Return $oSC.Eval("obj")
    Else
        Return False
    EndIf
EndFunc   ;==>json_decode

 

[vpervenditti]

Oh, nice!

 

Thanks @Chimp!!