String Table To Array?

[toto22]

I have a string that look like this:

WIFI    13.8    26.59
BCRX    9.6    13.34
GTES    8.5    11.15
DFRG    5.9    33.02
GIL    5.5    12.08

How can I simply build an Array with it?
 

[Melba23]

toto22,

This seems to work:

#include <StringConstants.au3>
#include <Array.au3>

$sInput = "WIFI    13.8    26.59" & @CRLF & _
    "BCRX    9.6    13.34" & @CRLF & _
    "GTES    8.5    11.15" & @CRLF & _
    "DFRG    5.9    33.02" & @CRLF & _
    "GIL    5.5    12.08"

; Replace all spaces by "|"
$sInput = StringRegExpReplace($sInput, "\h+", "|")

ConsoleWrite($sInput & @CRLF)

; Split string on @CRLF
$aSplit_1 = StringSplit($sInput, @CRLF, $STR_ENTIRESPLIT)
; Split first line on "|"
$aSplit_2 = StringSplit($aSplit_1[1], "|")

; Create suitably sized array
Global $aArray[$aSplit_1[0]][$aSplit_2[0]]

; For each line
For $i = 1 To $aSplit_1[0]
    ; Split on "|"
    $aSplit_2 = StringSplit($aSplit_1[$i], "|")
    ; Fill array
    For $j = 1 To $aSplit_2[0]
        $aArray[$i - 1][$j - 1] = $aSplit_2[$j]
    Next
Next

; And here is the result
_ArrayDisplay($aArray, "", Default, 8)

M23

[toto22]

thank you for all of your work!

[Melba23]

toto22,

My pleasure as always.

M23