Regular expression - capture a character when "escaped", split otherwise

[therks]

I'm looking for a regex genius, cus I'm stumped when it comes to assertions.

So what I have now, is this regular expression: ([^|=]+)=([^|]+)
It takes a string (user input) of keys=values separated by pipes (ie: "param=value|param=value") and splits them into an array.

Example:

$vParamData = 'example=value|fruit=apple|phrase=Hello world'
$aRegEx = StringRegExp($vParamData, '([^|=]+)=([^|]+)', 3)

; Result
;   [0] => example
;   [1] => value
;   [2] => fruit
;   [3] => apple
;   [4] => phrase
;   [5] => Hello world

So that's working fine, but I'm wondering if there's also a way I could have this capture escaped pipes instead of splitting by them.

ie:

$vParamData = 'pipe test=this \| is a pipe|example=value'
$aRegEx = StringRegExp($vParamData, '([^|=]+)=([^|]+)', 3)

; I'm getting this:
;   [0] => pipe test
;   [1] => this \
;   [2] => example
;   [3] => value

; But I'd like a result like this:
;   [0] => pipe test
;   [1] => this \| is a pipe
;   [2] => example
;   [3] => value

Is there some pattern that would accomplish this, or am I better off parsing it some other way?

Edited April 18, 2018 by therks

[iamtheky]

there are more efficient ways to do the pieces, but here is replacement method that simply avoids the escaped pipes and then slaps it all back together

#include<array.au3>

$vParamData = 'pipe test=this \| is a pipe|example=value'
$aData = stringsplit(stringreplace(_ArrayToString(stringsplit(stringreplace($vParamData , "\|" , "\*") , "|" , 2) , "=") , "\*" , "\|") , "=" , 2)
_ArrayDisplay($aData)

 

[BugFix]

; mask the pipe with a char combination, i.e. "@#"

$vParamData = 'pipe test=this @# is a pipe|example=value'
$aRegEx = StringRegExp($vParamData, '([^|=]+)=([^|]+)', 3)
For $i = 0 To UBound($aRegEx) -1
    $aRegEx[$i] = StringReplace($aRegEx[$i], '@#', '|') ; now replace with the pipe
Next

_ArrayDisplay($aRegEx)

 

[iamtheky]

Might be able to pull off reusing the capture....

$vParamData = 'pipe test=this \| is a pipe|example=value'
msgbox(0, '' , stringreplace(stringregexpreplace($vParamData , "(\\\|)|(=)|(\|)" , "$1" & @LF  ) , "\|" & @LF , "\|"))

 

and without the additional stringreplace, but becoming much more fragile (but works for this specific case).

$vParamData = 'pipe test=this \| is a pipe|example=value'

msgbox(0, '' , stringregexpreplace($vParamData , "(\\\|.*)\||=|(=)|(\|)" , "$1" & @LF ))

 

Edited April 18, 2018 by iamtheky

[jchd]

Another skin:

$vParamData = 'pipe test=this \| is a pipe|example=value|another\|example=five|last \|one = one\|two\|three'
$aRegEx = StringRegExp($vParamData, '(.+?)=((?:\\\||[^\\|])+)(?:\||$)', 3)
_ArrayDisplay($aRegEx)

 

[mikell]

#Include <Array.au3>
$vParamData = 'pipe test=this \| is a pipe|example=value|another\|example=five|last \|one = one\|two\|three'
$aRegEx = StringSplit(StringRegExpReplace($vParamData, '(?<!\\)\|', '='), "=", 3)
_ArrayDisplay($aRegEx)

 

[jchd]

Real programmers use a single function call, quiche eaters use two.
© Ed Post. https://www.ee.ryerson.ca/~elf/hack/realmen.html

[mikell]

Real Programmers aren't afraid to use GOTOs.
So I assume that these 1982 scientists would actually use in AutoIt function calls instead of GOTOs

BTW I'm a fake programmer indeed. Does \Q..\E mean literal quiche eater ?

[jchd]

Computed indirect GOTOs, preferably.