COM error handling in a UDF - best practice?

[orbs]

COM error handling is a global thing, right? when i declare this:

$oCOMError = ObjEvent('AutoIt.Error', '_COMErrorHandler')

it means that whatever previous declaration i made for "AutoIt.Error" is discarded.

now, suppose i write a UDF that uses COM, and i want to introduce COM error handling in the UDF. i do just that, but then, the main script declares a COM error handler for its own purposes, that is unaware of the UDF COM error handler. this means the UDF COM error handler is discarded.

how to approach such a situation, when i want the UDF COM error handler to not interfere with the main script COM error handler, but still operate?

thanks for any ideas.

[mLipok]

Look in my ADO and XML udf.

HINT: You should declare COM ERROR HANDLER in UDF locally for each function.

 

Edited December 2, 2017 by mLipok

[orbs]

let me see if i get this right:

the main script can define a dedicated function, which resides in the main script, that will handle COM error in the ADO UDF. the ADO UDF error handler, which is not declared globally but at the beginning of every UDF function (thus revoked once the function had returned), will call the main script dedicated function if declared, otherwise will call the UDF default COM error handler.

if so, how should the main script declare a COM error handler for COM operations not related to the UDF?

[water]

Example:
You define a global COM error handler to grab all COM errors occurring in the main script. A local COM error handler grabs all COM errors occurring inside a function.
When  the function ends the local COM error handler is dropped and the global COM error handler is active again.

expandcollapse popup

Global $oGlobalCOMErrorHandler = ObjEvent("AutoIt.Error", "_ErrFuncGlobal") ; Global COM error handler

Global $oIE = ObjCreate("InternetExplorer.Application")
$oIE.xyz
FunctionLocal()
$oIE.xyz
Exit

Func FunctionLocal()
    Local $oLocalCOMErrorHandler = ObjEvent("AutoIt.Error", "_ErrFuncLocal") ; Local COM error handler
    $oIE.xyz
EndFunc

; Global COM error handler
Func _ErrFuncGlobal($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> Global COM error handler - COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

; Local COM error handler
Func _ErrFuncLocal($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> Local COM error handler - COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

 

Edited December 5, 2017 by water

[orbs]

oh, i see what i was missing. the error handler functions accept a parameter! and that parameter is assigned with the error object that was declared in the corresponding ObjEvent() command. not so obvious, but now it makes sense. thanks (again...) @water

[water]

[oemript]

On 12/5/2017 at 10:42 PM, water said:

Func FunctionLocal()     Local $oLocalCOMErrorHandler = ObjEvent("AutoIt.Error", "_ErrFuncLocal") ; Local COM error handler     $oIE.xyz EndFunc

I would like to know on where "AutoIt.Error" come from, would it be used for all purpose as a standard parameter?

Do you have any suggestions?
Thanks, to everyone very much for any suggestions (^v^)

 

[argumentum]

On 10/29/2018 at 10:37 AM, oemript said:

I would like to know on where "AutoIt.Error" come from

the example above is excellent. Now .error is the event of  the object autoit. As in TheObject (dot) TheEvent.
AutoIt.Error  =)

[mLipok]

On 29.10.2018 at 3:37 PM, oemript said:

I would like to know on where "AutoIt.Error" come from, would it be used for all purpose as a standard parameter?

Do you have any suggestions?
Thanks, to everyone very much for any suggestions (^v^)

 

as you can see in HelpFile:
 

Quote

ObjEvent

Handles incoming events from the given Object.

ObjEvent ( $ObjectVar, "functionprefix" [, "interface name"] )
ObjEvent ( "AutoIt.Error" [, "function"] )

in syntax section you see two "formats" which in Remarks are descibed as:

Quote

The first format is used to receive Events from the given Object.
To receive a specific event, create an AutoIt function name using the given prefix appended with the event name.

The second format is used for COM Error Handling.

The second format is an internal "AutoIt" way to change how ObjEvent() acts.

 

The following part of this post, is my way how I understand this feature.

BEWARE: This is only my humble opinion

 

The first format              is used to handle specyfic EVENT of specyfic COM/ActiveX object

The second format        is used to handle COM/ActiveX Errors and then "function" given in second parameter became "COM ERROR HANDLER" for all Error's fired by any COM/ActiveX ERROR, but only   fired by any COM/ActiveX which is used in the same level/scope as  "COM ERROR HANDLER"  was declared by using  in ObjEvent () specyfic keyword Global / Local . For this reason Return from ObjEvent() must be stored to variable, also because cleaning/reseting this this variable is a way to disable "COM ERROR HANDLER". The reasone to store this variable is also to have possibility to set it in Local scope and hide any COM errors in the inner function area (out of UDF). This is also a way to change COM Errors into specyfic @error defined by UDF Developer , as an example you could look in ie.au3 exactly here:
 

Func __IEComErrorUnrecoverable($iError)
    Switch $iError
        ; Cross-domain scripting security error
        Case -2147352567 ; "an exception has occurred."
            Return $_IESTATUS_AccessIsDenied
        Case -2147024891 ; "Access is denied."
            Return $_IESTATUS_AccessIsDenied
            ;
            ; Browser object is destroyed before we try to operate upon it
        Case -2147417848 ; "The object invoked has disconnected from its clients."
            Return $_IESTATUS_ClientDisconnected
        Case -2147023174 ; "RPC server not accessible."
            Return $_IESTATUS_ClientDisconnected
        Case -2147023179 ; "The interface is unknown."
            Return $_IESTATUS_ClientDisconnected
            ;
        Case Else
            Return $_IESTATUS_Success
    EndSwitch
EndFunc   ;==>__IEComErrorUnrecoverable

 

or soon (not published yet) you will be able to show how to Get Last Error Description in my new version of Debenu Quick PDF Library - UDF:

Func _QPDF_LastError_Set(ByRef $oQP, $iError = @error, $iExtended = @extended)
    _QPDF_LastError_SetCode($oQP)
    _QPDF_LastError_SetDescription($oQP)
    Return SetError($iError, $iExtended, $QPDF_RET_DEFAULT)
EndFunc   ;==>_QPDF_LastError_Set

Func _QPDF_LastError_GetCode($iError = @error, $iExtended = @extended)
    Local $oQP = Default ; fake object - to get code
    Return SetError($iError, $iExtended, _QPDF_LastError_SetCode($oQP))
EndFunc   ;==>_QPDF_LastError_GetCode

Func _QPDF_LastError_GetDescription($iError = @error, $iExtended = @extended)
    Local $oQP = Default ; fake object - to get description
    Return SetError($iError, $iExtended, _QPDF_LastError_SetDescription($oQP))
EndFunc   ;==>_QPDF_LastError_GetDescription

Func _QPDF_LastError_ReSet($iError = @error, $iExtended = @extended)
    Local $oQP = Null ; Fake object to Reset
    _QPDF_LastError_SetCode($oQP)
    _QPDF_LastError_SetDescription($oQP)
    Return SetError($iError, $iExtended, $QPDF_RET_DEFAULT)
EndFunc   ;==>_QPDF_LastError_ReSet

used like this:

Func _QPDF_CreateObjectFromStream(ByRef $dPDF_Stream, $sPDF_Password = '')
    Local $oQP
    If _QPDF_CreateObjectAndUnlock($oQP) <> $QPDF_RET_VALID_COMMERCIAL Then Return SetError(@error, @extended, $QPDF_RET_FAILURE)

    __QPDF_IsStream($dPDF_Stream)
    If @error Then Return SetError(@error, $QPDF_EXT_PARAM2, $QPDF_RET_FAILURE)

    If $oQP.LoadFromVariant($dPDF_Stream, $sPDF_Password) = 1 Then _
            Return SetError($QPDF_ERR_SUCCESS, $QPDF_EXT_DEFAULT, $oQP)
    _QPDF_LastError_Set($oQP)
    Return SetError($QPDF_ERR_STREAMCANNOTBELOADED, _QPDF_LastError_GetCode(), $QPDF_RET_FAILURE)
EndFunc   ;==>_QPDF_CreateObjectFromStream

 

Edited December 20, 2018 by mLipok