[Solved]Converting PDF file to word document. Possible for AutoIt?

[KickStarter15]

Hi Experts,

I've tried searching for existing thread on how to convert pdf file into a word file, but it led me to a reverse situation which is word to PDF cases and could not find any samples for me to start with.

I just want to ask if that would be possible using AutoIt and if it is, please share any link or thread that can put me to right track. However, any help from Experts in this forum is much more appreciated.

EDIT: I forgot to add this link which can convert PDF to word file but all contents from PDF was converted as one line in word file output.

 

Thanks in advance Experts.

KS15

Edited June 16, 2017 by KickStarter15

[mLipok]

Only with using wirtual Printer, or using separate ActiveX component .

 

[anthonyjr2]

I actually had this exact problem about a week ago, and after an entire day of searching I still had no luck. Adobe Acrobat DC can export a PDF to Word but there is no way to call it externally so it isn't really possible with AutoIt. To be honest, I couldn't find a single free reliable tool that would be able to do this conversion from the command line. Total bummer.

[ViciousXUSMC]

I would guess it depends if its a flat pdf that is basically an image, or if it has metadata so you can extract the text out of it.

Also maybe 2013 and 2016 have a feature: https://support.office.com/en-us/article/Edit-PDF-content-in-Word-b2d1d729-6b79-499a-bcdb-233379c2f63a

 

[jguinch]

As @ViciousXUSMC said, Office 2013 and above can open a PDF file and save it into another format (doc, docx...)
Try with the Word UDF, why not...

[KickStarter15]

Thanks, Experts for the response appreciated for the ideas, links and details. So, basically, my only chance of having it is using online converter as what does this link do.

However, found some codings for VBA scripting and tried having it this way:

Sub convertToWord()
   Dim MyObj As Object, MySource As Object, file As Variant
   file = Dir("D:\Programs\PDF\" & "*.pdf") 'pdf path
   Do While (file <> "")
   ChangeFileOpenDirectory "D:\Programs\PDF\"
          Documents.Open FileName:=file, ConfirmConversions:=False, ReadOnly:= _
        False, AddToRecentFiles:=False, PasswordDocument:="", PasswordTemplate:= _
        "", Revert:=False, WritePasswordDocument:="", WritePasswordTemplate:="", _
        Format:=wdOpenFormatAuto, XMLTransform:=""
    ChangeFileOpenDirectory "D:\Programs\PDF\WORD" 'saving word
    ActiveDocument.SaveAs2 FileName:=Replace(file, ".pdf", ".docx"), FileFormat:=wdFormatXMLDocument _
        , LockComments:=False, Password:="", AddToRecentFiles:=True, _
        WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:=False, _
         SaveNativePictureFormat:=False, SaveFormsData:=False, SaveAsAOCELetter:= _
        False, CompatibilityMode:=15
    ActiveDocument.Close
     file = Dir
   Loop
End Sub

But it will set as a Windows Default formatting when converting. Tried having it using Office 2010 won't work, but when trying using Office 2013 definitely worked but still in one line paragraph.

Here is a sample screen-grab converted from PDF to DOC.

Is there a way of converting these VBA code to AutoIt? by that, at least we can start and wishing with luck.

 

Edited June 14, 2017 by KickStarter15

[Subz]

This is just using Word (2013 or above) to open a PDF and then saving the file as .doc or .docx, so you should be able to use Word UDF to do this.

[KickStarter15]

@Subz, WORD UDF is kind of complex for my knowledge as for now I need more learning on how to handle Word UDF by water. kind of new with it and still catching up. I have this confusion on how to do this in word udf?

Edited June 14, 2017 by KickStarter15

[mLipok]

Something like this:
 

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>

; Create application object
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Open the test document
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Example.pdf")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error opening 'Example.pdf'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

_Word_DocSaveAs($oDoc, @ScriptDir & "\_Word_Test2.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error saving the Word document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", "Document successfully saved as '" & _
        @ScriptDir & "\_Word_Test2.doc'.")

Remark: not tested.

 

[Subz]

Slightly modified version of mLipoks version.

Disables/Enables the conversion message, not to be confused with _Word_DocOpen conversion parameter
Need to specify $wdFormatDocumentDefault otherwise it just saves it as something like word.doc rather than the name you specify.

#include <Word.au3>

; Create application object
Local $oWord = _Word_Create()
If @error Then Exit

;~ Disable Message: Word will now convert your PDF to an editable Word document.  This may take a while.  The resulting Word document will be optimized to allow you to edit the text, so it might not look exactly like the original PDF, especially if the original file contained lots of graphics.
RegWrite("HKCU\SOFTWARE\Microsoft\Office\15.0\Word\Options", "DisableConvertPdfWarning", "REG_DWORD", 1)
; Open the test document
Local $bDoc = True, $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Filename.pdf")
If @error Then $bDoc = False
;~ Enable Message: Word will now convert your PDF to an editable Word document.  This may take a while.  The resulting Word document will be optimized to allow you to edit the text, so it might not look exactly like the original PDF, especially if the original file contained lots of graphics.
RegWrite("HKCU\SOFTWARE\Microsoft\Office\15.0\Word\Options", "DisableConvertPdfWarning", "REG_DWORD", 0)
If $bDoc = False Then Exit

; *****************************************************************************
; Save the document as Filename.docx
; *****************************************************************************
_Word_DocSaveAs($oDoc, @ScriptDir & "\Filename.docx", $WdFormatDocumentDefault)
If @error Then Exit
_Word_DocClose($oDoc)

 

[KickStarter15]

@Subz and @mLipok your both given codes are working great in converting PDF to Word but using Office 2013. Thanks guys! appreciated.

However, is there a way to have this worked if user used Office 2010? very much thankful if that can be done.

[water]

No, this feature is only available with Office 2013 and later.

[KickStarter15]

@water, I understand your point but as of the current environment we have in our company, it has both Office 2010 and 2013. However, most of our computers has word 2010 which they can't use the program. I was so happy and overwhelm when Subz and mLipok direct me to your Word UDF and gladly you have that feature.

Tried searching for forums and most of issues were involving word 2010 which are still hanging until these days.

Maybe can you make something like that for 2010?

[Subz]

@KickStarter15 The issue is Word 2010 doesn't support the feature, Waters great Word udf just utilizes the Office version installed on the local system.  What you would probably need is a third-party app for instance: http://www.flipbuilder.com/free-pdf-to-word/ (haven't tested), with batch support.  In the past we use to have a similar product to the one mentioned, except from Word to PDF where a user would dump Word documents into a directory and these were automatically converted to Word files, that way we had no requirements for handling Office versions etc...

[KickStarter15]

@Subz, Thanks. How does this work?

[water]

As Subz noted: He didn't test the product. Seems you need to try it yourself  

[KickStarter15]

Got it @water and @Subz, with thanks and everything for the support. But some of the characters from PDF file was changed to unknown characters and some were presented in one line paragraph. So, I preferred to used the below codes from Subz and mLipok and check what's the best. I already requested for installation of Office 2013 of some computers here in our work station but limited only to those in need only.

#include <Word.au3>

; Create application object
Local $oWord = _Word_Create()
If @error Then Exit

;~ Disable Message: Word will now convert your PDF to an editable Word document.  This may take a while.  The resulting Word document will be optimized to allow you to edit the text, so it might not look exactly like the original PDF, especially if the original file contained lots of graphics.
RegWrite("HKCU\SOFTWARE\Microsoft\Office\15.0\Word\Options", "DisableConvertPdfWarning", "REG_DWORD", 1)
; Open the test document
Local $bDoc = True, $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Filename.pdf")
If @error Then $bDoc = False
;~ Enable Message: Word will now convert your PDF to an editable Word document.  This may take a while.  The resulting Word document will be optimized to allow you to edit the text, so it might not look exactly like the original PDF, especially if the original file contained lots of graphics.
RegWrite("HKCU\SOFTWARE\Microsoft\Office\15.0\Word\Options", "DisableConvertPdfWarning", "REG_DWORD", 0)
If $bDoc = False Then Exit

; *****************************************************************************
; Save the document as Filename.docx
; *****************************************************************************
_Word_DocSaveAs($oDoc, @ScriptDir & "\Filename.docx", $WdFormatDocumentDefault)
If @error Then Exit
_Word_DocClose($oDoc)

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>

; Create application object
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Open the test document
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Example.pdf")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error opening 'Example.pdf'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

_Word_DocSaveAs($oDoc, @ScriptDir & "\_Word_Test2.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", _
        "Error saving the Word document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Example", "Document successfully saved as '" & _
        @ScriptDir & "\_Word_Test2.doc'.")

For other computers that has no Office 2013, I already provided them the online converter (off course permitted with IT department). This link and This link as well.

Hopefully in the future seeker for help on converting PDF file to Word file, this thread might help them.

 

Thanks,

KS15

 

Edited June 15, 2017 by KickStarter15
Added link...

[KickStarter15]

Hi @Subz and @water

I need you inputs on the below code on how to change this from _IE... to Firefox. I need to use GUI to run the link in converting PDF to Word file. I need to made something like this so that those who don't have Office2013 yet can use this link.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>

Local $oIE = _IECreateEmbedded()
GUICreate("Embedded Web control Test", 640, 580, _
        (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, _
        $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
GUICtrlCreateObj($oIE, 10, 40, 600, 360)
Local $idButton_Back = GUICtrlCreateButton("Back", 10, 420, 100, 30)
Local $idButton_Forward = GUICtrlCreateButton("Forward", 120, 420, 100, 30)
Local $idButton_Home = GUICtrlCreateButton("Home", 230, 420, 100, 30)
Local $idButton_Stop = GUICtrlCreateButton("Stop", 340, 420, 100, 30)

Global $g_idError_Message = GUICtrlCreateLabel("", 100, 500, 500, 30)
GUICtrlSetColor(-1, 0xff0000)

GUISetState(@SW_SHOW) ;Show GUI

_IENavigate($oIE, "http://www.google.com")
_IEAction($oIE, "stop")

; Waiting for user to close the window
While 1
    Local $iMsg = GUIGetMsg()
    Select
        Case $iMsg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $iMsg = $idButton_Home
            _IENavigate($oIE, "http://www.google.com")
            _IEAction($oIE, "stop")
            _IEAction($oIE, "back")
            CheckError("Home", @error, @extended)
        Case $iMsg = $idButton_Back
            _IEAction($oIE, "back")
            CheckError("Back", @error, @extended)
        Case $iMsg = $idButton_Forward
            _IEAction($oIE, "forward")
            CheckError("Forward", @error, @extended)
        Case $iMsg = $idButton_Stop
            _IEAction($oIE, "stop")
            CheckError("Stop", @error, @extended)
    EndSelect
WEnd

GUIDelete()

Exit

Func CheckError($sMsg, $iError, $iExtended)
    If $iError Then
        $sMsg = "Error using " & $sMsg & " button (" & $iExtended & ")"
    Else
        $sMsg = ""
    EndIf
    GUICtrlSetData($g_idError_Message, $sMsg)
EndFunc   ;==>CheckError

Something like ObjCreate("Mozilla.Browser.1").

[water]

You need to use the Firefox UDF. Please check the example scripts forum for this UDF. 

[KickStarter15]

Thanks, @water. I'll check on Firefox UDF.