_IsPressed('20') dont work well (SPACEBAR)

[Verssuss]

hey guys. here is simple example with keys pressed.

after u click button: press a - working good

                                    press 1 - working good

                                    press F1 - working good

but after u click buton and press SPACEAR it wont work good. what is problem ???

expandcollapse popup

#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>

$GUI = GUICreate("set hotkeys", -1,-1)
GUISetState()

$button_hotkey = (GUICtrlCreateButton("", 80, 30, 150, 25))
Local $hDLL = DllOpen("user32.dll")

$start = False

While 1
    $Msg = GUIGetMsg()
            Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
                Case $button_hotkey
                    $start = True
                    GUICtrlSetData($button_hotkey, "Press Hot Key")
            EndSwitch

        If $start = True And _IsPressed('20', $hDLL) Then
            $start = False
            $klawisz1 = "SPACEBAR"
            GUICtrlSetData($button_hotkey, $klawisz1)
            $start = False
;~          Beep(500)
        EndIf

        If $start = True And _IsPressed('31', $hDLL) Then
            $klawisz1 = "1"
            GUICtrlSetData($button_hotkey, $klawisz1)
            $start = False
        EndIf

        If $start = True And _IsPressed('41', $hDLL) Then
            $klawisz1 = "a"
            GUICtrlSetData($button_hotkey, $klawisz1)
            $start = False
        EndIf

        If $start = True And _IsPressed('70', $hDLL) Then
            $klawisz1 = "F1"
            GUICtrlSetData($button_hotkey, $klawisz1)
            $start = False
        EndIf
WEnd

 

[Melba23]

Verssuss,

Pressing the Spacebar actions the default control - this is a Windows default, nothing to do with AutoIt. I suggest creating a dummy control to which you can give focus so that the main button does not get actioned:

expandcollapse popup

#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>

$GUI = GUICreate("set hotkeys")
GUISetState()

$button_hotkey = (GUICtrlCreateButton("", 80, 30, 150, 25))

$cDummy = GUICtrlCreateButton("Dummy", 80, 100, 150, 25) ; Here is your dummy control <<<<<<<<<<<<<

Local $hDLL = DllOpen("user32.dll")

$start = False

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            DllClose($hDLL) ; If you open it then you must close it <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            Exit
        Case $button_hotkey
            $start = True
            GUICtrlSetData($button_hotkey, "Press Hot Key")
            GUICtrlSetState($cDummy, $GUI_FOCUS) ; Give focus to the dummy <<<<<<<<<<<<<<<<<<<<<<<<<
    EndSwitch

    If $start = True And _IsPressed('20', $hDLL) Then
        $start = False
        $klawisz1 = "SPACEBAR"
        GUICtrlSetData($button_hotkey, $klawisz1)
        $start = False
;~          Beep(500)
    EndIf

    If $start = True And _IsPressed('31', $hDLL) Then
        $klawisz1 = "1"
        GUICtrlSetData($button_hotkey, $klawisz1)
        $start = False
    EndIf

    If $start = True And _IsPressed('41', $hDLL) Then
        $klawisz1 = "a"
        GUICtrlSetData($button_hotkey, $klawisz1)
        $start = False
    EndIf

    If $start = True And _IsPressed('70', $hDLL) Then
        $klawisz1 = "F1"
        GUICtrlSetData($button_hotkey, $klawisz1)
        $start = False
    EndIf
WEnd

M23