Autoit Wrappers

[MilesAhead]

An API alternative to FileExist.

ConsoleWrite(_WinAPI_PathFileExists(@ScriptFullPath) & @LF) ; File.
ConsoleWrite(_WinAPI_PathFileExists("C:") & @LF) ; Drive.
ConsoleWrite(_WinAPI_PathFileExists(@ProgramFilesDir) & @LF) ; Directory.
ConsoleWrite(_WinAPI_PathFileExists("Z:File.txt") & @LF) ; Shouldn't exist!

Func _WinAPI_PathFileExists($sFilePath)
    Local $aReturn = DllCall('shlwapi.dll', 'int', 'PathFileExistsW', 'wstr', $sFilePath)
    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    Return $aReturn[0]
EndFunc   ;==>_WinAPI_PathFileExists

Thanks for posting. Just what I needed as FileExists() tends to time out checking mapped network drives that have been disconnected. This seems to react very quickly. Edited January 21, 2012 by MilesAhead

[guinness]

Retrieve the install date of Windows.

ConsoleWrite(_InstallDate() & @CRLF)

Func _InstallDate()
    Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!" & "." & "rootcimv2")
    Local $oColFiles = $oWMIService.ExecQuery("Select * From Win32_OperatingSystem")
    If IsObj($oColFiles) Then
        For $oObjectFile In $oColFiles
            Return StringRegExpReplace($oObjectFile.InstallDate, "A(d{4})(d{2})(d{2})(d{2})(d{2})(d{2})(?:.*)", "$3/$2/$1 $4:$5:$6")
        Next
    EndIf
    Return SetError(1, 0, 0)
EndFunc   ;==>_InstallDate

[guinness]

If _IsDefault(Default) Then
    MsgBox(0, "_IsDefault() - 1", "This was a Default variable.")
EndIf

If _IsDefault(-1) Then
    MsgBox(0, "_IsDefault() - 2", "This was a Default variable.")
EndIf

If _IsDefault("Other") Then
    MsgBox(0, "_IsDefault() - 3", "This was a Default variable.")
EndIf

Func _IsDefault($sDefault)
    Return StringRegExp($sDefault, "(?-i)s|Default|-1|0")
EndFunc   ;==>_IsDefault

[guinness]

#include <Constants.au3>

ConsoleWrite(_Sort("$sVariable" & @CRLF & "$iVariable" & @CRLF & "$tVariable" & @CRLF & "$pVariable"))

Func _Sort($sSortList)
    Local $iPID = Run("sort.exe", @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD), $sOutput = ""

    StdinWrite($iPID, $sSortList)
    StdinWrite($iPID)

    While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then
            ExitLoop
        EndIf
    WEnd
    Return $sOutput
EndFunc   ;==>_Sort

Edited January 29, 2012 by guinness

[Xenobiologist]

Search in a Listview and show the row with the match as the top row in the listiview.

expandcollapse popup

#include <GuiListView.au3>
_main()
Func _main()
Local $hGUI = GUICreate("Test", 500, 500)
Local $hListView = GUICtrlCreateListView("Items", 10, 10, 480, 380)
_GUICtrlListView_SetColumnWidth($hListView, 0, 450)
For $i = 0 To 250
  Switch $i
   Case 50, 100, 150, 200
    GUICtrlCreateListViewItem("Item 999", $hListView)
   Case Else
    GUICtrlCreateListViewItem("Item " & StringFormat("%03i", $i), $hListView)
  EndSwitch
Next
Local $hButton = GUICtrlCreateButton("Search", 10, 460, 100, 30, 0x0001) ; DEFAULT_BUTTON
Local $hInput = GUICtrlCreateInput("999", 200, 460, 100, 30)
GUICtrlSetState($hInput, 256) ; FOCUS
GUICtrlCreateLabel("Search for 999 - the listview will show the match as top row", 10, 410, 470, 30)
GUISetState()
While 1
  Switch GUIGetMsg()
   Case -3 ; EVENT_CLOSE
    Exit
   Case $hButton
    _search($hListView, GUICtrlRead($hInput))
  EndSwitch
WEnd
EndFunc   ;==>_main
Func _search($hLV, $startPos = 0)
_GUICtrlListView_ClickItem($hLV, _GUICtrlListView_GetTopIndex($hLV)) ;
Local $selIndex_A = _GUICtrlListView_GetSelectedIndices($hLV, True)
Local $iIndex = _GUICtrlListView_FindInText($hLV, $startPos, $selIndex_A[1])
; Scroll to bottom
_GUICtrlListView_EnsureVisible($hLV, _GUICtrlListView_GetItemCount($hLV) - 1)
; Now click item and we get it at the top - or as close as it will go
_GUICtrlListView_SetItemFocused($hLV, $iIndex)
_GUICtrlListView_ClickItem($hLV, $iIndex)
EndFunc   ;==>_search

[fett8802]

It was suggested by guiness that I add this here. This function will move the mouse to a control and click it:

; #FUNCTION# ====================================================================================================================
; Name...........: _ControlMouseClick
; Description ...: Use the mouse to move to a control and click it
; Syntax.........: _ControlMouseClick($iTitle, $iText, $iControl [, $iButton = "left" [, $iClicks = "1" [, $iSpeed = "10" [, $iXpos = "" [, $iYpos = "" ]]]]] )
; Parameters ....: $iTitle  - The title of the window containing the control
;      $iText  - Some text from the window containing the control. Can enter no text be using ""
;      $iControl - The Control ID of the control to click
;      $iButton  - [optional] The button to click: "left", "right", "middle", "main", "menu", "primary", "secondary". Default is "left"
;      $iClicks  - [optional] The number of times to click the mouse. Default is 1.
;      $iSpeed  - [optional] The speed to move the mouse in the range 1 (fastest) to 100 (slowest). A speed of 0 will move the mouse instantly. Default speed is 10.
;      $iXpos  - [optional] The x position to click within the control. Default is center.
;      $iYpos  - [optional] The y position to click within the control. Default is center.
; Author ........: Kris Mills <fett8802 at gmail dot com>
; UserCallTip....: _ControlMouseClick ( "title", "text", controlID [, button [, clicks [, speed [, x [, y ]]]]] ) Use the mouse to move to a control and click it.(required: #include <KrisUDF.au3>)
; ===============================================================================================================================
Func _ControlMouseClick($iTitle, $iText, $iControl, $iButton = "left", $iClicks = "1", $iSpeed = "10", $iXpos = "", $iYpos = "")
$iOriginal = Opt("MouseCoordMode",2)              ;Change the MouseCoordMode to relative coords and get the previous setting
$aPos = ControlGetPos($iTitle, $iText, $iControl)          ;Get the position of the given control
MouseClick($iButton,$aPos[0] + ($aPos[2]/2) + $iXpos, $aPos[1] + ($aPos[3]/2) + $iYpos, $iClicks, $iSpeed) ;Move the mouse and click on the given control
Opt("MouseCoordMode",$iOriginal)               ;Change the MouseCoordMode back to the original
EndFunc   ;==>_ControlMouseClick

Edited February 13, 2012 by fett8802

[Valuater]

Gui with scrollable TabItem

expandcollapse popup

; Gui with scrollable TabItem
; Author - AutoBert

#include <GUIConstantsEx.au3>
#include <ScrollBarConstants.au3>
#include <GuiScrollBars.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>
$hGui = GUICreate("Gui with scrollable TabItem ", 633, 350, 190, 220)
GUISetBkColor(0xFFFFFF)
$idTab = GUICtrlCreateTab(10, 10, 613, 300)
$idTab0 = GUICtrlCreateTabItem("tab0")
$hChild = GUICreate("Scrollbereich", 588, 255, 26, 45, $WS_POPUP, $WS_EX_MDICHILD, $hGui)
$x = 6 ; +22
$y = 8
Local $aInputs[15]
For $i = 0 To 14
 $aInputs[$i] = GUICtrlCreateInput('', $x, $y, 21, 20)
 $x += 22
 $y += 21
Next
_GUIScrollBars_Init($hChild, -1)
_GUIScrollBars_ShowScrollBar($hChild, $SB_HORZ, False) ; horizontale Scrollbar verstecken
_GUIScrollBars_SetScrollRange($hChild, $SB_VERT, 3, 30)
GUISetState(@SW_HIDE, $hChild)
GUISwitch($hGui)
$idTab1 = GUICtrlCreateTabItem("tab----1")
GUICtrlCreateLabel("label1", 30, 80, 50, 20)
$idTab1combo = GUICtrlCreateCombo("", 20, 50, 60, 120)
GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo", "Jon"); default Jon
$idTab1OK = GUICtrlCreateButton("OK1", 80, 50, 50, 20)
$idTab2 = GUICtrlCreateTabItem("tab2")
GUICtrlSetState(-1, $Gui_SHOW); will be display first
GUICtrlCreateLabel("label2", 30, 80, 50, 20)
$idTab2OK = GUICtrlCreateButton("OK2", 140, 50, 50)
GUICtrlCreateTabItem(""); end tabitem definition
$idBtnBack = GUICtrlCreateButton("&Zurueck", 72, 320, 100, 25)
$idBtnCancel = GUICtrlCreateButton("&Beenden", 264, 320, 100, 25)
$idBtnContinue = GUICtrlCreateButton("&Weiter", 448, 320, 100, 25)
GUISetState()
GUIRegisterMsg($WM_VSCROLL, "WM_VSCROLL")
While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $idTab
   $iTab = _GUICtrlTab_GetCurSel($idTab)
   Switch $iTab
    Case 0
     GUISetState(@SW_SHOW, $hChild)
    Case 1
     GUISetState(@SW_HIDE, $hChild)
   EndSwitch
 EndSwitch
WEnd
Func WM_VSCROLL($hWnd, $Msg, $wParam, $lParam)
 #forceref $Msg, $wParam, $lParam
 Local $nScrollCode = BitAND($wParam, 0x0000FFFF)
 Local $index = -1, $yChar, $yPos
 Local $Min, $Max, $Page, $Pos, $TrackPos
 For $x = 0 To UBound($aSB_WindowInfo) - 1
  If $aSB_WindowInfo[$x][0] = $hWnd Then
   $index = $x
   $yChar = $aSB_WindowInfo[$index][3]
   ExitLoop
  EndIf
 Next
 If $index = -1 Then Return 0
 ; Get all the vertial scroll bar information
 Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
 $Min = DllStructGetData($tSCROLLINFO, "nMin")
 $Max = DllStructGetData($tSCROLLINFO, "nMax")
 $Page = DllStructGetData($tSCROLLINFO, "nPage")
 ; Save the position for comparison later on
 $yPos = DllStructGetData($tSCROLLINFO, "nPos")
 $Pos = $yPos
 $TrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
 Switch $nScrollCode
  Case $SB_TOP ; user clicked the HOME keyboard key
   DllStructSetData($tSCROLLINFO, "nPos", $Min)
  Case $SB_BOTTOM ; user clicked the END keyboard key
   DllStructSetData($tSCROLLINFO, "nPos", $Max)
  Case $SB_LINEUP ; user clicked the top arrow
   DllStructSetData($tSCROLLINFO, "nPos", $Pos - 1)
  Case $SB_LINEDOWN ; user clicked the bottom arrow
   DllStructSetData($tSCROLLINFO, "nPos", $Pos + 1)
  Case $SB_PAGEUP ; user clicked the scroll bar shaft above the scroll box
   DllStructSetData($tSCROLLINFO, "nPos", $Pos - $Page)
  Case $SB_PAGEDOWN ; user clicked the scroll bar shaft below the scroll box
   DllStructSetData($tSCROLLINFO, "nPos", $Pos + $Page)
  Case $SB_THUMBTRACK ; user dragged the scroll box
   DllStructSetData($tSCROLLINFO, "nPos", $TrackPos)
 EndSwitch
;~    // Set the position and then retrieve it.  Due to adjustments
;~    //   by Windows it may not be the same as the value set.
 DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
 _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
 _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
 ;// If the position has changed, scroll the window and update it
 $Pos = DllStructGetData($tSCROLLINFO, "nPos")
 If ($Pos <> $yPos) Then
  _GUIScrollBars_ScrollWindow($hWnd, 0, $yChar * ($yPos - $Pos))
  $yPos = $Pos
 EndIf
 Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL

8)

[guinness]

Func _RandomNumber($iStart = 0, $iEnd = 10000000000)
    Return Random($iStart, $iEnd, 1)
EndFunc   ;==>_RandomNumber

Func _RandomText($iLength = 10)
    Local $sData = "", $sRandom
    For $A = 1 To $iLength
        $sRandom = Random(55, 116, 1)
        $sData &= Chr($sRandom + 6 * ($sRandom > 90) - 7 * ($sRandom < 65))
    Next
    Return $sData
EndFunc   ;==>_RandomText

[guinness]

_RunAU3("AU3_Example.txt", '"This is a commandline example!"')

Func _RunAU3($sFilePath,  $sCommandLine = "", $sWorkingDir = "", $iShowFlag = @SW_SHOW, $iOptFlag = 0)
    Return Run('"' & @AutoItExe & '" /AutoIt3ExecuteScript "' & $sFilePath & '" ' & $sCommandLine, $sWorkingDir, $iShowFlag, $iOptFlag)
EndFunc   ;==>_RunAU3

Func _RunWaitAU3($sFilePath, $sCommandLine = "", $sWorkingDir = "", $iShowFlag = @SW_SHOW, $iOptFlag = 0)
    Local $iPID
    $iPID = RunWait('"' & @AutoItExe & '" /AutoIt3ExecuteScript "' & $sFilePath & '" ' & $sCommandLine, $sWorkingDir, $iShowFlag, $iOptFlag)
    If @error Then
        Return SetError(@error, 1, 0)
    EndIf
    Return $iPID
EndFunc   ;==>_RunWaitAU3

[guinness]

Alternatives to FileRead & FileWrite.

Func _GetFile($sFile, $iFormat = 0)
    Local $hFileOpen = FileOpen($sFile, $iFormat)
    If $hFileOpen = -1 Then
        Return SetError(1, 0, "")
    EndIf
    Local $sData = FileRead($hFileOpen)
    FileClose($hFileOpen)
    Return $sData
EndFunc   ;==>_GetFile

Func _SetFile($sString, $sFile, $iOverwrite = 0)
    Local $hFileOpen = FileOpen($sFile, $iOverwrite + 1)
    FileWrite($hFileOpen, $sString)
    FileClose($hFileOpen)
    If @error Then
        Return SetError(1, 0, $sString)
    EndIf
    Return $sString
EndFunc   ;==>_SetFile

Edited April 2, 2012 by guinness

[guinness]

ConsoleWrite(_OSSerial() & @CRLF)

Func _OSSerial()
    Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!" & "." & "rootcimv2")
    Local $oColFiles = $oWMIService.ExecQuery("Select * From Win32_OperatingSystem")
    If IsObj($oColFiles) Then
        For $oObjectFile In $oColFiles
            Return $oObjectFile.SerialNumber
        Next
    EndIf
    Return SetError(1, 0, 0)
EndFunc   ;==>OSSerial

[guinness]

#include <WinAPI.au3>

ConsoleWrite(_WinAPI_PathFindOnPath(@ScriptName) & @LF)
_SetCurrentPath()
ConsoleWrite(_WinAPI_PathFindOnPath(@ScriptName) & @LF)

Func _SetCurrentPath()
    Return EnvSet("PATH", EnvGet("PATH") & ";" & @ScriptDir & "")
EndFunc   ;==>_SetCurrentPath

[guinness]

ConsoleWrite(_IsServer() & @CRLF)

Func _IsServer() ; MSDN: http://msdn.microsoft.com/en-us/library/windows/desktop/aa394239(v=vs.85).aspx
    Local $oWMIService = ObjGet("winmgmts://./root/cimv2"), $oWMIServiceItem
    Local $oColItems = $oWMIService.ExecQuery("Select * From Win32_OperatingSystem")
    If IsObj($oColItems) Then
        For $oWMIServiceItem In $oColItems
            If $oWMIServiceItem.ProductType = 2 Or $oWMIServiceItem.ProductType = 3 Then
                Return 1
            EndIf
        Next
    EndIf
    Return SetError(1, 0, 0)
EndFunc   ;==>_IsServer

[guinness]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("_AlwaysOnTop()", 200, 200, -1, -1)
    Local $iControlID = GUICtrlCreateCheckbox("Always On Top", 5, 10, 85, 25, BitOR($BS_CHECKBOX, $BS_AUTOCHECKBOX, $BS_PUSHLIKE, $WS_TABSTOP))
    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit

            Case $iControlID
                _AlwaysOnTop($hGUI, $iControlID)

        EndSwitch
    WEnd
EndFunc   ;==>Example

Func _AlwaysOnTop($hHandle, $iControlID)
    Local $iState = 0
    If GUICtrlRead($iControlID) = $GUI_CHECKED Then
        $iState = 1
    EndIf
    WinSetOnTop($hHandle, "", $iState)
    Return $iState
EndFunc   ;==>_AlwaysOnTop

Edited March 3, 2012 by guinness

[guinness]

ConsoleWrite(_GetComputerModel() & @CRLF)

Func _GetComputerModel()
    Local $oWMIService = ObjGet("winmgmts:.")
    Local $oColItems = $oWMIService.ExecQuery("Select * From Win32_ComputerSystem", "WQL", 0x30), $sDescription
    If IsObj($oColItems) Then
        For $oObjectItem In $oColItems
            $sDescription &= $oObjectItem.Model
        Next
        Return $sDescription
    EndIf
    Return SetError(1, 1, 0)
EndFunc   ;==>_GetComputerModel

[guinness]

#include <Date.au3>

; Check if the file was modified less than 24 hours ago.
ConsoleWrite(_FileCheck(@ScriptFullPath, 24) & @CRLF)

Func _FileCheck($sFilePath, $iHours = 24)
    Local $aTime
    If FileExists($sFilePath) = 0 Then
        Return SetError(1, 0, 0)
    EndIf
    $aTime = FileGetTime($sFilePath, 0, 0)
    Return Number(_DateDiff("h", $aTime[0] & "/" & $aTime[1] & "/" & $aTime[2] & " " & $aTime[3] & ":" & $aTime[4] & ":" & $aTime[5], @YEAR & "/" & @MON & "/" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC) < $iHours)
EndFunc   ;==>_FileCheck

[guinness]

#include <Constants.au3>

ConsoleWrite( _GetDOSOutput("ping 4.2.2.2") & @CRLF)

Func _GetDOSOutput($sCommand)
    Local $iPID, $sOutput = ""

    $iPID = Run('"' & @ComSpec & '" /c ' & $sCommand, "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    While 1
        $sOutput &= StdoutRead($iPID, False, False)
        If @error Then
            ExitLoop
        EndIf
        Sleep(10)
    WEnd
    Return $sOutput
EndFunc   ;==>_GetDOSOutput

Edited March 26, 2012 by guinness

[guinness]

I saw this #2156 about adding IsDir & IsFile natively to AutoIt, but I did wonder why, since this could be easily achieved using functions already present in AutoIt and quite rightly so this ticket was rejected. Here are the functions.

ConsoleWrite("IsDir: Using a file - " & IsDir(@ScriptFullPath) & @CRLF) ; Return 0
ConsoleWrite("IsFile: Using a file - " & IsFile(@ScriptFullPath) & @CRLF) ; Return 1
ConsoleWrite("IsDir: Using a directory - " & IsDir(@ScriptDir) & @CRLF) ; Return 1
ConsoleWrite("IsFile: Using a directory - " & IsFile(@ScriptDir) & @CRLF) ; Return 0

Func IsDir($sFilePath)
    Return Number(FileExists($sFilePath) And StringInStr(FileGetAttrib($sFilePath), "D", 2, 1) > 0)
EndFunc   ;==>IsDir

Func IsFile($sFilePath)
    Return Number(FileExists($sFilePath) And StringInStr(FileGetAttrib($sFilePath), "D", 2, 1) = 0)
EndFunc   ;==>IsFile

[guinness]

#include <Array.au3>

Local $aMain[11] = [10]
_ArrayEmpty($aMain)
_ArrayDisplay($aMain, "Empty 1D Array.")

Local $aMainEx[11][3] = [[10]]
_ArrayEmpty($aMainEx)
_ArrayDisplay($aMainEx, "Empty 2D Array.")

Func _ArrayEmpty(ByRef $aArray)
    Switch UBound($aArray, 0) ; Dimension, 1D or 2D array are supported.
        Case 1
            Local $aEmpty1D[1]
            $aArray = $aEmpty1D

        Case 2
            Local $aEmpty2D[1][UBound($aArray, 2)]
            $aArray = $aEmpty2D
    EndSwitch
EndFunc   ;==>_ArrayEmpty

[guinness]

#include <Constants.au3>

ConsoleWrite(_Tracert("www.duckduckgo.com") & @CRLF)

Func _Tracert($sURL)
    Local $aReturn, $iPID = 0, $sOutput = ""

    ; -d = Do Not Resolve Host & -h Is The Number Of Hops.
    $iPID = Run(@ComSpec & " /c tracert " & "-d -h 1 " & $sURL, @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then
            ExitLoop
        Endif
    WEnd
    $aReturn = StringRegExp($sOutput, '[(.*)]', 3)
    If @error Then
        Return SetError(1, 0, -1)
    EndIf
    Return $aReturn[0]
EndFunc   ;==>_Tracert

If the SRE can be improved or there's an error with it then by all means please let me know.

Edited March 26, 2012 by guinness