Jump to content

Reverse _NumberNumToName

TrashBoat
 Share

Recommended Posts

Deye Universalist

Deye

Posted
Posted

you need to download the above and keep it in same directory together with the UDF found in the link you posted

make sure you have included both udfs with your script testing  form i.e (#include <BigNum.au3> ) same for the other ..

Usage example: MsgBox(262144, "Test", _NumberNumToName(770))

TrashBoat Wayfarer

TrashBoat

Posted
  • Author
Posted (edited)

thats not what i asked for ...

i know what that udf does but i need it do it backwards from  SEVEN HUNDRED SEVENTY to 770

Edited by Melba23
Quote deleted
Deye Universalist

Deye

Posted
Posted (edited)

just to get you going, here is some quick sketch i came up with
note that its not clean nor fully tested ..

Edit: cleaned up a little more, let me know if some number fails to translate 

MsgBox(0, "", NameToNumber("two hundred thousand thirty six"))

Func NameToNumber($Number)
    Local $iString, $Num = StringSplit($Number, " ", 1), $aArray[4][10] = _
            [ _
            ['ten', 'eleven', 'twelve', 'thirteen', 'fourteen', 'fifteen', 'sixteen', 'seventeen', 'eighteen', 'nineteen'], _
            ['', '', 'hundred', 'thousand', '', '', '', '', '', ''], _
            ['', '', 'twenty', 'thirty', 'forty', 'fifty', 'sixty', 'seventy', 'eighty', 'ninety'], _
            ['', 'One', 'two', 'three', 'four', 'five', 'six', 'seven', 'eight', 'nine'] _
            ]
    For $i = $Num[0] To 1 Step -1
        For $a = 0 To 3
            For $b = 0 To 9
                If $Num[$i] = $aArray[$a][$b] Then
                    Switch $a
                        Case 3
                            $iString = $b & $iString
                        Case 2
                            If StringLen($iString) = 1 Then
                                $iString = $b & $iString
                            Else
                                $iString = $b & 0 & $iString
                            EndIf
                        Case 1
                            If $b - StringLen($iString) < 0 Then
                                For $k = 1 To $b
                                    $iString = 0 & $iString
                                Next
                            Else
                                For $k = 1 To $b - StringLen($iString)
                                    $iString = 0 & $iString
                                Next
                            EndIf
                        Case 0
                            If $b = 0 Then
                                $iString = 10 & $iString
                            Else
                                $iString = 1 & $b & $iString
                            EndIf
                    EndSwitch
                    ExitLoop 2
                EndIf
            Next
        Next
    Next
    Return $iString
EndFunc   ;==>NameToNumber

 

Edited by Deye
  • Moderators
Melba23 Universalist

Melba23

Posted
  • Moderators
Posted

TrashBoat,

When you reply, please use the "Reply to this topic" button at the top of the thread or the "Reply to this topic" editor at the bottom rather than the "Quote" button - responders know what they wrote and it just pads the thread unnecessarily. Thanks for your cooperation.

M23

 

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

  Reveal hidden contents

 

Deye Universalist

Deye

Posted
Posted

Updated the above code, let me know if some number still fails to translate ..

TrashBoat Wayfarer

TrashBoat

Posted
  • Author
Posted (edited)

@Deye It loops through every each member in the array to check if it matches right? so if i would add a case 4 for thousands how would that work? 

MsgBox(0, '', NameToNumber("one thousand seven hundred ninety three"))

Func NameToNumber($Number)
    Local $aArray[5][10] = _
            [ _
            ['ten', 'eleven', 'twelve', 'thirteen', 'fourteen', 'fifteen', 'sixteen', 'seventeen', 'eighteen', 'nineteen'], _
            ['', 'hundred', 'two hundred', 'three hundred', 'four hundred', 'five hundred', 'six hundred', 'seven hundred', 'eight hundred', 'nine hundred'], _
            ['', '', 'twenty', 'thirty', 'forty', 'fifty', 'sixty', 'seventy', 'eighty', 'ninety'], _
            ['', 'one', 'two', 'three', 'four', 'five', 'six', 'seven', 'eight', 'nine'], _
            ['one thousand', 'two thousand', 'three thousand', 'four thousand', 'five thousand', 'six thousand', 'seven thousand', 'eight thousand', 'nine thousand','ten thousand'] _
            ]

    $Num = StringSplit($Number, " ", 1)

    Local $iString

    For $i = $Num[0] To 1 Step -1
        For $a = 0 To 4
            For $b = 0 To 9
                If $Num[$i] = $aArray[$a][$b] Then
                    Switch $a
                        Case 4
                            If StringLen($iString) >= 2 Then
                            ElseIf StringLen($iString) >= 1 Then
                                $iString = 0 & 0 & $iString
                            Else
                                $iString = 0 & 0 & 0 & $iString
                            EndIf
                        Case 3
                            $iString = "," & $b & $iString
                        Case 2
                            If StringInStr($iString, ",") Then
                                If StringLen($iString) >= 1 Then
                                    $iString = $b & $iString
                                EndIf
                            Else
                                $iString = $b & 0 & 0 & $iString
                            EndIf
                        Case 1
                            If StringLen($iString) >= 2 Then
                            ElseIf StringLen($iString) >= 1 Then
                                $iString = 0 & $iString
                            Else
                                $iString = 0 & 0 & $iString
                            EndIf
                        Case 0
                            If StringInStr($iString, ",") Then
                                If $b = 0 Then
                                    $iString = 10 & $iString
                                Else
                                    $iString = 1 & $b & $iString
                                EndIf
                            Else
                                If $b = 0 Then
                                    $iString = 10 & $iString
                                Else
                                    $iString = 1 & $b & $iString
                                EndIf
                            EndIf
                    EndSwitch
                    ExitLoop 2
                EndIf
            Next
        Next
    Next
    Return StringReplace($iString, ",", "")
;~ Return $iString
EndFunc   ;==>NameToNumber

Edit: I added the thousands part to the array and took your case 1 because that's where it loops through hundreds so it should be the same with thousands and i added a extra zero in case 4 it seems to work so far

Edited by TrashBoat
Deye Universalist

Deye

Posted
Posted

Please try the above edited code, changed for adding in the thousands .. if it all worked well then we got it .. :D

  • Moderators
Melba23 Universalist

Melba23

Posted
  • Moderators
Posted (edited)

Hi,

A fun little challenge for a windy afternoon. Here is my suggestion: 

#include <StringConstants.au3>

Local $aMajorDivisions[3] = ["billion", "million", "thousand"]

Local $aDecades[10] = ["", "", "twenty", "thirty", "forty", "fifty", "sixty", "seventy", "eighty", "ninety"]
Local $aTens[10] = ["ten", "eleven", "twelve", "thirteen", "fourteen", "fifteen", "sixteen", "seventeen", "eighteen", "nineteen"]
Local $aUnits[10] = ["", "one", "two", "three", "four", "five", "six", "seven", "eight", "nine"]

; ###########################

; Example

Local $aInitialAmounts[] = ["One hundred and three billion five hundred and eleven million two hundred and thirteen thousand seven hundred and fifty five", _
                            "One hundred and three billion two hundred and thirteen thousand seven hundred and fifty five", _
                            "One hundred and three billion eleven million nineteen thousand and one", _
                            "Five hundred and thirteen thousand seven hundred and fifty five", _
                            "Five hundred and thirteen thousand"]

For $n = 0 To UBound($aInitialAmounts) - 1
    $sRet = _NumberStringToDigits($aInitialAmounts[$n])
    ConsoleWrite($aInitialAmounts[$n] & @CRLF & $sRet & @CRLF)
Next

; ###########################

Func _NumberStringToDigits($sInitialAmount)

    ; Remove any English "and"s
    $sWorkingAmount = StringReplace($sInitialAmount, " and ", " ")
    ; Initialise return
    $sFigures = ""

    For $i = 0 To 2
        ; Look for major division (billion, million, thousand)
        $iPos = StringInStr($sWorkingAmount, $aMajorDivisions[$i])
        If $iPos Then
            ; Get value of major division
            $sValue = StringMid($sWorkingAmount, 1, $iPos - 1)
            ; And parse it
            $sFigures &= _ParseHundred($sValue) & ","
            ; Strip to next division
            $sWorkingAmount = StringTrimLeft($sWorkingAmount, $iPos + StringLen($aMajorDivisions[$i]))
        Else
            ; No major division
            If $sFigures Then
                $sFigures &= "000,"
            EndIf
        EndIf
    Next
    ; Parse any remaining hundred value
    If $sWorkingAmount Then
        $sFigures &= _ParseHundred($sWorkingAmount)
    Else
        $sFigures &= "000"
    EndIf

    ; Strip any leading zeroes
    While StringLeft($sFigures, 1) = 0
        $sFigures = StringTrimLeft($sFigures, 1)
    WEnd

    Return $sFigures

EndFunc   ;==>_NumberStringToDigits

Func _ParseHundred($sMajorValue)

    ; Initialise return
    $sIntFigures = ""
    ; Initialise unit value
    $sUnits = ""

    ; Look for "hundred"
    $aSplit = StringSplit($sMajorValue, "hundred", $STR_ENTIRESPLIT)
    If @error Then
        ; Add "0" if no hundred
        $sIntFigures &= "0"
        ; Set unit value
        $sUnits = $sMajorValue
    Else
        ; Parse hundred value
        For $j = 1 To 9
            If StringInStr($aSplit[1], $aUnits[$j]) Then
                ; Add hundred value
                $sIntFigures &= $j
                ; Set unit value
                $sUnits = $aSplit[2]
                ExitLoop
            EndIf
        Next
    EndIf

    ; Parse unit value
    ; Look for 10-19
    For $j = 0 To 9
        If StringInStr($sUnits, $aTens[$j]) Then
            ; Add value
            $sIntFigures &= "1" & $j
            ExitLoop
        EndIf
    Next
    ; If not found then look for decades
    If $j > 9 Then
        For $j = 2 To 9
            If StringInStr($sUnits, $aDecades[$j]) Then
                ; Add value
                $sIntFigures &= $j
                ExitLoop
            EndIf
        Next
        If $j > 9 Then
            ; Add "0"  if no ten value
            $sIntFigures &= "0"
        EndIf
        ; Finally look for units
        For $j = 1 To 9
            If StringInStr($sUnits, $aUnits[$j]) Then
                ; Add value
                $sIntFigures &= $j
                ExitLoop
            EndIf
        Next
        ; Add "0" if no unit value
        If $j > 9 Then
            $sIntFigures &= "0"
        EndIf
    EndIf

    Return $sIntFigures

EndFunc   ;==>_ParseHundred

And the results: 

One hundred and three billion five hundred and eleven million two hundred and thirteen thousand seven hundred and fifty five
103,511,213,755
One hundred and three billion two hundred and thirteen thousand seven hundred and fifty five
103,000,213,755
One hundred and three billion eleven million nineteen thousand and one
103,011,019,001
Five hundred and thirteen thousand seven hundred and fifty five
513,755
Five hundred and thirteen thousand
513,000

M23

Edited by Melba23
Fixed leading zero problem - see below

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

  Reveal hidden contents

 

  • Moderators
Melba23 Universalist

Melba23

Posted
  • Moderators
Posted

TrashBoat,

I have commented my code fairly liberally - just ask if you need any further explanation.

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

  Reveal hidden contents

 

jchd Universalist

jchd

Posted
Posted (edited)

My take at both conversions. I rewrote _IntegerToText as the function mentionned above is buggy. 

Local $r, $n

For $i = 1 To 10
    $r = Random(0, 100000000000, 1)
    $n = Random(1, 2000, 1)
    ConsoleWrite("Range is " & $r & " .. " & $r + $n & @LF)
    For $j = 1 To $n
        _Check($r + $j)
    Next
Next

Func _Check($n)
    Local $s = _IntegerToText($n)
    Local $r = _TextToInteger($s)
    ConsoleWrite($r = $n ? "" : $n & " ERROR" & @LF)
EndFunc

Func _CheckDetail($n)
    ConsoleWrite($n & @LF)
    Local $s = _IntegerToText($n)
    ConsoleWrite($s & @LF)
    Local $r = _TextToInteger($s)
    ConsoleWrite($r & @LF)
    ConsoleWrite("-------------- " & ($r = $n ? "OK" : "ERROR") & @LF)
EndFunc

Func _IntegerToText($iNum)
    Local $aGroup3, $iGroup3, $iHundreds, $iTens, $iUnits, $iMultiple, $sText

    If IsString($iNum) Then $iNum = StringStripWS($iNum, 8)
    $iNum = Int($iNum)
    If $iNum = 0 Then
        Return 'zero'
    EndIf

    $iNum = StringRegExpReplace($iNum, '(\A\d{1,3}(?=(\d{3})+\z)|\d{3}(?=\d))', '\1 ')
    $aGroup3 = StringSplit($iNum, ' ', 2)

    Local Static $aWords = [ _
        ['', ' one', ' two', ' three', ' four', ' five', ' six', ' seven', ' eight', ' nine', ' ten', ' eleven', ' twelve', ' thirteen', ' fourteen', ' fifteen', ' sixteen', ' seventeen', ' eighteen', ' nineteen'], _
        ['', '', ' twenty', ' thirty', ' forty', ' fifty', ' sixty', ' seventy', ' eighty', ' ninety'], _
        ['', ' thousand', ' million', ' billion', ' trillion', ' quadrillion', ' quintillion'] _
    ]

    $sText = ''
    $iMultiple = UBound($aGroup3) - 1

    For $i = 0 To UBound($aGroup3) - 1
        $iGroup3 = Int($aGroup3[$i])
        If $iGroup3 = 0 Then
            $iMultiple -= 1
            ContinueLoop
        EndIf

        $iHundreds = Int($iGroup3 / 100)
        $iTens = Int(Mod($iGroup3, 100) / 10)
        $iUnits = Mod($iGroup3, 10)
        $iTwenty = $iTens * 10 + $iUnits


        Switch $iHundreds
            Case 2 To 9
                $sText &= $aWords[0][$iHundreds]
                ContinueCase
            Case 1
                $sText &= " hundred"
        EndSwitch
        If $iTwenty < 20 Then
            $sText &= $aWords[0][$iTwenty]
        Else
            $sText &= $aWords[1][$iTens] & $aWords[0][$iUnits]
        EndIf

        $sText &= $aWords[2][$iMultiple] & ($iMultiple < 2 ? "" : ($iGroup3 > 1 ? "s" : ""))
        $iMultiple -= 1
    Next

    Return StringStripWS($sText, 3)
EndFunc

Func _TextToInteger($sText)

    If IsString($sText) Then $sText = StringStripWS($sText, 8)

    Local Static $s0_9 = "zero|one|two|three|four|five|six|seven|eight|nine"
    Local Static $s10_19 = "ten|eleven|twelve|thirteen|fourteen|fifteen|sixteen|seventeen|eighteen|nineteen"
    Local Static $s20_27 = "twenty|thirty|forty|fifty|sixty|seventy|eighty|ninety"
    Local Static $s28_33 = "thousand|million|billion|trillion|quadrillion|quintillion"
    Local $aExpr = StringRegExp($sText, _
        "(?ix) (?(DEFINE) (?<Range0_9> " & $s0_9 & ") (?<Range10_19> " & $s10_19 & ") (?<Range20_27> " & $s20_27 & ") (?<Range28_33> " & $s28_33 & ") )" & _
        "(?:((?&Range0_9)?) (hundred))?   (?| ((?&Range20_27)) ((?&Range0_9)?) | ()? ((?&Range10_19)) | ()? ((?&Range0_9)) )?   ((?&Range28_33)?)", 3)
    Local Static $a0_19 = StringSplit($s0_9 & "|" & $s10_19, "|", 2)
    Local Static $a20_27 = StringSplit($s20_27, "|", 2)
    Local Static $a28_33 = StringSplit($s28_33, "|", 2)
    Local $iNumber, $iGroupNb, $idx, $iNbGroups = UBound($aExpr) / 9
    For $i = 0 To $iNbGroups - 1
        $iGroupNb = 0
        If $aExpr[9 * $i + 5] Then $iGroupNb = 100
        If $aExpr[9 * $i + 4] Then $iGroupNb *= _ArraySearch($a0_19, $aExpr[9 * $i + 4])
        $idx = _ArraySearch($a20_27, $aExpr[9 * $i + 6])
        If Not @error Then $iGroupNb += 10 * ($idx + 2)
        $idx = _ArraySearch($a0_19, $aExpr[9 * $i + 7])
        If Not @error Then $iGroupNb += $idx
        $idx = _ArraySearch($a28_33, $aExpr[9 * $i + 8])
        If Not @error Then $iGroupNb *= Int(1000 ^ ($idx + 1))
        $iNumber += $iGroupNb
    Next

    Return $iNumber
EndFunc

EDIT: forgot to mention that it's rather easy to add some decoration, like the word "and" or comma as separator of groups of 3 digits, all in both functions.

Edited by jchd
  Reveal hidden contents

This wonderful site allows debugging and testing regular expressions (many flavors available). An absolute must have in your bookmarks.
Another excellent RegExp tutorial. Don't forget downloading your copy of up-to-date pcretest.exe and pcregrep.exe here
RegExp tutorial: enough to get started
PCRE v8.33 regexp documentation latest available release and currently implemented in AutoIt beta.

SQLitespeed is another feature-rich premier SQLite manager (includes import/export). Well worth a try.
SQLite Expert (freeware Personal Edition or payware Pro version) is a very useful SQLite database manager.
An excellent eBook covering almost every aspect of SQLite3: a must-read for anyone doing serious work.
SQL tutorial (covers "generic" SQL, but most of it applies to SQLite as well)
A work-in-progress SQLite3 tutorial. Don't miss other LxyzTHW pages!
SQLite official website with full documentation (may be newer than the SQLite library that comes standard with AutoIt)

Malkey Universalist

Malkey

Posted
Posted (edited)

@TrashBoat
    "one million, two hundred and thirteen thousand, seven hundred and twenty-five" your script returns
    1213700

@Melba23
    "one million, two hundred and thirteen thousand, seven hundred and twenty-five" your script returns
    001,213,725

@jchd
    "one million, two hundred and thirteen thousand, seven hundred and twenty-five" your script returns
     1013925

And another one. 

#include <Array.au3> ; For _ArrayDisplay(), if used.

ConsoleWrite(_Text2Num("twenty") & @CRLF)                                    ; Returns  20
ConsoleWrite(_Text2Num("hundred") & @CRLF)                                   ; Returns 100
ConsoleWrite(_Text2Num("two thousand and eighteen", 0) & @CRLF)              ; Returns 2018  (Comma separator set ot "0")
ConsoleWrite(_Text2Num("A thousand, five hundred and thirty-seven") & @CRLF) ; Returns 1,537
ConsoleWrite(_Text2Num("Twelve billion, eight hundred and forty-four million, three hundred and thirteen thousand, seven hundred and twenty-five") & @CRLF) ; Returns 12,844,313,725
ConsoleWrite(_Text2Num("Million hundred and thirteen thousand, seven hundred and twenty-five") & @CRLF) ; Returns 1,113,725
ConsoleWrite(_Text2Num("A billion hundred eighty-one million, four hundred nine thousand hundred seventy-nine") & @CRLF) ; Returns 1,181,409,179


Func _Text2Num($Txt, $AddThousandsSep = 1)
    Local $sRet = "("
    Local $sD = "zero=+0,one=+1,two=+2,twen=+2,three=+3,thir=+3,for=+4,four=+4,fif=+5,five=+5,six=+6,seven=+7,eigh=+8,eight=+8,nine=+9," & _
            "ten=+10,teen=+10,eleven=+11,twelve=+12,ty=*10,hundred=*100,thousand=)*1000+(,million=)*1000000+(,billion=)*1000000000+("
    Local $sREP = StringTrimRight(StringRegExpReplace($sD, "=\)?[+*]\d+(\+\()?,?", "|"), 1)
    $Txt = StringRegExpReplace($Txt, "(?i)(^|a\h*|,\h*|ion\h*|and\h*)(?=hundred|thousand|million|billion)", "\1 one ") ; Add "one" infront of a hundred, etc., when absent.
    ;ConsoleWrite($Txt & @CRLF) ; View modified $Txt string.

    Local $aArr = StringRegExp($Txt, "(?i)" & $sREP, 3)
    For $i = 0 To UBound($aArr) - 1
        $sRet &= StringRegExpReplace($sD, "(?i)^.*" & $aArr[$i] & "=(\)?[+*]\d+(\+\()?).*$", "$1")
    Next
    ;ConsoleWrite($sRet & ")" & @CRLF) ; See string pre-executed.
    ;_ArrayDisplay($aArr)              ; See array from which the pre-executed string is formed.
    $iRet = Execute($sRet & ")")
    If $AddThousandsSep Then
        Return StringRegExpReplace($iRet, '(\d+?)(?=(\d{3})+\b)', '$1,') ; Add comma separators.
    Else
        Return $iRet
    EndIf
EndFunc   ;==>_Text2Num

 

Edited by Malkey
_Text2Num() modified to allow "a hundred", or just "hundred" to be read as" one hundred".
jchd Universalist

jchd

Posted
Posted
  On 5/7/2018 at 1:35 PM, Malkey said:

@jchd
    "one million, two hundred and thirteen thousand, seven hundred and twenty-five" your script returns
     1013925

Expand  

Maybe, but :
ConsoleWrite(_TextToInteger("one million two hundred thirteen thousand seven hundred twenty five") &@LF)
works fine. I said I didn't bother to handle "and", commas, dashes nor any other cosmetic variation. This isn't hard to add to my code.

BTW, nice code of yours.

  Reveal hidden contents

This wonderful site allows debugging and testing regular expressions (many flavors available). An absolute must have in your bookmarks.
Another excellent RegExp tutorial. Don't forget downloading your copy of up-to-date pcretest.exe and pcregrep.exe here
RegExp tutorial: enough to get started
PCRE v8.33 regexp documentation latest available release and currently implemented in AutoIt beta.

SQLitespeed is another feature-rich premier SQLite manager (includes import/export). Well worth a try.
SQLite Expert (freeware Personal Edition or payware Pro version) is a very useful SQLite database manager.
An excellent eBook covering almost every aspect of SQLite3: a must-read for anyone doing serious work.
SQL tutorial (covers "generic" SQL, but most of it applies to SQLite as well)
A work-in-progress SQLite3 tutorial. Don't miss other LxyzTHW pages!
SQLite official website with full documentation (may be newer than the SQLite library that comes standard with AutoIt)

  • Moderators
Melba23 Universalist

Melba23

Posted
  • Moderators
Posted (edited)
  On 5/7/2018 at 1:35 PM, Malkey said:

@Melba23
    "one million, two hundred and thirteen thousand, seven hundred and twenty-five" your script returns
    001,213,725

Expand  

Thanks for pointing that out - the algorithm does not do it any more as it now strips any leading zeroes.

M23

Edited by Melba23
Fixed quote

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

  Reveal hidden contents

 

Deye Universalist

Deye

Posted
Posted

Hi jchd,

_IntegerToText("18050152552")
"eighteen billions fifty millions hundred fifty two thousand five hundred fifty two"

 will it be easy to get it fixed to show:
"eighteen billion fifty million one hundred fifty two thousand five hundred fifty two"

Thanks

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share
Go to topic listing
×
×
  • Create New...