How to Make AutoIt GUI Accept to Drag Files from Windows Explorer

nacerbaaziz · February 12, 2018

Hello all
I have a question please
I've searched a lot on how to make a GUI for programs designed by Autoit to accepts dragging files from Windows File Explorer
Unfortunately, however, it failed
Is there any way to do this?
Where I am making a audio player and I want to activate the feature of dragging files from Windows Explorer to a program window to play them
I hope to find a simple solution here in this wonderful forum
Thank you very much in advance

kylomas · February 12, 2018

nacerbaaziz,

See the example for GuiCtrlCreateInput in the3 help file...

kylomas

Edited February 12, 2018 by kylomas

buymeapc · February 12, 2018

You can start by setting the state of the control you want to drag a file onto, like an input field or similar, with the state of $GUI_DROPACCEPTED and in your main loop, look for $GUI_EVENT_DROPPED. The file path will be held under @GUI_DragFile

The help file has info on this if you get lost.

Cheers!

nacerbaaziz · February 12, 2018

thank you

but it don't work with me

can any one write a example for me

SplashFlo · February 13, 2018

You mean something like this?

#include <GuiConstants.au3>
#include <GuiConstantsEx.au3>
#include <FileConstants.au3>
#include <EditConstants.au3>

GuiCreate('Drag and Drop', 700, 600, @DesktopWidth / 2 - 192, _
            @DesktopHeight / 2 - 235, -1, $WS_EX_ACCEPTFILES)

GUICtrlCreateGroup("Dict Files", 5, 5, 570, 90)
GUICtrlCreateLabel('Select file:', 20, 30)
$dropFile = GUICtrlCreateInput ("", 120, 30, 200, 20, -1, $WS_EX_STATICEDGE)
GUICtrlSetState (-1, $GUI_DROPACCEPTED)
GUICtrlSetTip (-1, 'You can drag & drop files here...')


GUICtrlCreateLabel('Select file:', 20, 60)
$dropFile = GUICtrlCreateInput ("", 120, 60, 200, 20, -1, $WS_EX_STATICEDGE)
GUICtrlSetState (-1, $GUI_DROPACCEPTED)
GUICtrlSetTip (-1, 'You can drag & drop files here...')


GuiSetState() ;Loop GUI
While 1
  $msg = GuiGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        Exit
  EndSelect
WEnd

TheSaint · February 13, 2018

While what SplashFlo provided will work, you will find an Insert can occur rather than Replace for subsequent drops to the same inputs.

So try this instead.

#include <GuiConstants.au3>
#include <GuiConstantsEx.au3>
#include <FileConstants.au3>
#include <EditConstants.au3>

Global $dropFile_1, $dropFile_2

GuiCreate('Drag and Drop', 530, 120, @DesktopWidth / 2 - 192, _
            @DesktopHeight / 2 - 235, -1, $WS_EX_ACCEPTFILES)

GUICtrlCreateGroup("Dict Files", 5, 5, 510, 90)
GUICtrlCreateLabel('File 1:', 20, 30)
$dropFile_1 = GUICtrlCreateInput ("", 80, 30, 400, 20, -1, $WS_EX_STATICEDGE)
GUICtrlSetState (-1, $GUI_DROPACCEPTED)
GUICtrlSetTip (-1, 'You can drag & drop files here...')


GUICtrlCreateLabel('File 2:', 20, 60)
$dropFile_2 = GUICtrlCreateInput ("", 80, 60, 400, 20, -1, $WS_EX_STATICEDGE)
GUICtrlSetState (-1, $GUI_DROPACCEPTED)
GUICtrlSetTip (-1, 'You can drag & drop files here...')


GuiSetState() ;Loop GUI
While 1
  $msg = GuiGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        GUIDelete()
        ExitLoop
    Case $msg = $GUI_EVENT_DROPPED
        If @GUI_DropId = $dropFile_1 Then
            GUICtrlSetData($dropFile_1, @GUI_DragFile)
        ElseIf @GUI_DropId = $dropFile_2 Then
            GUICtrlSetData($dropFile_2, @GUI_DragFile)
        EndIf
  EndSelect
WEnd

Exit

Edited February 13, 2018 by TheSaint

nacerbaaziz · February 13, 2018

Hello again
Thank you very much for your interaction with my question
I have a simple inquiry
You should link the dragging files with a input controle
I mean, if can I drop the file at anywhere in the window
If possible, please tell me how
thank you very much

TheSaint · February 14, 2018

As far as I know, you cannot just drag & drop to a GUI itself. You need to specify a control to receive the drop.

Try this, which importantly has the $label control created last, is the full size of the GUI, and is set as Transparent.

#include <GuiConstants.au3>
#include <GuiConstantsEx.au3>
#include <FileConstants.au3>
#include <EditConstants.au3>

Global $dropFile_1, $dropFile_2, $label

GuiCreate('Drag and Drop', 530, 120, @DesktopWidth / 2 - 192, _
            @DesktopHeight / 2 - 235, -1, $WS_EX_ACCEPTFILES + $WS_EX_TOPMOST)

GUICtrlCreateGroup("Dict Files", 5, 5, 510, 90)
GUICtrlCreateLabel('File 1:', 20, 30)
$dropFile_1 = GUICtrlCreateInput ("", 80, 30, 400, 20, -1)
GUICtrlSetState($dropFile_1, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_1, 'You can drag & drop files here...')

GUICtrlCreateLabel('File 2:', 20, 60)
$dropFile_2 = GUICtrlCreateInput ("", 80, 60, 400, 20, -1)
GUICtrlSetState($dropFile_2, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_2, 'You can drag & drop files here...')

$label = GUICtrlCreateLabel('', 0, 0, 530, 120)
GUICtrlSetBkColor($label, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetState($label, $GUI_DROPACCEPTED)

GuiSetState() ;Loop GUI
While 1
  $msg = GuiGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        GUIDelete()
        ExitLoop
    Case $msg = $GUI_EVENT_DROPPED
        If @GUI_DropId = $dropFile_1 Then
            GUICtrlSetData($dropFile_1, @GUI_DragFile)
        ElseIf @GUI_DropId = $dropFile_2 Then
            GUICtrlSetData($dropFile_2, @GUI_DragFile)
        Else;If @GUI_DropId = $label Then
            MsgBox(262144, "Drop Result", @GUI_DragFile)
        EndIf
  EndSelect
WEnd

Exit

Drag to anywhere but the two Inputs and the MsgBox will popup with file path.

That should give you enough clues to play around with.

Edited February 14, 2018 by TheSaint

nacerbaaziz · February 15, 2018

thank you verry much

apbonn · February 17, 2020

On 2/14/2018 at 4:03 PM, TheSaint said:

As far as I know, you cannot just drag & drop to a GUI itself. You need to specify a control to receive the drop.

Try this, which importantly has the $label control created last, is the full size of the GUI, and is set as Transparent.

#include <GuiConstants.au3>
#include <GuiConstantsEx.au3>
#include <FileConstants.au3>
#include <EditConstants.au3>

Global $dropFile_1, $dropFile_2, $label

GuiCreate('Drag and Drop', 530, 120, @DesktopWidth / 2 - 192, _
            @DesktopHeight / 2 - 235, -1, $WS_EX_ACCEPTFILES + $WS_EX_TOPMOST)

GUICtrlCreateGroup("Dict Files", 5, 5, 510, 90)
GUICtrlCreateLabel('File 1:', 20, 30)
$dropFile_1 = GUICtrlCreateInput ("", 80, 30, 400, 20, -1)
GUICtrlSetState($dropFile_1, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_1, 'You can drag & drop files here...')

GUICtrlCreateLabel('File 2:', 20, 60)
$dropFile_2 = GUICtrlCreateInput ("", 80, 60, 400, 20, -1)
GUICtrlSetState($dropFile_2, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_2, 'You can drag & drop files here...')

$label = GUICtrlCreateLabel('', 0, 0, 530, 120)
GUICtrlSetBkColor($label, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetState($label, $GUI_DROPACCEPTED)

GuiSetState() ;Loop GUI
While 1
  $msg = GuiGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        GUIDelete()
        ExitLoop
    Case $msg = $GUI_EVENT_DROPPED
        If @GUI_DropId = $dropFile_1 Then
            GUICtrlSetData($dropFile_1, @GUI_DragFile)
        ElseIf @GUI_DropId = $dropFile_2 Then
            GUICtrlSetData($dropFile_2, @GUI_DragFile)
        Else;If @GUI_DropId = $label Then
            MsgBox(262144, "Drop Result", @GUI_DragFile)
        EndIf
  EndSelect
WEnd

Exit

Drag to anywhere but the two Inputs and the MsgBox will popup with file path.

That should give you enough clues to play around with.

Hi, im trying to use your example.

I dropped files and it is getting their directory. But now i want to start a skript by using a button and use the input like:

if $start == 1 then
    
    $path1 = MY FIRST DROPPED FILE like C:\Useres\XY\file.xml
    $path2 = MY SECOND DROPPED FILE C:\Useres\XY\file2.xml
    
    do something here
    
endif

How do i do that?

Nine · February 17, 2020

Maybe this ?

#include <Constants.au3>
#include <GuiConstants.au3>
#include <FileConstants.au3>
#include <EditConstants.au3>

Opt("MustDeclareVars", 1)

Local $dropFile_1, $dropFile_2, $label, $msg

GUICreate('Drag and Drop', 530, 150, @DesktopWidth / 2 - 192, _
    @DesktopHeight / 2 - 235, -1, $WS_EX_ACCEPTFILES + $WS_EX_TOPMOST)

GUICtrlCreateGroup("Dict Files", 5, 5, 510, 90)
GUICtrlCreateLabel('File 1:', 20, 30)
$dropFile_1 = GUICtrlCreateInput("", 80, 30, 400, 20, -1)
GUICtrlSetState($dropFile_1, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_1, 'You can drag & drop files here...')

GUICtrlCreateLabel('File 2:', 20, 60)
$dropFile_2 = GUICtrlCreateInput("", 80, 60, 400, 20, -1)
GUICtrlSetState($dropFile_2, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_2, 'You can drag & drop files here...')

Local $idStart = GUICtrlCreateButton("Start", 215, 110, 100, 25)
Local $sFile1, $sFile2

GUISetState()
While 1
  $msg = GUIGetMsg()
  Switch $msg
    Case $GUI_EVENT_CLOSE
      GUIDelete()
      ExitLoop
    Case $GUI_EVENT_DROPPED
      If @GUI_DropId = $dropFile_1 Then
        GUICtrlSetData($dropFile_1, @GUI_DragFile)
      ElseIf @GUI_DropId = $dropFile_2 Then
        GUICtrlSetData($dropFile_2, @GUI_DragFile)
      EndIf
    Case $idStart
      $sFile1 = GUICtrlRead($dropFile_1)
      $sFile2 = GUICtrlRead($dropFile_2)
      If $sFile1 And $sFile2 Then
        ;   do something here
        ; clear fields afterwards
        GUICtrlSetData($dropFile_1, "")
        GUICtrlSetData($dropFile_2, "")
      Else
        MsgBox ($MB_SYSTEMMODAL,"Error","You must provide both file names")
      EndIf
  EndSwitch
WEnd

apbonn · March 2, 2020

On 2/17/2020 at 4:46 PM, Nine said:

Maybe this ?

#include <Constants.au3>
#include <GuiConstants.au3>
#include <FileConstants.au3>
#include <EditConstants.au3>

Opt("MustDeclareVars", 1)

Local $dropFile_1, $dropFile_2, $label, $msg

GUICreate('Drag and Drop', 530, 150, @DesktopWidth / 2 - 192, _
    @DesktopHeight / 2 - 235, -1, $WS_EX_ACCEPTFILES + $WS_EX_TOPMOST)

GUICtrlCreateGroup("Dict Files", 5, 5, 510, 90)
GUICtrlCreateLabel('File 1:', 20, 30)
$dropFile_1 = GUICtrlCreateInput("", 80, 30, 400, 20, -1)
GUICtrlSetState($dropFile_1, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_1, 'You can drag & drop files here...')

GUICtrlCreateLabel('File 2:', 20, 60)
$dropFile_2 = GUICtrlCreateInput("", 80, 60, 400, 20, -1)
GUICtrlSetState($dropFile_2, $GUI_DROPACCEPTED)
GUICtrlSetTip($dropFile_2, 'You can drag & drop files here...')

Local $idStart = GUICtrlCreateButton("Start", 215, 110, 100, 25)
Local $sFile1, $sFile2

GUISetState()
While 1
  $msg = GUIGetMsg()
  Switch $msg
    Case $GUI_EVENT_CLOSE
      GUIDelete()
      ExitLoop
    Case $GUI_EVENT_DROPPED
      If @GUI_DropId = $dropFile_1 Then
        GUICtrlSetData($dropFile_1, @GUI_DragFile)
      ElseIf @GUI_DropId = $dropFile_2 Then
        GUICtrlSetData($dropFile_2, @GUI_DragFile)
      EndIf
    Case $idStart
      $sFile1 = GUICtrlRead($dropFile_1)
      $sFile2 = GUICtrlRead($dropFile_2)
      If $sFile1 And $sFile2 Then
        ;   do something here
        ; clear fields afterwards
        GUICtrlSetData($dropFile_1, "")
        GUICtrlSetData($dropFile_2, "")
      Else
        MsgBox ($MB_SYSTEMMODAL,"Error","You must provide both file names")
      EndIf
  EndSwitch
WEnd

Works like a charme thank you.

But i have one problem now.

I created a function for my script. But now the basic things arent working anymore.

For example

local $var = "test/test/test"
local $xmlFileName = StringRegExpReplace($var, "^.*\/", "")
MsgBox($MB_SYSTEMMODAL, "Test", $xmlFileName)

--> correct output

--------
CASE 2
--------

func test($var)
    local $xmlFileName = StringRegExpReplace($var, "^.*\/", "")
    MsgBox($MB_SYSTEMMODAL, "Test", $xmlFileName)
endfunc

test("test/test/test")

--> wrong ouput, StringRegExpReplace is doing nothing

All the basic function arent working, like stringSplit or all the others

What am i doing wrong?

Nine · March 2, 2020

Seems you are putting the call to test AFTER the while loop, maybe ? Post all your code, crystal ball is out of luck lately...

Block all input without UAC	Save/Retrieve Images to/from Text	Monitor Management (VCP commands)
Tool to search in text (au3) files	Date Range Picker	Virtual Desktop Manager
Sudoku Game 2020	Overlapped Named Pipe IPC	HotString 2.0 - Hot keys with string
x64 Bitwise Operations	Multi-keyboards HotKeySet	Recursive Array Display
Fast and simple WCD IPC	Multiple Folders Selector	Printer Manager
GIF Animation (cached)	Screen Scraping	Multi-Threading Made Easy

Block all input without UAC	Save/Retrieve Images to/from Text	Monitor Management (VCP commands)
Tool to search in text (au3) files	Date Range Picker	Virtual Desktop Manager
Sudoku Game 2020	Overlapped Named Pipe IPC	HotString 2.0 - Hot keys with string
x64 Bitwise Operations	Multi-keyboards HotKeySet	Recursive Array Display
Fast and simple WCD IPC	Multiple Folders Selector	Printer Manager
GIF Animation (cached)	Screen Scraping	Multi-Threading Made Easy

How to Make AutoIt GUI Accept to Drag Files from Windows Explorer

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Similar Content