Autoit Wrappers

guinness · March 15, 2012

ConsoleWrite(_MilesToKilometres(1) & @CRLF)
ConsoleWrite(_KilometresToMiles(1) & @CRLF)

Func _MilesToKilometres($iLength)
    Return $iLength * 1.609
EndFunc   ;==>_MilesToKilometres

Func _KilometresToMiles($iLength)
    Return $iLength * 0.6214
EndFunc   ;==>_KilometresToMiles

Edited March 15, 2012 by guinness

JLogan3o13 · March 15, 2012

ConsoleWrite(_Tracert("www.duckduckgo.com") & @CRLF)

Func _Tracert($sURL)
    Local $aReturn, $iPID = 0, $sOutput = ""

    ; -d = Do Not Resolve Host & -h Is The Number Of Hops.
    $iPID = Run(@ComSpec & " /c tracert " & "-d -h 1 " & $sURL, @SystemDir, @SW_HIDE, 2 + 4)
    While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then
            ExitLoop
        Endif
    WEnd
    $aReturn = StringRegExp($sOutput, '[(.*)]', 3)
    If @error Then
        Return SetError(1, 0, -1)
    EndIf
    Return $aReturn[0]
EndFunc   ;==>_Tracert

If the SRE can be improved or there's an error with it then by all means please let me know.

No errors on Win7 x64. Thanks for this, was looking for something just like it :oops:

guinness · March 17, 2012

ConsoleWrite(_Random(0, 1) & @CRLF) ; Will return a float number between 0 & 1.
ConsoleWrite(_Random(42, 42) & @CRLF) ; Will return 42, as both values are the same.
ConsoleWrite(_Random(1, 99, 1) & @CRLF) ; Will return an integer number between 1 & 99.

Func _Random($iMin, $iMax, $iInteger = 0)
    Local $iRandom = Random($iMin, $iMax, $iInteger)
    If @error Then
        Return $iMin
    EndIf
    Return $iRandom
EndFunc   ;==>_Random

guinness · March 18, 2012

Idea by It creates a small cue banner similar to _GUICtrlComboBox_SetCueBanner.

#include <GuiEdit.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate('Example', 300, 150)
    GUISetFont(9, 400, 0, 'Segoe UI')

    Local $iUsername = GUICtrlCreateInput('', 10, 10, 125, 25)
    _GUICtrlEdit_SetCueBanner($iUsername, "Search folder")

    Local $iPassword = GUICtrlCreateInput('', 10, 40, 125, 25)
    _GUICtrlEdit_SetCueBanner($iPassword, "Search...")

    Local $iClose = GUICtrlCreateButton("Close", 210, 120, 85, 25)
    ControlFocus($hGUI, "", $iClose)

    GUISetState(@SW_SHOW, $hGUI)

    MsgBox(4096, "", _GUICtrlEdit_GetCueBanner($iPassword))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iClose
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _GUICtrlEdit_GetCueBanner($hWnd)
    If $Debug_Ed Then __UDF_ValidateClassName($hWnd, $__EDITCONSTANT_ClassName)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    Local $tText = DllStructCreate("wchar[4096]")
    If _SendMessage($hWnd, $EM_GETCUEBANNER, $tText, 4096, 0, "struct*") <> 1 Then Return SetError(-1, 0, "")
    Return _WinAPI_WideCharToMultiByte($tText)
EndFunc   ;==>_GUICtrlEdit_GetCueBanner

Func _GUICtrlEdit_SetCueBanner($hWnd, $sText)
    If $Debug_Ed Then __UDF_ValidateClassName($hWnd, $__EDITCONSTANT_ClassName)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    Local $tText = _WinAPI_MultiByteToWideChar($sText)

    Return _SendMessage($hWnd, $EM_SETCUEBANNER, False, $tText, 0, "wparam", "struct*") = 1
EndFunc   ;==>_GUICtrlEdit_SetCueBanner

Edited April 3, 2012 by guinness

guinness · March 21, 2012

_SetEnvironment("CUSTOM_PATH", @ScriptDir, 0)

; #FUNCTION# ====================================================================================================================
; Name ..........: _SetEnvironment
; Description ...: Set/update a system wide environment variable.
; Syntax ........: _SetEnvironment($sEnvironmentVar, $sData[, $iAllUsers = 0])
; Parameters ....: $sEnvironmentVar     - Name of the environment variable to set/update.
;                  $sData               - Value to set the environment variable to. If a value is not used the environment variable will be deleted.
;                  $iAllUsers           - [optional] Add to Current Users (0) or All Users (1). Default is 0.
; Return values .: None
; Author ........: MrCreatoR
; Modified ......: guinness
; Link ..........: http://www.autoitscript.com/forum/topic/46727-can-i-create-a-new-environment-variable/
; Example .......: Yes
; ===============================================================================================================================
Func _SetEnvironment($sEnvironmentVar, $sData, $iAllUsers = 0)
    Local $i64Bit = "", $sRegistryKey = ""

    If StringStripWS($sEnvironmentVar, 8) = "" Then
        Return SetError(1, 0, 0)
    EndIf

    If @OSArch = "X64" Then
        $i64Bit = "64"
    EndIf
    If $iAllUsers Then
        $sRegistryKey = "HKEY_LOCAL_MACHINE" & $i64Bit & "SYSTEMCurrentControlSetControlSession ManagerEnvironment"
    Else
        $sRegistryKey = "HKEY_CURRENT_USER" & $i64Bit & "Environment"
    EndIf

    If StringStripWS($sData, 8) = "" Then
        Return RegDelete($sRegistryKey, $sEnvironmentVar)
    Else
        Return RegWrite($sRegistryKey, $sEnvironmentVar, "REG_SZ", $sData)
    EndIf
EndFunc   ;==>_SetEnvironment

guinness · March 25, 2012

ConsoleWrite(_GetTodaysDate() & @CRLF) ; Return the time.
ConsoleWrite(_GetTodaysDate(0) & @CRLF) ; Return the date without the time.

Func _GetTodaysDate($iReturnTime = 1)
    Local $aMDay[8] = [7, "Sun", "Mon", "Tue", "Wed", "Thur", "Fri", "Sat"], _
            $aMonth[13] = [12, "Jan", "Feb", "Mar", "Apr", "May", "June", "July", "Aug", "Sept", "Oct", "Nov", "Dec"], $aTime[2] = ["", ' ' & @HOUR & ':' & @MIN & ':' & '00']
    Return $aMDay[@WDAY] & ', ' & @MDAY & ' ' & $aMonth[@MON] & ' ' & @YEAR & $aTime[$iReturnTime]
EndFunc   ;==>_GetTodaysDate

guinness · March 26, 2012

_ConvertFileToUTF16(@ScriptDir & "Example.xml")

Func _ConvertFileToUTF16($sFilePath)
    Local $iEncoding = FileGetEncoding($sFilePath)
    Local $hFileOpen = FileOpen($sFilePath, $iEncoding)
    If $hFileOpen = -1 Then
        Return SetError(1, 0, 0)
    EndIf
    Local $sData = FileRead($hFileOpen)
    FileClose($hFileOpen)

    $hFileOpen = FileOpen($sFilePath, 2 + 32)
    If $hFileOpen = -1 Then
        Return SetError(2, 0, 0)
    EndIf
    FileWrite($hFileOpen, $sData)
    Return FileClose($hFileOpen)
EndFunc   ;==>_ConvertFileToUTF16

guinness · March 26, 2012

#include <WinAPI.au3>

; Create a dummy file that is 1MB in size.
_DummyFile(@ScriptDir & "Test.txt", 1, 1) ; Initial idea by trancexx who created it in AutoIt code.

Func _DummyFile($sFilePath, $iSizeMB, $iOverwrite = 0)
    Local $hFile = _WinAPI_CreateFile($sFilePath, 0 + $iOverwrite, 4)
    If Not $hFile Then
        Return SetError(1, 0, 0)
    EndIf
    _WinAPI_SetFilePointer($hFile, 1048576 * $iSizeMB)
    _WinAPI_SetEndOfFile($hFile)
    Return Number(_WinAPI_CloseHandle($hFile))
EndFunc   ;==>_DummyFile

guinness · March 26, 2012

ConsoleWrite(_IsReadOnly(@ScriptFullPath) & @CRLF)

Func _IsReadOnly($sFilePath)
    Return StringInStr(FileGetAttrib($sFilePath), "R") > 0
EndFunc   ;==>_IsReadOnly

guinness · March 26, 2012

#include <Constants.au3>

ConsoleWrite( _GetActiveSSID() & @CRLF)

Func _GetActiveSSID()
    Local $iPID = Run(@ComSpec & ' /u /c ' & 'netsh wlan show interfaces', @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD), $sOutput = ''
    While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then
            ExitLoop
        EndIf
        $sOutput = StringStripWS($sOutput, 7)
    WEnd

    $sReturn = StringRegExp($sOutput, '(?s)(?i)SSIDs*:s(.*?)' & @CR, 3)
    If @error Then
        Return SetError(1, 0, '')
    EndIf
    Return $sReturn[0]
EndFunc   ;==>_GetActiveSSID

guinness · March 27, 2012

ConsoleWrite(Boolean(True) & @CRLF) ; Returns True.
ConsoleWrite(Boolean("This is a string with something True.") & @CRLF) ; Returns False if a string of text (excluding True/False or a number.)
ConsoleWrite(Boolean("1") & @CRLF) ; Returns True as it is a string but a number.
ConsoleWrite(Boolean("False") & @CRLF) ; Returns False.
ConsoleWrite(Boolean("False") & @CRLF) ; Returns False.
ConsoleWrite(Boolean(1) & @CRLF) ; Returns True.

; Convert a value to boolean (True or False).
; If a number is passed then anything that is NOT 0 is True and if a string is the explicit word True, False or a number than it's equivilant boolean value is returned.
; Anthing else e.g. This is a string is False.
Func Boolean($fValue)
    If IsBool($fValue) Then
        Return $fValue
    EndIf
    Return Number($fValue) >= 1
EndFunc   ;==>Boolean

guinness · March 28, 2012

ConsoleWrite(_IsVistaAbove() & @CRLF) ; Returns True is greater or equal to Windows Vista.

Func _IsVistaAbove()
    Return RegRead("HKEY_LOCAL_MACHINESOFTWAREMicrosoftWindows NTCurrentVersion", "CurrentVersion") >= 6.0
EndFunc   ;==>_IsVistaAbove

guinness · March 28, 2012

ConsoleWrite(_IsUACEnabled() & @CRLF) ; Returns 0/1 if disabled/enabled and sets @error to non-zero if the OS doesn't support UAC i.e. XP and below.

Func _IsUACEnabled()
    If RegRead("HKEY_LOCAL_MACHINESOFTWAREMicrosoftWindows NTCurrentVersion", "CurrentVersion") >= 6.0 Then
        Return Number(RegRead("HKEY_LOCAL_MACHINESoftwareMicrosoftWindowsCurrentVersionPoliciesSystem", "ConsentPromptBehaviorAdmin") = 1)
    EndIf
    Return SetError(1, 0, 0)
EndFunc   ;==>_IsUACEnabled

guinness · March 28, 2012

#include <WinAPI.au3>
#include <WindowsConstants.au3>

ConsoleWrite(_IsSafeMode() & @CRLF)

Func _IsSafeMode()
    Return _WinAPI_GetSystemMetrics($SM_CLEANBOOT) > 0
EndFunc   ;==>_IsSafeMode

guinness · March 30, 2012

#include <WinAPI.au3>
#include <WindowsConstants.au3>

MsgBox(64, "_IsWindowsTablet()", _IsWindowsTablet())

Func _IsWindowsTablet()
    Return _WinAPI_GetSystemMetrics($SM_TABLETPC) > 0
EndFunc   ;==>_IsWindowsTablet

guinness · March 30, 2012

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("", 400, 300, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
    Local $iListView = GUICtrlCreateListView("", 0, 0, 400, 270)
    Local $hListView = GUICtrlGetHandle($iListView)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)

    Local $iAllSelected = GUICtrlCreateButton("All Selected?", 400 - 90, 275, 85, 22.5)
    GUICtrlSetResizing(-1, $GUI_DOCKRIGHT + $GUI_DOCKSIZE + $GUI_DOCKBOTTOM)

    GUISetState(@SW_SHOW, $hGUI)

    __ListViewFill($hListView, Random(1, 5, 1), Random(2, 15, 1), 1) ; Randomly fill data in a ListView.

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $iAllSelected
                MsgBox(4096, "", "If all items are checked this will Return True: " & _GUICtrlListView_AllChecked($hListView))

        EndSwitch
    WEnd
    Return GUIDelete($hGUI)
EndFunc   ;==>Example

Func _GUICtrlListView_AllChecked($hListView)
    Local $iChecked = 0, $iCount = _GUICtrlListView_GetItemCount($hListView)
    For $i = 0 To $iCount - 1
        If _GUICtrlListView_GetItemChecked($hListView, $i) Then
            $iChecked += 1
        EndIf
    Next
    Return $iChecked = $iCount ; Returns True - all items are checked or False - some are checked.
EndFunc   ;==>_GUICtrlListView_AllChecked

Func __ListViewFill($hListView, $iColumns, $iRows, $iCheckboxes = 0) ; Randomly fill data in a ListView.
    For $A = 0 To $iColumns - 1
        _GUICtrlListView_InsertColumn($hListView, $A, "Column " & $A + 1, 50)
        _GUICtrlListView_SetColumnWidth($hListView, $A - 1, -2)
    Next
    For $A = 0 To $iRows - 1
        _GUICtrlListView_AddItem($hListView, Chr(Random(65, 90, 1)) & " - Row " & $A + 1 & ": Col 1", $A)
        If Random(0, 1, 1) And $iCheckboxes Then
            _GUICtrlListView_SetItemChecked($hListView, $A)
        EndIf
        For $B = 1 To $iColumns
            _GUICtrlListView_AddSubItem($hListView, $A, "Row " & $A + 1 & ": Col " & $B + 1, $B)
        Next
    Next
EndFunc   ;==>__ListViewFill

guinness · March 30, 2012

#include <Date.au3>

_ChangeDate(@YEAR, @MON , @MDAY) ; Change the date of the local system.

Func _ChangeDate($iYear, $iMon, $iDay)
    Local $sDate = _DateTimeFormat($iYear & "/" & $iMon & "/" & $iDay , 2)
    RunWait(@ComSpec & " /c Date " & $sDate, "", @SW_HIDE)
    Return $sDate
EndFunc   ;==>_ChangeDate

guinness · March 31, 2012

I came across this Trac Ticket #2169 and decided to create a small wrapper function to show this functionality can be created without the need for the Devs to implement directly into AutoIt.

Local $aArray[2][50]
ConsoleWrite(ArrayLength($aArray, 2) & @CRLF) ;= > 10 - Total items
ConsoleWrite(ArrayLength($aArray, 1) & @CRLF) ;= > 5 - Columns
ConsoleWrite(ArrayLength($aArray, 0) & @CRLF) ;= > 2 - Rows

ConsoleWrite(@CRLF)

Local $aArray[2]
ConsoleWrite(ArrayLength($aArray, 2) & @CRLF) ;= > 2 - Total items
ConsoleWrite(ArrayLength($aArray, 1) & @CRLF) ;= > 1 - Columns
ConsoleWrite(ArrayLength($aArray, 0) & @CRLF) ;= > 2 - Rows

Func ArrayLength($aArray, $iType = 1)
    Local $iDim = UBound($aArray, 0)
    If $iDim < 0 Or $iDim > 2 Then ; If not a 1D or 2D Array, then return -1 and set @error to non-zero.
        Return SetError(1, 0, -1)
    EndIf
    Switch $iType
        Case 2
            If $iDim = 2 Then
                Return UBound($aArray, 2) * UBound($aArray, 1)
            Else
                Return UBound($aArray, 1)
            EndIf

        Case 1
            If $iDim = 2 Then
                Return UBound($aArray, 2)
            Else
                Return 1
            EndIf

        Case Else
            Return UBound($aArray, 1)

    EndSwitch
EndFunc   ;==>ArrayLength

Edited March 31, 2012 by guinness

guinness · April 2, 2012

ConsoleWrite(_IsFullPath(@ScriptFullPath) & @CRLF)
ConsoleWrite(_IsFullPath(@ScriptName) & @CRLF)

Func _IsFullPath($sFilePath)
    Return StringInStr($sFilePath, ":", 2) > 0
EndFunc   ;==>_IsFullPath

Edited April 2, 2012 by guinness

guinness · April 2, 2012

I updated the following by Zedna.

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("", 400, 300, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
    Local $iListView = GUICtrlCreateListView("", 0, 0, 400, 270)
    Local $hListView = GUICtrlGetHandle($iListView)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)

    Local $iSelectionState = GUICtrlCreateButton("Change State", 400 - 90, 275, 85, 22.5)
    GUICtrlSetResizing(-1, $GUI_DOCKRIGHT + $GUI_DOCKSIZE + $GUI_DOCKBOTTOM)

    GUISetState(@SW_SHOW, $hGUI)

    __ListViewFill($hListView, Random(1, 5, 1), Random(2, 15, 1), 1) ; Randomly fill data in a ListView.

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $iSelectionState
                _GUICtrlListView_SetCheckedStates($hListView, 2)
                MsgBox(4096, "", "All items were inverted, so if an item was checked before it was unchecked afterwards.")

                _GUICtrlListView_SetCheckedStates($hListView, 0)
                MsgBox(4096, "", "All items were unchecked.")

                _GUICtrlListView_SetCheckedStates($hListView, 1)
                MsgBox(4096, "", "All items were checked.")

        EndSwitch
    WEnd
    Return GUIDelete($hGUI)
EndFunc   ;==>Example

;~ $iType: 0 - UnCheck all, 1 - Check all & 2 - Invert selection.
Func _GUICtrlListView_SetCheckedStates($hListView, $iType) ; By Zedna, Modified by guinness.
    Local $fState = False, $iCount = _GUICtrlListView_GetItemCount($hListView)
    If $iType < 0 Or $iType > 2 Then
        Return SetError(1, 0, 0)
    EndIf
    If $iType Then
        $fState = True
    EndIf
    For $i = 0 To $iCount - 1
        If $iType = 2 Then
            $fState = Not _GUICtrlListView_GetItemChecked($hListView, $i) ; Invert checked state with $iType 2.
        EndIf
        _GUICtrlListView_SetItemChecked($hListView, $i, $fState)
    Next
EndFunc   ;==>_GUICtrlListView_SetCheckedStates

Func __ListViewFill($hListView, $iColumns, $iRows, $iCheckboxes = 0) ; Randomly fill data in a ListView.
    For $A = 0 To $iColumns - 1
        _GUICtrlListView_InsertColumn($hListView, $A, "Column " & $A + 1, 50)
        _GUICtrlListView_SetColumnWidth($hListView, $A - 1, -2)
    Next
    For $A = 0 To $iRows - 1
        _GUICtrlListView_AddItem($hListView, Chr(Random(65, 90, 1)) & " - Row " & $A + 1 & ": Col 1", $A)
        If Random(0, 1, 1) And $iCheckboxes Then
            _GUICtrlListView_SetItemChecked($hListView, $A)
        EndIf
        For $B = 1 To $iColumns
            _GUICtrlListView_AddSubItem($hListView, $A, "Row " & $A + 1 & ": Col " & $B + 1, $B)
        Next
    Next
EndFunc   ;==>__ListViewFill

Sign In

Autoit Wrappers

Recommended Posts

guinness

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

Valuater

Valuater

Valuater

JLogan3o13

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

guinness

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta