How to set / change the cursor over RichEdit?

[AndreyS]

Tell me, please, how to set / change the cursor over RichEdit (created with _GUICtrlRichEdit_Create)?

[AndreyS]

Can anybody answer me?
What does not really set / change the cursor at all?

[BrewManNH]

Try GUISetCursor

[AndreyS]

I certainly tried this function! But thanks for wanting to help!

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $hRichEdit, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is more text")
    GUISetState(@SW_SHOW)
    GUISetCursor(1,1,$hRichEdit)
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

 

[AndreyS]

Can not clearly expressed. But this method certainly does not work! Are there any other ways?

[kylomas]

AndreyS,

This link might interest you.  Follow the links inside for various solutions.

kylomas

[AndreyS]

Thank you for your participation kylomas!
How do I understand from your answer the standard functions of AutoIt this is not solved?!

[kylomas]

AndreyS,

Yes, there is no built-in AutoIt function to change a rich edit cursor.  However, I have only rudimentary experience with this.

kylomas

[mikell]

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
#include <winapiex.au3>
#include <WinAPIRes.au3>

$crazy = @tempdir & "\1.cur"
InetGet("http://www.rw-designer.com/cursor-download.php?id=103021", $crazy)

Global $Flag
$hold_cursor = _WinAPI_CopyCursor(_WinAPI_LoadCursor (0, $OCR_IBEAM))
$hnew_Cursor = _WinApi_LoadCursorFromFile($crazy)

    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is more text")
    GUISetState(@SW_SHOW)

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
            _WinAPI_SetSystemCursor($hold_Cursor, $OCR_IBEAM)
            _WinAPI_DestroyCursor($hnew_Cursor)
            _WinAPI_DestroyCursor($hold_cursor )
                Exit
        EndSelect

   If (_CheckMouseOver() = True) and $Flag Then
            _WinAPI_SetSystemCursor($hnew_Cursor, $OCR_IBEAM, 1)
            $Flag = False
    ElseIf (_CheckMouseOver() = False) and not $Flag Then
            _WinAPI_SetSystemCursor($hold_Cursor, $OCR_IBEAM, 1)
            $Flag = True
    EndIf
    WEnd


Func _CheckMouseOver()
    Local $RET = False
    If WinActive($hGui) Then
        Local $aMousePos = MouseGetPos()
        Local $aGuiPos = WinGetPos($hRichEdit)
        If ($aMousePos[0] > $aGuiPos[0]) And ($aMousePos[0] < ($aGuiPos[0] + $aGuiPos[2])) And _
                ($aMousePos[1] > $aGuiPos[1]) And ($aMousePos[1] < ($aGuiPos[1] + $aGuiPos[3])) Then
            $RET = True
        EndIf
    EndIf
    Return $RET
EndFunc   ;==>_CheckMouseOver

 

[AndreyS]

Thank you, mikell, for solving the problem and the idea!

Now it is even easier to organize.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>


Dim $hGui, $hRichEdit, $iMsg, $Flag
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
_GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is more text")
GUISetState(@SW_SHOW)

While True
    $iMsg = GUIGetMsg()
    Select
        Case $iMsg = $GUI_EVENT_CLOSE
            _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
            ; GUIDelete()   ; is OK too
            Exit
    EndSelect
    If (_CheckMouseOver() = True) and $Flag Then
        GUISetCursor(0,1) 
        $Flag = False
    ElseIf (_CheckMouseOver() = False) and not $Flag Then
        GUISetCursor() 
        $Flag = True
    EndIf
WEnd

Func _CheckMouseOver()
    Local $RET = False
    If WinActive($hGui) Then
        Local $aMousePos = MouseGetPos()
        Local $aGuiPos = WinGetPos($hRichEdit)
        If ($aMousePos[0] > $aGuiPos[0]) And ($aMousePos[0] < ($aGuiPos[0] + $aGuiPos[2])) And _
                ($aMousePos[1] > $aGuiPos[1]) And ($aMousePos[1] < ($aGuiPos[1] + $aGuiPos[3])) Then
            $RET = True
        EndIf
    EndIf
    Return $RET
EndFunc   ;==>_CheckMouseOver

 

Edited October 21, 2017 by AndreyS