Date Format change

[DigDeep]

Any guidance in getting the Date Format changed from YYYY-MM-DD to MM/DD/YYYY or DD/MM/YYYY?

Edited May 17, 2018 by DigDeep

[Andreik]

#include <Date.au3>

ConsoleWrite('Date in format DD/MM/YYYY: ' & DateFormat('2018-05-17',0) & @CRLF)
ConsoleWrite('Date in format MM/DD/YYYY: ' & DateFormat('2018-05-17',1) & @CRLF)

Func DateFormat($sDate, $iFormat)
    Local $aDate, $aTime
    _DateTimeSplit ($sDate, $aDate, $aTime)
    If $iFormat Then
        Return ((StringLen($aDate[2])=1)?('0' & $aDate[2]):($aDate[2])) & '/' & ((StringLen($aDate[3])=1)?('0' & $aDate[3]):($aDate[3])) & '/' & $aDate[1]
    Else
        Return ((StringLen($aDate[3])=1)?('0' & $aDate[3]):($aDate[3])) & '/' & ((StringLen($aDate[2])=1)?('0' & $aDate[2]):($aDate[2])) & '/' & $aDate[1]
    EndIf
EndFunc

 

[Zedna]

Or simple StringMid(), something like this:

 

; dd.mm.yyyy --> yyyy-mm-dd
Func dmy2ymd($date, $sep = '-')
    If $date == '' Then Return ''
    $ret = StringMid($date,7,4) & $sep & StringMid($date,4,2) & $sep & StringLeft($date,2)
;~  If StringLen($date) > 10 Then $ret &= StringMid($date,11) ; optionally including time
    Return $ret
EndFunc

 

[TheXman]

For more complex conversions or just for ease, you can use the _date_time_convert() UDF.   I found it in @Melba23's signature. 

; You can find the dtc.au3 file in the following link:
; https://www.autoitscript.com/forum/topic/154684-date_time_convert-bugfix-version-27-may-15/

#include <MyIncludes\DateTimeConvert\dtc.au3>

ConsoleWrite('Date in format DD/MM/YYYY: ' & _Date_Time_Convert('2018-05-17', 'yyyy-MM-dd', 'dd/MM/yyyy') & @CRLF)
ConsoleWrite('Date in format MM/DD/YYYY: ' & _Date_Time_Convert('2018-05-17', 'yyyy-MM-dd', 'MM/dd/yyyy') & @CRLF)

 

[DigDeep]

All great responses.

I just tried out with another way and works too. We can move the last ones as we want the format to be.

$Date = "2016-02-10"
MsgBox(0, '', StringRegExpReplace($Date, "(\d{4})-(\d{2})-(\d{2})", "${2}/${3}/${1}")) ; "${2}/${3}/${1}" = "${MM}/${DD}/${YYYY}"

Thanks all.

[mLipok]

here is good UDF:

 

EDIT: oops @TheXman pointed this already....

Edited May 17, 2018 by mLipok