Stringreplace behaviour

[IanN1990]

Hi, 

This topic is improve my understanding of stringreplace

StringReplace ( "string", "searchstring/start", "replacestring" [, occurrence = 0 [, casesense = 0]] )

Searchstring/start = The substring to search for or the character position to start the replacement.

$ExampleText = "123456789"
$Replacedtext = StringReplace($ExampleText, 4, "")
ConsoleWrite($Replacedtext & @crlf)

The example fails to remove the fourth character and i dont understand why.

[jchd]

As the help says:

" If the start method is used the occurrence and casesense parameters are ignored. The function will replace the characters in "string", starting at the requested position, with the characters in "replacestring" - as many characters will be replaced as are in "replacestring". However, if there are not enough characters in "string" for the entire "replacestring" to be inserted an empty string is returned and @error is set to 1. "

In your example, "replacestring" has length zero, hence zero characters are replaced.

[Gianni]

you have to use strings, not numbers, try with replacestring as "4" instead of the number 4:

$ExampleText = "123456789"
$Replacedtext = StringReplace($ExampleText, "4", "")
ConsoleWrite($Replacedtext & @crlf)

edit:

P.S. jchd correctly assumes you want to use the second parameter as "start point" method, as it seems from your example, but I think that you just want replace the substring "4" with nothing (just removing it)

Edited April 28, 2017 by Chimp

[IanN1990]

3 hours ago, jchd said:

As the help says:

" If the start method is used the occurrence and casesense parameters are ignored. The function will replace the characters in "string", starting at the requested position, with the characters in "replacestring" - as many characters will be replaced as are in "replacestring". However, if there are not enough characters in "string" for the entire "replacestring" to be inserted an empty string is returned and @error is set to 1. "

In your example, "replacestring" has length zero, hence zero characters are replaced.

I understand the logic. So there is no way to remove a single character using StringReplace and the character location?

Below is a proof of concept.

$ExampleText = "123456789"
$Replacedtext = StringReplaceBlank($ExampleText, 4)
ConsoleWrite($Replacedtext & @crlf)

Func StringReplaceBlank($String, $Number)
    $NewString = StringLeft($String, $Number-1)
    $NewString &= StringRight($String, StringLen($String)-$Number)
    Return $NewString
EndFunc

 

1 hour ago, Chimp said:

you have to use strings, not numbers, try with replacestring as "4" instead of the number 4:

$ExampleText = "123456789"
$Replacedtext = StringReplace($ExampleText, "4", "")
ConsoleWrite($Replacedtext & @crlf)

edit:

P.S. jchd correctly assumes you want to use the second parameter as "start point" method, as it seems from your example, but I think that you just want replace the substring "4" with nothing (just removing it)

Jcdh assumption was correct. I was looking to remove any character at requested location 

[jchd]

Try this:

$ExampleText = "123456789"
$Replacedtext = StringRegExpReplace($ExampleText, "(?<=^...)(.)", "")
ConsoleWrite($Replacedtext & @crlf)

 

[iamtheky]

$ExampleText = "123456789"

$PositionToRemove = 4

$Replacedtext = StringReplace($ExampleText, stringmid($ExampleText , $PositionToRemove , 1) , "")
ConsoleWrite($Replacedtext & @crlf)

 

[Gianni]

A small improvement on the @jchd's pattern lets you choose the starting point and how many chars to remove

$ExampleText = "123456789"
ConsoleWrite(StringRemoveChars($ExampleText, 4) & @CRLF)

; This function removes chars from a string
; $String   The string to elaborate
; $iStart   The starting char position
; $Number   [optional] number of chars to remove (default 1)
;
Func StringRemoveChars($String, $iStart, $Number = 1)

    Return StringRegExpReplace($String, "(?<=^.{" & $iStart - 1 & "})(.{" & $Number & "})", "")

EndFunc   ;==>StringRemoveChars

 

5 hours ago, iamtheky said:

$ExampleText = "123456789"

$PositionToRemove = 4

$Replacedtext = StringReplace($ExampleText, stringmid($ExampleText , $PositionToRemove , 1) , "")
ConsoleWrite($Replacedtext & @crlf)

 

..... Hi @iamtheky,

try to remove with your function only the fourth char from this string "4444444" .....

Edited April 28, 2017 by Chimp
syntax correction

[iamtheky]

$ExampleText = "4444444"

$PositionToRemove = 4

$Replacedtext = stringright($ExampleText , $PositionToRemove - 1) & stringmid($ExampleText , $PositionToRemove + 1)
ConsoleWrite($Replacedtext & @crlf)

yeah I was dumb, this should be better/

[CarlD]

Not much of a tutorial on StringReplace(), but try:

$x = StringRemoveChars("Mississippi", 4, 3)
Exit MsgBox(0, "StringRemoveChars", $x)

Func StringRemoveChars($sStringIn, $iStartPos, $iCount = 1)
    Return StringLeft($sStringIn, $iStartPos - 1) & StringMid($sStringIn, $iStartPos + $iCount)
EndFunc   ;==>StringRemoveChars

Edited April 30, 2017 by CarlD
Working example of code

[mikell]

My 2 cents 

$ExampleText = "123456789"
$PositionToRemove = 4
$Replacedtext = StringRegExpReplace($ExampleText, '^.{' & $PositionToRemove-1 & '}\K.', "")
ConsoleWrite($Replacedtext & @crlf)