Passing Function as Parameters

[PNB]

Hi,

My question is regarding how to pass function as parameter

Suppose I have 3 Functions like this

Func A()

EndFunc

Func B($sabc,$pqr,$xyz)

EndFunc

Func C($abc,$xyz,$test,$text)

EndFunc

I have to call these function from only function, all function should be call only from one call function.Just pass function name to that function no matter function has multiple paramaters.Without any select,switch case,if, or calling one by one function like this

Call("A")

Call("B","a","b","c")

Call("B","a","b","c","d")

 

 

 

 

 

[Melba23]

PNB,

Welcome to the AutoIt forum.

But please pay attention to where you post - the "Examples" section where you started this thread is clearly marked: "Do not post general support questions here".  I have moved it for you, but would ask you to be more careful in future.

M23

[LarsJ]

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

Func A()
  ConsoleWrite( "A()" & @CRLF )
EndFunc

Func B($sabc,$pqr,$xyz)
  ConsoleWrite( "B(" & $sabc & "," & $pqr & "," & $xyz & ")" & @CRLF )
EndFunc

Func C($abc,$xyz,$test,$text)
  ConsoleWrite( "C(" & $abc & "," & $xyz & "," & $test & "," & $text & ")" & @CRLF )
EndFunc

Func CallFunc( $f, $p1 = Default, $p2 = Default, $p3 = Default, $p4 = Default )
  Return FuncName($f) = "A" ? $f() : FuncName($f) = "B" ? $f($p1,$p2,$p3) : $f($p1,$p2,$p3,$p4)
EndFunc

Example()

Func Example()
  CallFunc( A )
  CallFunc( B, 1, 2, 3 )
  CallFunc( C, 1, 2, 3, 4 )
EndFunc

 

[jchd]

3 hours ago, PNB said:

I have to call these function from only function, all function should be call only from one call function.Just pass function name to that function no matter function has multiple paramaters.

It's the part in bold which keeps you from doing so. Well, unless all parameters are optional (have default values).
I see that a "workaround" was just posted but it merely illustrates my point about optional parameters.

BTW you rarely need to use Call("A"), just do A() to call it. Also functions are now first-class citizens: a variable can be assigned a function and be passed around.

 

[Gianni]

As explained in the help of the Call() function you can pass a variable number of arguments to a function using the Call() statement and an 1D array as second argument. That is, you have to stack all your arguments in an 1D array, where the first element  (element[0]) must contains the string "CallArgArray" and the following elements contains your arguments (also arrays are allowed as parameters), the receiving function must accept as many arguments as are stacked in the array.
So is up to you to prepare the proper array related to the number of arguments accepted by the function you have to call.

Call("A")

Dim $aArguments[4] = ["CallArgArray", "First parameter", "Second", 3] ; pass 3 arguments
Call("B", $aArguments)

Dim $aArguments[5] = ["CallArgArray", 1, "Second", 3, 4] ; pass 4 arguments
CallMyFunction("C", $aArguments) ; use your custom function to make the Call

; this function call another function and pass as many arguments as contained in the array (if any)
Func CallMyFunction($FunctionName, $aArguments = "")
    Call($FunctionName, $aArguments)
EndFunc   ;==>CallMyFunction


Func A()
    ConsoleWrite("Function A() has no arguments" & @CRLF)
EndFunc   ;==>A

Func B($sabc, $pqr, $xyz)
    ConsoleWrite("Received: " & $sabc & @TAB & $pqr & @TAB & $xyz & @CRLF)
EndFunc   ;==>B

Func C($abc, $xyz, $test, $text = "")
    ConsoleWrite("Received: " & @NumParams & " arguments." & @CRLF)
EndFunc   ;==>C