[REGEX] Phrase with comma at the end

[Terenz]

I need an help with StringRegExpReplace. I'll post a list of phrases and expected result:

My Word  --> My Word (nothing change)

My Word,  --> My Word (remove last comma if not followed by a word)

My Word,  --> My Word (remove last comma and every space after the comma if are not followed by a word)

My Word,AB  --> My Word,AB (allowed only if 2-letter char follow the comma, nothing change)

My Word, AB  --> My Word,AB (allowed since 2-letter char follow the comma but remove the space)

In synthesis, if there is a comma, need to follow to that comma 2-letter word, if there is a space after comma and follow the 2-letter rule remove it. If not follow this rule, remove everything after the comma

My Word, ABC --> My Word

My Word,ABC --> My Word

P.S. Isn't possible to have a situation with two commas in my test phrases, so at least is more "easy"

I think I was clear no? I'll hope  

Thanks

 

Edited May 2, 2018 by Terenz

[Malkey]

Try this.

Local $sTestStr = _
        "My Word" & @CRLF & _      ; --> My Word    (nothing change)
        "My Word," & @CRLF & _     ; --> My Word    (remove last comma if not followed by a word)
        "My Word, " & @CRLF & _    ; --> My Word    (remove last comma and every space after the comma if are not followed by a word)
        "My Word,AB" & @CRLF & _   ; --> My Word,AB (allowed only if 2-letter char follow the comma, nothing change)
        "My Word, AB" & @CRLF & _  ; --> My Word,AB (allowed since 2-letter char follow the comma but remove the space)
        "My Word, ABC" & @CRLF & _ ; --> My Word
        "My Word,ABC"              ; --> My Word

Local $s = StringRegExpReplace($sTestStr, "(?!,)\h+", "") ; Remove spaces following a coma,
$s = StringRegExpReplace($s, "(?im),([a-z]|.{3,})?$", "") ; Remove the coma and the following one letter, or, three or more characters to end of line.
ConsoleWrite($s & @CRLF)

 

[Terenz]

@Malkey

I didn't test it, I'll do it very soon. I have one line at time to process, not like your example, so maybe is possible to do everything in one pattern of the regex and not with 2 different passages?

Thanks

[jchd]

Try this:

Local $aTestStr = [ _
    "My Word", _       ; --> My Word    (nothing change)
    "My Word,", _      ; --> My Word    (remove last comma if not followed by a word)
    "My Word, ", _     ; --> My Word    (remove last comma and every space after the comma if are not followed by a word)
    "My Word,AB", _    ; --> My Word,AB (allowed only if 2-letter char follow the comma, nothing change)
    "My Word, AB", _   ; --> My Word,AB (allowed since 2-letter char follow the comma but remove the space)
    "My Word, ABC", _  ; --> My Word
    "My Word,ABC" _    ; --> My Word
]

For $s In $aTestStr
    $s = StringRegExpReplace($s, "(, *$|(?<=,) (?=[A-Z]{2}$)|, *[A-Z]{3,}$)", "")
    ConsoleWrite($s & @CRLF)
Next

 

[Malkey]

Thanks jchd for your clarity.

I experimented with your method.

; https://www.autoitscript.com/forum/topic/193797-regex-phrase-with-comma-at-the-end/?do=findComment&comment=1390114

Local $sREPattern = "(?im)(,\h*[A-Z]?$|,\h*[A-Z]{3,}$|(?<=,)\h+(?=[A-Z]{2}$))"
Local $sTestStr = _
        "My Word" & @CRLF & _       ; --> My Word    (nothing change)
        "My Word," & @CRLF & _      ; --> My Word    (remove last comma if not followed by a word)
        "My Word,  " & @CRLF & _    ; --> My Word    (remove last comma and every space after the comma if are not followed by a word)
        "My Word,AB" & @CRLF & _    ; --> My Word,AB (allowed only if 2-letter char follow the comma, nothing change)
        "My Word,  AB" & @CRLF & _  ; --> My Word,AB (allowed since 2-letter char follow the comma but remove the space)
        "My Word,  ABC" & @CRLF & _ ; --> My Word
        "My Word, A" & @CRLF & _    ; --> My Word
        "My Word,ABC"               ; --> My Word
Local $s = StringRegExpReplace($sTestStr, $sREPattern, "")
ConsoleWrite($s & @CRLF)
ConsoleWrite("---------------------" & @CRLF)

Local $aTestArray = [ _
        "My Word", _       ; --> My Word    (nothing change)
        "My Word,", _      ; --> My Word    (remove last comma if not followed by a word)
        "My Word,  ", _    ; --> My Word    (remove last comma and every space after the comma if are not followed by a word)
        "My Word,AB", _    ; --> My Word,AB (allowed only if 2-letter char follow the comma, nothing change)
        "My Word,  AB", _  ; --> My Word,AB (allowed since 2-letter char follow the comma but remove the space)
        "My Word,  ABC", _ ; --> My Word
        "My Word,  A", _   ; --> My Word
        "My Word,ABC" _    ; --> My Word
        ]
For $s In $aTestArray
    $s = StringRegExpReplace($s, $sREPattern, "")
    ConsoleWrite($s & @CRLF)
Next