Problem of copy the selected listview item

[youtuber]

when I copy this | copied in character

 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
Global $DoubleClicked = False

$Form1 = GUICreate("Form1", 259, 296, 192, 124)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
$ListV1 = GUICtrlCreateListView("ListView 1", 32, 32, 186, 182, -1, BitOR($LVS_EX_CHECKBOXES, $WS_EX_CLIENTEDGE))

For $i = 1 To 5
    GUICtrlCreateListViewItem("Item" & $i, $ListV1)
Next

GUISetState(@SW_SHOW)

While 1

    If $DoubleClicked Then
        DoubleClickFunc()
        $DoubleClicked = False
    EndIf

    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func DoubleClickFunc()
    MsgBox(64, "OK", "Double Clicked: " & GUICtrlRead(GUICtrlRead($ListV1)))
    ClipPut(GUICtrlRead(GUICtrlRead($ListV1)))
EndFunc   ;==>DoubleClickFunc

Func WM_NOTIFY($hWnd, $MsgID, $wParam, $lParam)
    Local $tagNMHDR, $event, $hwndFrom, $code
    $tagNMHDR = DllStructCreate("int;int;int", $lParam)
    If @error Then Return 0
    $code = DllStructGetData($tagNMHDR, 3)
    If $wParam = $ListV1 And $code = -3 Then $DoubleClicked = True
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

[Subz]

You can try:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
Global $DoubleClicked = False

$Form1 = GUICreate("Form1", 259, 296, 192, 124)
$ListV1 = GUICtrlCreateListView("ListView 1", 32, 32, 186, 182, -1, BitOR($LVS_EX_CHECKBOXES, $WS_EX_CLIENTEDGE))

For $i = 1 To 5
    GUICtrlCreateListViewItem("Item" & $i, $ListV1)
Next

GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func DoubleClickFunc($_iIndex)
    Local $sItemText = _GUICtrlListView_GetItemText($ListV1, $_iIndex)
    MsgBox(64, "OK", "Double Clicked: " & $sItemText)
    ClipPut($sItemText)
EndFunc   ;==>DoubleClickFunc

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    ; Local $tBuffer
    $hWndListView = $ListV1
    If Not IsHWnd($ListV1) Then $hWndListView = GUICtrlGetHandle($ListV1)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    DoubleClickFunc(DllStructGetData($tInfo, "Index"))
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

[kylomas]

Adapted from OP code...

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
Global $DoubleClicked = False

$Form1 = GUICreate("Form1", 259, 296, 192, 124)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
$ListV1 = GUICtrlCreateListView("ListView 1", 32, 32, 186, 182, -1, BitOR($LVS_EX_CHECKBOXES, $WS_EX_CLIENTEDGE))

For $i = 1 To 5
    GUICtrlCreateListViewItem("Item" & $i, $ListV1)
Next

GUISetState(@SW_SHOW)

While 1

    If $DoubleClicked Then
        DoubleClickFunc()
        $DoubleClicked = False
    EndIf

    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func DoubleClickFunc()
    MsgBox(64, "OK", "Double Clicked: " & _GUICtrlListView_GetItemTextString($ListV1, -1))
    ClipPut(_GUICtrlListView_GetItemTextString($ListV1, -1))
EndFunc   ;==>DoubleClickFunc

Func WM_NOTIFY($hWnd, $MsgID, $wParam, $lParam)
    Local $tagNMHDR, $event, $hwndFrom, $code
    $tagNMHDR = DllStructCreate("int;int;int", $lParam)
    If @error Then Return 0
    $code = DllStructGetData($tagNMHDR, 3)
    If $wParam = $ListV1 And $code = -3 Then $DoubleClicked = True
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

kylomas