How to check if EXE file is for 64 or 32 bit architecture ?

[mLipok]

I need to check if 7z.exe used in some project is version compiled for 64 or 32 bit.

Do you have any idea how to do this ? ... of course using AutoIt 

 

[Andreik]

$sPath = FileOpenDialog('Select exe',@ScriptDir,'Executable (*.exe)')
If $sPath Then MsgBox(0,'',BinaryType($sPath))

Func BinaryType($sPath)
    Local $aRet = DllCall('kernel32.dll','bool','GetBinaryType','str',$sPath,'dword*',0)
    If $aRet[0] Then
        Switch $aRet[2]
            Case 0
                Return 'SCS_32BIT_BINARY'
            Case 1
                Return 'SCS_DOS_BINARY'
            Case 2
                Return 'SCS_WOW_BINARY'
            Case 3
                Return 'SCS_PIF_BINARY'
            Case 4
                Return 'SCS_POSIX_BINARY'
            Case 5
                Return 'SCS_OS216_BINARY'
            Case 6
                Return 'SCS_64BIT_BINARY'
        EndSwitch
    EndIf
EndFunc

 

Edited May 7, 2018 by Andreik

[mLipok]

Here is my modified version:

$sPath = FileOpenDialog('Select exe', @ScriptDir, 'Executable (*.exe)')
If $sPath Then MsgBox(0, '', BinaryType($sPath))
If $sPath Then MsgBox(0, '_Is32BitExe', _Is32BitExe($sPath))
If $sPath Then MsgBox(0, '_Is64BitExe', _Is64BitExe($sPath))

Func BinaryType($sPath)
    Local $Type = DllStructCreate('dword lpBinaryType')
    DllCall('kernel32.dll', 'bool', 'GetBinaryType', 'str', $sPath, 'ptr', DllStructGetPtr($Type))
    Switch DllStructGetData($Type, 'lpBinaryType')
        Case 0
            Return 'SCS_32BIT_BINARY'
        Case 1
            Return 'SCS_DOS_BINARY'
        Case 2
            Return 'SCS_WOW_BINARY'
        Case 3
            Return 'SCS_PIF_BINARY'
        Case 4
            Return 'SCS_POSIX_BINARY'
        Case 5
            Return 'SCS_OS216_BINARY'
        Case 6
            Return 'SCS_64BIT_BINARY'
    EndSwitch
EndFunc   ;==>BinaryType

Func _Is32BitExe($sPath)
    Return StringInStr(BinaryType($sPath), 'SCS_32BIT_BINARY') <> 0
EndFunc   ;==>_Is32BitExe

Func _Is64BitExe($sPath)
    Return StringInStr(BinaryType($sPath), 'SCS_64BIT_BINARY') <> 0
EndFunc   ;==>_Is64BitExe