New Script

[careca]

Many times i copied to clipboard some code to test and i had to create a new au3 file, open it and paste the code in, with this script that's automatic.

#include <FileConstants.au3>

$NewAu3Path = @DesktopDir & '\NewAu3' & '.' & @HOUR & '.' & @MIN & '.' & @SEC & '.au3'
$NewAu3 = FileOpen($NewAu3Path, 2)
FileWrite($NewAu3, ClipGet())
FileClose($NewAu3)

Added current time to ensure the file has unique filename.

Edited August 20, 2018 by careca

[BrewManNH]

I wouldn't open it in Append mode, otherwise your "new script" will get written to the end of whatever is in that file already. Also, you could probably do a ShellExecute on your new script to open it in SciTE.

[JLogan3o13]

Just a suggestion; this might do better under the "Snippets" thread - it is the very definition of "short, reusable pieces of code"

[Simpel]

Hi.

This is my version. It starts with a hotkey in another tool I always have running:

#include <File.au3>
; define your pathes
Local $sDestinationPath = @DesktopDir
Local $sPathSciTE = ; FILL IN YOUR PATH HERE
; find the last test file
Local $aTestFiles = _FileListToArray($sDestinationPath, "test*.au3", $FLTA_FILES) ; search existing test*.au3
Local $sTestFiles = _ArrayToString($aTestFiles) ; make a string of it
$aTestFiles = StringRegExp($sTestFiles, "(?i)test(\d+)\.au3", $STR_REGEXPARRAYGLOBALMATCH) ; search all test*-files with digits between test and extension au3
For $i = 0 To UBound($aTestFiles) -1
    $aTestFiles[$i] = Number($aTestFiles[$i]) ; make them all to numbers
Next
_ArraySort($aTestFiles) ; sort them
Local $iLastNumber = $aTestFiles[UBound($aTestFiles) - 1] ; that is the highest number
; create the next test file
Local $sNewFile = $sDestinationPath & "\test" & $iLastNumber + 1 & ".au3" ; adding 1 to the last file
Local $File = FileOpen($sNewFile, $FO_OVERWRITE) ; open the file in overwrite mode
FileWrite($File, ClipGet()) ; put the clipboard inside
FileClose($File) ; close the file
; open the test file in SciTE
If Not WinExists("[CLASS:SciTEWindow]") Then ShellExecute($sPathSciTE) ; so all last opened tabs are opened too
While Not WinExists("[CLASS:SciTEWindow]")
    Sleep(100)
WEnd
RunWait('"' & $sPathSciTE & '" "' & $sNewFile & '"', $sDestinationPath, @SW_HIDE)

My test.au3 files are counted. This way I get the next file. And as @BrewManNH said it is opening SciTE directly.

Simpel

Edited August 20, 2018 by Simpel
code edited for "open test file"

[careca]

Thanks for input, i thought about snippets, but somehow it felt better here, but feel free to move it @JLogan3o13

@BrewManNH, yes, makes sense, now i added the current time in the filename to make it unique, thus not overwriting or appending anything, each file is unique in theory.

[Simpel]

Hi, I added another feature. If there are testX.au3 files (X is are digits) that is empty it will use this one:

#include <File.au3>
; define your pathes
Local $sDestinationPath = ; your path where these test files should be
Local $sPathSciTE = ; your path to SciTE
; find the last test file
Local $aTestFiles = _FileListToArray($sDestinationPath, "test*.au3", $FLTA_FILES) ; search existing test*.au3
Local $sTestFiles = _ArrayToString($aTestFiles) ; make a string of it
$aTestFiles = StringRegExp($sTestFiles, "(?i)test(\d+)\.au3", $STR_REGEXPARRAYGLOBALMATCH) ; search all test*-files with digits between test and extension au3
For $i = 0 To UBound($aTestFiles) -1
    $aTestFiles[$i] = Number($aTestFiles[$i]) ; make them all to numbers
Next
_ArraySort($aTestFiles) ; sort them
; find first empty file or get the last number + 1
Local $iNextNumber
For $i = 0 To UBound($aTestFiles) -1
    If FileGetSize($sDestinationPath & "\test" & $aTestFiles[$i] & ".au3") = 0 Then
        $iNextNumber = $aTestFiles[$i]
        ExitLoop
    EndIf
Next
If Not IsNumber($iNextNumber) Then $iNextNumber = $aTestFiles[UBound($aTestFiles) -1] + 1 ; that is the highest number + 1
; create the next test file
Local $sNewFile = $sDestinationPath & "\test" & $iNextNumber & ".au3"
Local $File = FileOpen($sNewFile, $FO_OVERWRITE) ; open the file in overwrite mode
FileWrite($File, ClipGet()) ; put the clipboard inside
FileClose($File) ; close the file
; open the test file in SciTE
If Not WinExists("[CLASS:SciTEWindow]") Then ShellExecute($sPathSciTE) ; that's for re-opening current opened files too before
While Not WinExists("[CLASS:SciTEWindow]")
    Sleep(100)
WEnd
RunWait('"' & $sPathSciTE & '" "' & $sNewFile & '"', $sDestinationPath, @SW_HIDE) ; now open that file

Simpel

[Danyfirex]

Hello. Proably you could also add a hotkey and detect topic name etc to organize all better.

 

 

Maybe You can get interested in this.

Probably I'll develop a firefox version too.

 

Saludos

[kcvinu]

Well, that's a very helpful program from the great talented programmer Danyfirex. Thanks a lot man.  

Its actually a blend of JavaScript & AutoIt. Superb !

Edited August 26, 2018 by kcvinu

[Simpel]

Just another small update:

#include <File.au3>
; define your pathes
Local $sDestinationPath = ; your path where these test files should be
Local $sPathSciTE = ; your path to SciTE
; find the last test file
Local $aTestFiles = _FileListToArray($sDestinationPath, "test*.au3", $FLTA_FILES) ; search existing test*.au3
Local $sTestFiles = _ArrayToString($aTestFiles) ; make a string of it
$aTestFiles = StringRegExp($sTestFiles, "(?i)test(\d+)\.au3", $STR_REGEXPARRAYGLOBALMATCH) ; search all test*-files with digits between test and extension au3
For $i = 0 To UBound($aTestFiles) -1
    $aTestFiles[$i] = Number($aTestFiles[$i]) ; make them all to numbers
Next
_ArraySort($aTestFiles) ; sort them
; find first empty file or get the last number + 1
Local $iNextNumber
For $i = 0 To UBound($aTestFiles) -1
    If FileGetSize($sDestinationPath & "\test" & $aTestFiles[$i] & ".au3") = 0 Then
        $iNextNumber = $aTestFiles[$i]
        ExitLoop
    EndIf
Next
If Not IsNumber($iNextNumber) Then $iNextNumber = $aTestFiles[UBound($aTestFiles) -1] + 1 ; that is the highest number + 1
; create the next test file
Local $sNewFile = $sDestinationPath & "\test" & $iNextNumber & ".au3"
Local $File = FileOpen($sNewFile, $FO_OVERWRITE) ; open the file in overwrite mode
Local $sCheck = "#AutoIt3Wrapper_AU3Check_Parameters=;-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7" ; commenting out all predefined checks inside ini
FileWrite($File, $sCheck & @CRLF & @CRLF & ClipGet()) ; put the clipboard inside
FileClose($File) ; close the file
; open the test file in SciTE
If Not WinExists("[CLASS:SciTEWindow]") Then ShellExecute($sPathSciTE) ; that's for re-opening current opened files too before
While Not WinExists("[CLASS:SciTEWindow]")
    Sleep(100)
WEnd
RunWait('"' & $sPathSciTE & '" "' & $sNewFile & '"', $sDestinationPath, @SW_HIDE) ; now open that file

If you have defined AU3Check_Parameter in AutoIt3Wrapper.ini then often you are confronted with a lot of AU3Check error messages (e.g. "variable not declared"). But often I only want to test the script and maybe adopt it later. So here I insert "#AutoIt3Wrapper_AU3Check_Parameters=;-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7" on top of the new file (look for the semicolon in the string). So no error messages of these types are fired. For further development delete the ";" inside that string or delete the whole line to go back to your own settings.

Simpel

[Simpel]

@Danyfirex, I tried your chrome extension and it worked like charme. I modified the AutoItCodeRunner this way:

expandcollapse popup

#include <String.au3>
#include <File.au3>
; define your pathes
Local $sDestinationPath = ; where do you want putted the files to - no trailing \
Local $sPathSciTE = ; path to SciTE

Local $sFileName = "CCR_" ; ChromeCodeRunner
Local $aFilename = _StringBetween(ClipGet(), ";Title: ", " - AutoIt ")
If IsArray($aFilename) Then
    $sFileName &= StringRegExpReplace($aFilename[0], '[ /:*?"<>|]', '_')
    ConsoleWrite($sFileName & @CRLF)
Else
    ; find the last test file
    Local $aTestFiles = _FileListToArray($sDestinationPath, "test*.au3", $FLTA_FILES) ; search existing test*.au3
    Local $sTestFiles = _ArrayToString($aTestFiles) ; make a string of it
    $aTestFiles = StringRegExp($sTestFiles, "(?i)test(\d+)\.au3", $STR_REGEXPARRAYGLOBALMATCH) ; search all test*-files with digits between test and extension au3
    For $i = 0 To UBound($aTestFiles) -1
        $aTestFiles[$i] = Number($aTestFiles[$i]) ; make them all to numbers
    Next
    _ArraySort($aTestFiles) ; sort them
    ; find first empty file or get the last number + 1
    Local $iNextNumber
    For $i = 0 To UBound($aTestFiles) -1
        If FileGetSize($sDestinationPath & "\test" & $aTestFiles[$i] & ".au3") = 0 Then
            $iNextNumber = $aTestFiles[$i]
            ExitLoop
        EndIf
    Next
    If Not IsNumber($iNextNumber) Then $iNextNumber = $aTestFiles[UBound($aTestFiles) -1] + 1 ; that is the highest number + 1
    $sFileName &= "test" & $iNextNumber
    ConsoleWrite($sFileName & @CRLF)
EndIf

; create the file
Local $sNewFile = $sDestinationPath & "\" & $sFileName & ".au3"
Local $File = FileOpen($sNewFile, $FO_OVERWRITE) ; open the file in overwrite mode
Local $sCheck = "#AutoIt3Wrapper_AU3Check_Parameters=;-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7" ; for all those cases variables are not declared etc.
FileWrite($File, $sCheck & @CRLF & @CRLF & ClipGet()) ; put the clipboard inside
FileClose($File) ; close the file
; open the file in SciTE
If Not WinExists("[CLASS:SciTEWindow]") Then ShellExecute($sPathSciTE) ; that's for re-opening current opened files too before
While Not WinExists("[CLASS:SciTEWindow]")
    Sleep(100)
WEnd
RunWait('"' & $sPathSciTE & '" "' & $sNewFile & '"', $sDestinationPath, @SW_HIDE) ; now open that file

Regards, Simpel