_ArrayDisplay can't show multi-line cell

[Ostap]

I have a small script that checks if users from certain security groups exist or are disabled in AD. 

   For $j = Ubound ( $Users, 1 ) -1 To 0 Step -1
      Switch _AD_IsObjectDisabled ( $Users[$j] )
          Case 1
            ClipPut ( $Users[$j] & " - account disabled; " )
          Case 0
            If @error = 1 Then
               ClipPut ( $Users[$j] & " - account not found; " )
            Else
               ClipPut ( $Users[$j] & " - Ok; " )
            EndIf
      EndSwitch

   $Clip = $Clip & @CRLF & ClipGet ()
   Next

  $Data[$O][1] = $Clip

The code works correctly, at the end I have a 2D array $Data with security group in column 1 and checked user accounts in columns 2. However, _ArrayDisplay ( $Data ) shows users in one row, despite I added @CRLF. When I write $Clip to a text file, user accounts are written as column. Isn't it possible to have multiple-line cell split by @CRLF in _ArrayDisplay? 

[Subz]

Can you post your full code, why are you using Clip functions, why not just concatenate the array and the string?

[Ostap]

Clip functions are easy and they work. Full code is too long and not really relevant here, because question is about output formatting.

Just to illustrate what I am after, here's the code: 

#include <Array.au3>
Global $Array[1][2]
$Cell = "user1 - ok, " & @CRLF & "user2 - disabled, " & @CRLF & "user3 - not found"
$Array[0][0] = "Sometext"
$Array[0][1] = $Cell
_ArrayDisplay ( $Array )
MsgBox ( 0, "", $Cell )

How can I force _ArrayDisplay to show $Array[0][1] as in msgbox? 

[BrewManNH]

_ArrayDisplay isn't meant to show multiline items, listviews in general don't show multiline items by default. You can look in the Examples section for something that might work.

That function is usually meant as a debugging tool and not really designed for much else

 

[mLipok]

As I remember @LarsJ made this magic in one of his ListView Examples / UDF

Edited March 28, 2018 by mLipok

[Bilgus]

You can do it without too much trouble just be aware that if you are pushing a lot of data its going to be slow

#include <Array.au3>
Global $Array[1][2]
Global $iPos
$Cell = "user1 - ok, " & @LF & "user2 - disabled, " & @LF & "user3 - not found"
$iPos = Array_AddLine($Array, 0, "Sometext")
$iPos = Array_AddLine($Array, 1, $Cell)
$iPos = Array_AddLine($Array, 0, "SomeMoretext")
$iPos = Array_AddLine($Array, 1, $Cell & @LF & "user4 - went home")
ConsoleWrite("UBound " & $iPos & @CRLF)
_ArrayDisplay($Array)
MsgBox(0, "", $Cell)

Func Array_AddLine(ByRef $a2DArray, $iCol, $sItem)
    Local $aOut = StringSplit($sItem, @LF)
    If IsArray($aOut) Then
        Local $iCount = $aOut[0]
        $a2DArray[UBound($a2DArray) - 1][$iCol] = $aOut[1]
        If $iCount > 1 Then
            For $i = 2 To $iCount
                _ArrayAdd($a2DArray, $aOut[$i], $iCol)
            Next
        EndIf
    EndIf
    Return (UBound($a2DArray))
EndFunc

To speed it up a bit you could trade _ArrayAdd out for just straight assignment

 Create $Array with a good number of elements and keep a running count of items added in the first element of $Array

#include <Array.au3>
Global $Array[1000][2]
$Array[0][0] = 1
Global $iPos

$Cell = "user1 - ok, " & @LF & "user2 - disabled, " & @LF & "user3 - not found"
$iPos = Array_AddLine($Array, "Sometext", $Cell)
$iPos = Array_AddLine($Array, "SomeMoretext", $Cell & @LF & "user4 - went home")
ConsoleWrite("Pos " & $iPos & @CRLF)

_ArrayDisplay($Array, "", $iPos)

MsgBox(0, "", $Cell)

Func Array_AddLine(ByRef $a2DArray, $sItem1, $sItem2)
    $a2DArray[$a2DArray[0][0]][0] = $sItem1

    Local $aOut = StringSplit($sItem2, @LF)
    If IsArray($aOut) Then
        Local $iCount = $aOut[0]
        $a2DArray[$a2DArray[0][0]][1] = $aOut[1]
        $a2DArray[0][0] += 1

        If $a2DArray[0][0] + $iCount >= UBound($a2DArray) Then
            ReDim $a2DArray[UBound($a2DArray) + $iCount + 1000][2]
        EndIf

        If $iCount > 1 Then
            For $i = 2 To $iCount
                $a2DArray[$a2DArray[0][0]][1] = $aOut[$i]
                $a2DArray[0][0] += 1
            Next
        EndIf
    EndIf
    Return ($a2DArray[0][0])
EndFunc   ;==>Array_AddLine

 

Edited March 28, 2018 by Bilgus

[iamtheky]

There are plenty of ways to organize it in that fashion if just for display.  Some much simpler to extract and reuse the data.

#include <Array.au3>
Global $Array[3][2]

$Cell1 = "user1 - ok" & @LF & "user2 - disabled" & @LF & "user3 - not found"
$Cell2 = "user4 - ok"
$Cell3 = "user5 - ok" & @LF & "user6 - ok"

$Array[0][0] = "Sometext1"
$Array[0][1] =  $Cell1
$Array[1][0] = "Sometext2"
$Array[1][1] =  $Cell2
$Array[2][0] = "Sometext3"
$Array[2][1] =  $Cell3

local $aOut[0]

for $i = 0 to ubound($Array) - 1
    _ArrayAdd($aOut , "       " & $Array[$i][0])
     $aSplit = stringsplit($Array[$i][1] , @LF , 2)
    _ArrayConcatenate($aOut , $aSplit)
Next

_ArrayDisplay($aOut)

 

[Gianni]

as @mLipok has already indicated, if you want to truly write more lines in single cells instead of create more array elements, you should use the techniques explained in the following link by @LarsJ... (however it is not a trivial task)