Error calculating the last row in excel

[LoneWolf_2106]

Hi,

i have an error:

==> The requested action with this object has failed.:
$iRowCount = .Range(.Cells(1, 1), .Cells($oRangeLast.Row, $oRangeLast.Column)).Rows.Count
$iRowCount = .Range(^ ERROR

 

My code is:

$oRangeLast = .UsedRange.SpecialCells($xlCellTypeLastCell)
Sleep(1000)
$iRowCount = .Range(.Cells(1, 1), .Cells($oRangeLast.Row, $oRangeLast.Column)).Rows.Count
Sleep(1000)
_Excel_RangeWrite($oWorkbook_1, $oWorkbook_1.ActiveSheet,$aFileList[$i][2] , "AB3:AB"&$iRowCount)

I have added some sleep because the application was crashing more often before, so i thought to slow down the code execution.

But i didn't solve the issue.

Has anyone an idea of what the problem might be?

Thanks in advance.

[water]

Can you please post the full code? Dot notation only works in a With block. 

Edited November 14, 2017 by water

[LoneWolf_2106]

expandcollapse popup

#include <MsgBoxConstants.au3>
#include <Array.au3>
#include <File.au3>
#include <Excel.au3>
#include <WinAPIShellEx.au3>
#include <Excel_Funktion_test.au3>

; Script Start 

Local Const $sMessage = "Select a folder"

    ; Display an open dialog to select a file.
Global $sFileSelectFolder = FileSelectFolder($sMessage, "")
    If @error Then
        ; Display the error message.
        MsgBox($MB_SYSTEMMODAL, "", "No folder was selected.")
    Else
        ; Display the selected folder.
        MsgBox($MB_SYSTEMMODAL, "", "You chose the following folder:" & @CRLF & $sFileSelectFolder)
    EndIf

Global $Cloud_Folder=""

FolderWrite()
Sleep(1000)

Global $aFileList = _FileListToArray($sFileSelectFolder, Default, Default, True)

$Output_Index = _ArraySearch($aFileList, "Output_Cloud",0,0,0,1)


_ArrayDelete($aFileList, $Output_Index)

FolderScan()

$Path_Len = StringLen($sFileSelectFolder)
_ArrayColInsert($aFileList, 1)



For $i=1 To UBound($aFileList) - 1
    $aFileList[$i][1] = StringTrimLeft($aFileList[$i][0], $Path_Len+1)
Next



_ArrayColInsert($aFileList, 2)


For $i = 1 To UBound($aFileList) - 1

    $split_array=StringSplit($aFileList[$i][1], "_", 2 )

    $aFileList[$i][2] = $split_array[0]
Next






For $i=1 To UBound($aFileList) - 1
    $Excel_File_1 = $aFileList[$i][0]
    Local $oExcel_1 = _Excel_Open()
    Local $vZeile_2 =""
    If @error Then Exit MsgBox(16, "Excel UDF: _Excel_BookOpen Example", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    Local $sWorkbook_1 = $Excel_File_1
    Local $oWorkbook_1 = _Excel_BookOpen($oExcel_1, $sWorkbook_1)
    Sleep(1000)
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpen Example 1", "Error opening '" & $sWorkbook_1 & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
;   MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpen Example 1", "Workbook '" & $sWorkbook_1 & "' has been opened successfully." & @CRLF & @CRLF & "Creation Date: " & $oWorkbook_1.BuiltinDocumentProperties("Creation Date").Value)
    With $oWorkbook_1.ActiveSheet ; process active sheet

        $vZeile_2=_Excel_RangeRead($oWorkbook_1, Default, "A2")

        $vRange=$oWorkBook_1.Activesheet.Range("A2").EntireRow

        If $vZeile_2 = "" Then
            _Excel_RangeDelete($oWorkbook_1.ActiveSheet, $vRange, $xlShiftUp, 1)
        EndIf

        Sleep(1000)

        $oRangeLast = .UsedRange.SpecialCells($xlCellTypeLastCell)
        Sleep(1000)
        $iRowCount = .Range(.Cells(1, 1), .Cells($oRangeLast.Row, $oRangeLast.Column)).Rows.Count
        Sleep(1000)
        _Excel_RangeWrite($oWorkbook_1, $oWorkbook_1.ActiveSheet,$aFileList[$i][2] , "AB3:AB"&$iRowCount)
    EndWith
    ;_Excel_RangeWrite($oWorkbook_1, $oWorkbook_1.ActiveSheet,$aFileList[$i][2] , "AB3:AB"&$iRowCount)
    Sleep(1000)
    _Excel_BookSaveAs($oWorkbook_1, $Cloud_Folder&"\"&$aFileList[$i][1], $xlWorkbookDefault, true)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookSaveAs Example 1", "Error saving workbook to '" & $sWorkbook_1 & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
;MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookSaveAs Example 1", "Workbook successfully saved as '" & $sWorkbook_1 & "'.")
ShellExecute($sWorkbook_1)
Sleep(1000)
_Excel_Close($oExcel_1,False, True)
if @error then MsgBox($MB_OK, "error", @error)
ProcessClose("EXCEL.exe")
Sleep(1000)
Next

Sleep(1000)



Global $aFileList_Modified = _FileListToArray($Cloud_Folder, Default, Default, True)

;_ArrayDisplay($aFileList_Modified)


For $j=1 To UBound($aFileList_Modified) - 1

    ;MsgBox($MB_OK, "test", $aFileList_Modified[$j])

    SpalteAA($aFileList_Modified[$j])
    if @error then MsgBox($MB_OK, "error", @error)
    Sleep(1000)
    ProcessClose("EXCEL.exe")
    Sleep(1000)
Next

MsgBox($MB_OK, "Info", "Alle Dateien wurden bearbeitet")


Func FileSearch()

  ; Assign a Local variable the search handle of all files in the current directory.
    Local $hSearch = FileFindFirstFile("XYZ.xlsx")

    ; Check if the search was successful, if not display a message and return False.
    If $hSearch = -1 Then
        MsgBox($MB_SYSTEMMODAL, "", "Error: No files/directories matched the search pattern.")
        Exit
    Else

        Return True
    EndIf

    ; Close the search handle.
    FileClose($hSearch)
EndFunc

Func FolderScan()
    ; List all the files and folders in the desktop directory using the default parameters and return the full path.
    If @error = 1 Then
        MsgBox($MB_SYSTEMMODAL, "", "Path was invalid.")
        Exit
    EndIf
    If @error = 4 Then
        MsgBox($MB_SYSTEMMODAL, "", "No file(s) were found.")
        Exit
    EndIf
    ; Display the results returned by _FileListToArray.
    ;_ArrayDisplay($aFileList, "$aFileList")
EndFunc

Func FolderWrite()

$Cloud_Folder=$sFileSelectFolder&"\Output_Cloud"

$Folder_exists=FileExists($Cloud_Folder)

If $Folder_exists=0 Then

    _WinAPI_ShellCreateDirectory ( $Cloud_Folder)

EndIf

EndFunc

I hope that this is enough  If you need also the second part(which has no influence on the main one), let me know.

Thanks in advance for your support.

[water]

Will check on Friday as I‘m on vacation right now. 

[LoneWolf_2106]

Enjoy your vacation :-)

Edited November 15, 2017 by LoneWolf_2106

[LoneWolf_2106]

I have noticed that the issue occurs only with the 32 bit Version. The issue is not reproducible in the 64 bit Version.

I have 64 bit OS and Excel is 32 bit.

[water]

I noticed you use your own Excel include file. 
Do you still get the error when using the default Excel UDF that comes with AutoIt?

[Faalamva]

Hi,

This code will give you the last row of column 1, and the last column on row 1 of your Excel file :

$MaxRow = $oWorkbook.Sheets($SheetName).Range("A99999").End(-4162).Row
$MaxCol = $oWorkbook.Sheets($SheetName).Range("ZZ1").End(-4159).Column

-4162 is the internal Excel code for "XlUp" and -4159 the one for "XlToLeft".

Make sure to adapt the 99999 and ZZ if necessary (i.e. if not high enough).

[LoneWolf_2106]

@water I am using the attached version of excel

Excel.au3

[JLogan3o13]

@LoneWolf_2106 when you say last row I am assuming you mean last used row, correct? If so, there are a couple of ways you can do it.

   Something like this is you want all of the data in an array, for later manipulation:

#include <Array.au3>
#include <Excel.au3>

Local $oExcel = _Excel_Open()
Local $oWorkbook = _Excel_BookOpen($oExcel, @DesktopDir & "\defects.xlsx")
Local $aRange = _Excel_RangeRead($oWorkbook, Default, $oExcel.ActiveSheet.UsedRange)

_Excel_BookClose($oWorkbook)
_Excel_Close($oExcel)

    $iLastRow = (UBound($aRange))
    ConsoleWrite($iLastRow & @CRLF)

   Or something like this is you purely want to know the row count:

#include <Array.au3>
#include <Excel.au3>

Local $oExcel = _Excel_Open()
Local $oWorkbook = _Excel_BookOpen($oExcel, @DesktopDir & "\defects.xlsx")
Local $iLastRow = $oExcel.ActiveSheet.UsedRange.Rows.Count

_Excel_BookClose($oWorkbook)
_Excel_Close($oExcel)

    ConsoleWrite($iLastRow & @CRLF)

 

[Juvigy]

On 11/16/2017 at 1:56 PM, LoneWolf_2106 said:

I have noticed that the issue occurs only with the 32 bit Version. The issue is not reproducible in the 64 bit Version.

I have 64 bit OS and Excel is 32 bit.

I think the issue comes from here. Why dont you compile a 32bit script and then a 64bit and test it?

[LoneWolf_2106]

@Juvigy I have compiled 2 Versions, i have tested both for 3 hours. The 32 bit one crashes sometimes.

I would like just to find out the reason, in order to avoid the same issue in the future.

[water]

You have to compile the AutoIt script for the bitness of Excel.
Means:
If Excel is 32 bit then you need to compile your AutoIt script for 32 bit.
If Excel is 64 bit then you need to compile your AutoIt script for 64 bit.

[water]

You open the Excel application over and over again in your Loop. I have cleaned up your loop a bit:

Local $vZeile_2, $sWorkbook_1, $oWorkbook_1
Local $oExcel_1 = _Excel_Open()
If @error Then Exit MsgBox(16, "My Script", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
For $i = 1 To UBound($aFileList) - 1
    $Excel_File_1 = $aFileList[$i][0]
    $vZeile_2 = ""
    $sWorkbook_1 = $Excel_File_1
    $oWorkbook_1 = _Excel_BookOpen($oExcel_1, $sWorkbook_1)
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpen Example 1", "Error opening '" & $sWorkbook_1 & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    With $oWorkbook_1.ActiveSheet ; process active sheet
        $vZeile_2 = _Excel_RangeRead($oWorkbook_1, Default, "A2")
        $vRange = $oWorkbook_1.Activesheet.Range("A2").EntireRow
        If $vZeile_2 = "" Then _Excel_RangeDelete($oWorkbook_1.ActiveSheet, $vRange, $xlShiftUp, 1)
        $oRangeLast = .UsedRange.SpecialCells($xlCellTypeLastCell)
        $iRowCount = .Range(.Cells(1, 1), .Cells($oRangeLast.Row, $oRangeLast.Column)).Rows.Count
        _Excel_RangeWrite($oWorkbook_1, $oWorkbook_1.ActiveSheet, $aFileList[$i][2], "AB3:AB" & $iRowCount)
    EndWith
    _Excel_BookSaveAs($oWorkbook_1, $Cloud_Folder & "\" & $aFileList[$i][1], $xlWorkbookDefault, True)
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "My Script", "Error saving workbook to '" & $Cloud_Folder & "\" & $aFileList[$i][1] & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    ; ShellExecute($sWorkbook_1)
Next
_Excel_Close($oExcel_1, False, True)
If @error Then MsgBox($MB_OK, "error", @error)

 

Edited November 21, 2017 by water

[water]

Another question:
What is

ShellExecute($sWorkbook_1)

for?

[LoneWolf_2106]

@water, thanks for your support. Please ignore that line, i have removed it from the code, i don't even remember what test i have made in August :-)