Progress Bar for Opening a file Excel

[Ilounah]

Hello! where should I start, if I want to have a Progress Bar while waiting for my File to be open, can I use WinWaitActive? Thanks,

[water]

Do you open the workbook using AutoIt?
How long does it take to open the workbook?

[Ilounah]

Hi @water Yes im using AutoIt to open my file, using my office desktop which is xp Excel 2007 it loads faster, then yesterday on my presentation with other co-manager they let me use the laptap win10  to present the project and opening of the file take some 45sec to open and I'm afraid someone will open it twice if it takes to long to open and it will have a Run time error due to 2 running files.

#include <Excel.au3>

$sFileName =  @TempDir & "\Stock Requisition Template.xlsm"
FileInstall("C:\Stock Requisition Template.xlsm", $sFileName, 1)
$oExcel = _Excel_Open(False) ; Open Excel invisible
$oExcel.AutomationSecurity = 1
$oWorkbook = _Excel_BookOpen($oExcel, $sFileName)
$oExcel = _Excel_Open(True)
ObjEvent($oWorkbook, "Workbook_")
$bExit = False

While 1 ; Wait until the workbook gets closed
    Sleep(10)
    If $bExit Then
        Sleep(500) ; Make sure that Excel has closed
        FileDelete($sFileName)
        Exit
    EndIf
WEnd

Func WorkBook_BeforeClose($bCancel)
    $bExit = True
 EndFunc

 

[water]

You could pop up a window before you open the workbook and close it when open.

#include <Excel.au3>

$sFileName =  @TempDir & "\Stock Requisition Template.xlsm"
FileInstall("C:\Stock Requisition Template.xlsm", $sFileName, 1)
$oExcel = _Excel_Open(False) ; Open Excel invisible
$oExcel.AutomationSecurity = 1
SplashTextOn("Stock Requisition", "Opening workbook: " & $sFileName) ; <== Display Text
$oWorkbook = _Excel_BookOpen($oExcel, $sFileName)
SplashOff() ; <== Remove Text 
; $oExcel = _Excel_Open(True) ; <== This statement is not needed as the Excel application is already running
$oExcel.Visible = True ; <== Make Excel visible again
ObjEvent($oWorkbook, "Workbook_")
$bExit = False

While 1 ; Wait until the workbook gets closed
    Sleep(10)
    If $bExit Then
        Sleep(500) ; Make sure that Excel has closed
        FileDelete($sFileName)
        Exit
    EndIf
WEnd

Func WorkBook_BeforeClose($bCancel)
    $bExit = True
 EndFunc

 

[Ilounah]

Thank's @water, It was working now , 5 store's are using it for test Run and check for errors before  they implemented on all branch 

[water]