Disable / Enable GUI Close button

[DigDeep]

Hi,

I wanted the $GUI_EVENT_CLOSE button to be enabled only when I am at my Default GUI screen. Is there a way, I can disable the Close button while I am performing some operations.

I was checking a long ago post and tried putting the below line where ever I wanted to disable the close button. This works, but it also disables when I back to the default screen.

GUIRegisterMsg ($WM_NCLBUTTONDOWN, "WM_NCLBUTTONDOWN_FUNC")

Giving a small example

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#include <GUIConstants.au3>


$Form1 = GUICreate("Close GUI", 615, 199, 642, 406)
$Label1 = GUICtrlCreateLabel("  Open Lable 2", 232, 24, 74, 17)
$Label2 = GUICtrlCreateLabel("  Label2", 240, 104, 66, 17)
GUICtrlSetState($Label2, $GUI_HIDE)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Label1
            GUIRegisterMsg ($WM_NCLBUTTONDOWN, "WM_NCLBUTTONDOWN_FUNC") ; Disabling Close button
            GUICtrlSetState($Label2, $GUI_Show)

        Case $Label2
            GUICtrlSetState($Label2, $GUI_HIDE) ; When $Lable2 is hidden, it means the screen is in default mode. Close button should be enabled now... 
    EndSwitch
WEnd

Func WM_NCLBUTTONDOWN_FUNC($hWnd, $Msg, $WParam, $LParam)
    $nID = BitAnd($wParam, 0x0000FFFF)
    If $nID = 20 Then
        Return 0
    Else
        Return $GUI_RUNDEFMSG
    EndIf
EndFunc

 

[BrewManNH]

Try this:

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#include <GUIConstants.au3>
$CloseGUI = True

$Form1 = GUICreate("Close GUI", 615, 199, 642, 406)
$Label1 = GUICtrlCreateLabel("  Open Label 2", 232, 24, 74, 17)
$Label2 = GUICtrlCreateLabel("  Label2", 240, 104, 66, 17)
GUICtrlSetState($Label2, $GUI_HIDE)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            If $CloseGUI Then Exit

        Case $Label1
            $CloseGUI = False
            GUICtrlSetState($Label2, $GUI_Show)

        Case $Label2
            $CloseGUI = True
            GUICtrlSetState($Label2, $GUI_HIDE) ; When $Lable2 is hidden, it means the screen is in default mode. Close button should be enabled now...
    EndSwitch
WEnd

 

Edited February 19, 2018 by BrewManNH
Corrected code

[DigDeep]

thanks @BrewManNH

[Zedna]

Look here

 

[MojoeB]

expandcollapse popup

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Local $pid = Run('notepad.exe')
Sleep(1000) ; Wait for the window to load

; Find the main window handle of the started process
Local $hWnd = WinGetHandle("[CLASS:Notepad]")
If $hWnd = "" Then
    ConsoleWrite("Window not found." & @CRLF)
    Exit
EndIf

; Display a selection menu
Local $iChoice = MsgBox($MB_ICONQUESTION + $MB_TOPMOST + $MB_YESNOCANCEL, "Choose an Option", _
    "Yes: Remove Minimize and Maximize buttons" & @CRLF & _
    "No: Hide entire title bar" & @CRLF & _
    "Cancel: Exit")

Switch $iChoice
    Case $IDYES
        ; Remove Minimize and Maximize buttons
        Local $iStyle = _WinAPI_GetWindowLong($hWnd, $GWL_STYLE)
        $iStyle = BitAND($iStyle, BitNOT($WS_MINIMIZEBOX + $WS_MAXIMIZEBOX))
        _WinAPI_SetWindowLong($hWnd, $GWL_STYLE, $iStyle)
        _WinAPI_SetWindowPos($hWnd, 0, 0, 0, 0, 0, _
            BitOR($SWP_NOMOVE, $SWP_NOSIZE, $SWP_NOZORDER, $SWP_FRAMECHANGED))
        ConsoleWrite("Minimize and Maximize buttons have been removed." & @CRLF)
    Case $IDNO
        ; Hide entire title bar
        Local $iStyle = _WinAPI_GetWindowLong($hWnd, $GWL_STYLE)
        $iStyle = BitAND($iStyle, BitNOT($WS_CAPTION))
        _WinAPI_SetWindowLong($hWnd, $GWL_STYLE, $iStyle)
        _WinAPI_SetWindowPos($hWnd, 0, 100, 100, 800, 600, _
            BitOR($SWP_NOZORDER, $SWP_FRAMECHANGED))
        ConsoleWrite("Title bar has been removed." & @CRLF)
    Case $IDCANCEL
        ; Exit without making changes
        ConsoleWrite("No changes made." & @CRLF)
        Exit
EndSwitch

 

Edited November 8 by MojoeB