Read xml then write to log file

[antmar904]

Hi All,

I have a large xml file that I am trying to read and get any text in between the "<name></name>" brackets then write that text to a log file.

Exp xml:

<name>SOME TEXT</name>

<name>SOME more TEXT</name>

<name>hello world</name>

Output of text file:

SOME TEXT

SOME more TEXT

hello world

 

Ill post what I have of my code shortly.  Thanks

[mLipok]

Did you try anything so far ? Show your code snippet.

Maybe you should also try to start here:

 

[InunoTaishou]

You could also look at _StringBetween

[jdelaney]

Look up examples using:

Local $oXML = ObjCreate("Microsoft.XMLDOM")

.selectNodes('//name')

[antmar904]

This is what I have so far

 

$File = @ScriptDir & "\Data Classes.xml"
$oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.Load($File)
$oNode = $oXML.selectNode('//name')

 

[jdelaney]

close...

_FileCreate("DataClasses.xml")
FileWrite("DataClasses.xml","<root><name>SOME TEXT</name><name>SOME more TEXT</name><name>hello world</name></root>" )

$File = "DataClasses.xml"
$oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.Load($File)
$oNodes = $oXML.selectNodes('//name')
For $oNode In $oNodes
    ConsoleWrite($oNode.text & @CRLF)
Next

 

[InunoTaishou]

Not sure why you need an object to read a plain text file (even if the extension is .xml)

#include <String.au3>
#include <Array.au3>

Global $sXml = @TAB & "<name>SOME TEXT</name>" & @CRLF & @CRLF & @TAB & "<name>SOME more TEXT</name>" & @CRLF & @CRLF & @TAB & "<name>hello world</name>"
Global $sLog = ""

; Option 1
Global $aStringBetween = _StringBetween($sXml, "<name>", "</name>")
_ArrayDisplay($aStringBetween, "_StringBetween")

; Option 2, bypassing _StringBetween (which just uses StringRegExp anyway)
Global $aRegExp = StringRegExp($sXml, "<name>(.*)</name>", 3)
_ArrayDisplay($aRegExp, "StringRegExp")

For $iName = 0 To UBound($aRegExp) - 1
    $sLog &= $aRegExp[$iName] & @CRLF
Next

FileWrite(@ScriptDir & "\Log File.log", StringTrimRight($sLog, 2))

Maybe I'm just weird...

[jdelaney]

It removes all the variability to serialize the contents.  My code will always work...yours will work until an attribute is added.

I do agree that this is a very simple xml as given, but even so, it might have more complexity, and a more specific xpath will grab exactly what you need rather than everything.

Edited March 31, 2017 by jdelaney