GUI_Extender - New Version 16 Apr 2022

Melba23 · March 24, 2021

dmob,

Thanks for that. I will take a look when I can - we are having a lot of electrical work done in the house at the moment and I lose power for quite a lot of the day.

M23

Melba23 · March 27, 2021

dmob,

You asked for it, so you get to test it: GUIExtender_Mod.au3

; #FUNCTION# =========================================================================================================
; Name...........: _GUIExtender_Section_Activate
; Description ...: Creates buttons for extension/retraction of GUI sections
; Syntax.........: _GUIExtender_Section_Activate($hWnd, $iSection[, $sExtended = ""[, $sRetracted = ""[, $iX = 0[, $iY = 0[, $iW = 0[, $iH = 0[, $iType = 0[, $iEventMode = 0]]]]]]]]])
; Parameters ....: $hWnd            - Handle of GUI containing the section
;                  $iSection        - Section to action
;                                     0 = all extendable sections
;                  $sExtended       - Action control content when extended
;                                         Mode 0/1 = Text of button - default: small up/left arrow
;                                         Mode 2   = Path to icon, DLL or executable - main icon displayed
;                                                        If another icon from the file is required, add a trailing "|" followed by the icon index
;                                         Mode 3   = Path to image file
;                  $sRetracted      - Action control content when retracted
;                                         Mode 0/1 = Text of button - default: small down/right arrow
;                                         Mode 2   = Path to icon, DLL or executable - main icon displayed
;                                                        If another icon from the file is required, add a trailing "|" followed by the icon index
;                                         Mode 3   = Path to image file
;                  $iX              - Left side of the control
;                  $iY              - Top of the control
;                  $iW              - Width of the control
;                  $iH              - Height of the control
;                  $iType           - Type of control:
;                                     0 = normal button (default)
;                                     1 = pushbutton
;                                     2 = icon
;                                     3 = image - set to 4 programatically if image is png
;                  $iEventMode      - 0 = (default) MessageLoop mode
;                                     1 = OnEvent mode - control automatically linked to __GUIExtender_Section_Event function
; Requirement(s).: v3.3 +
; Return values .: Success:  Returns 1
;                  Failure:  Returns 0 and sets @error as follows:
;                  1 = GUI not initialised
;                  2 = Control not created
; Author ........: Melba23
; Remarks .......: Sections are static unless an action control has been set
;                  Omitting all optional parameters creates a section which can only be actioned programmatically
; Example........: Yes

Images can be bmp, jpg, gif, or png as requested. Plus you can select any of the available icons in exe/DLL files.

Let me know what you think.

M23

dmob · March 30, 2021

@Melba

Works perfectly, thank you.

Melba23 · March 30, 2021

dmob,

Excellent news - thanks for testing.

M23

Melba23 · March 30, 2021

[New Version] - 30 Mar 21

Added:

- _GUIExtender_EventMonitor now returns 0 if nothing has occurred and 1 if a section has been actioned. @extended is set to the index number of the actioned section or 0 for all sections. This could be useful if you want to have only one section extended at one time - as soon as one is opened you can programmatically retract all the others.

- The action control for a section can now be a normal button, a push button, an icon, or an image. Icons and images are passed as full paths. Normally the main icon of an exe/DLL file is shown, but this can be changed by adding the icon index number separated from the path by "|". See the _GUIExtender_Section_Activate header for more details.

New UDF plus examples in the zip in the first post.

M23

MWIProd · October 27, 2021

Hi Melba23,

GUISetOnEvent($GUI_EVENT_RESTORE) doesn't work with your UDF. Nothing happen when I restore the window.

Which syntax must I use to have this functionnality back ?

Melba23 · October 27, 2021

MWIProd,

If you are using OnEvent mode, the Restore event function should be called automatically by the UDF. Could you please post a short reproducer script so I can debug. -see here how to do it

M23

mLipok · October 27, 2021

Tested on Windows11 - works well

(not related to @MWIProd question)

Edited October 27, 2021 by mLipok

MWIProd · October 28, 2021

Here it is :

#include <GUIConstantsEx.au3>
#include <GUIExtender.au3>
Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("", 500, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "Exit1")
GUISetOnEvent($GUI_EVENT_RESTORE, "Restore")

_GUIExtender_Init($hGUI, 1)
_GUIExtender_Section_Create($hGUI, Default, 300)
_GUIExtender_Section_Activate($hGUI, 2)
GUICtrlCreateButton("Toggle", 20, 20)
GUICtrlSetOnEvent(-1, "Toggle")
Global $idButton = GUICtrlCreateButton("Hello", 20, 200)
_GUIExtender_Section_Create($hGUI, Default, Default)
_GUIExtender_Section_Create($hGUI, -99)
_GUIExtender_Section_Action($hGUI, 2, False) ; hide section 2
GUISetState(@SW_SHOW)
GUICtrlSetState($idButton, $GUI_HIDE)

While 1
    Sleep(10)
WEnd

Func Toggle()
    _GUIExtender_Section_Action($hGUI, 2, 9)
EndFunc   ;==>Toggle

Func Restore()
    GUICtrlSetState($idButton, $GUI_SHOW)
EndFunc   ;==>Restore

Func Exit1()
    Exit
EndFunc   ;==>Exit1

Every time I show/hide section 2, the button $idButton is no longer hidden.

Edited October 28, 2021 by MWIProd

Melba23 · October 28, 2021

MWIProd,

The UDF was not designed to handle hidden controls, so every time the UDF needs to redraw the GUI it assumes that all controls in an expanded section are visible. Hence your hidden button reappears after a restore event and whenever you toggle section 2.

No-one has ever found this a problem before, but I will take a look to see how easy it would be to determine the visible state of each control - and if it could be done without too many changes to the UDF code, how much it would cost in execution time.

M23

MWIProd · October 29, 2021

Melba23,

Thank you for your fast answers.

I understand why you didn't add this functionnality. If you do, I'll be very happy. 🙂

Have a good day.

Melba23 · October 29, 2021

MWIProd,

A fun way to pass a dull day! I think I have a solution for you - I have added a new function to the UDF allowing you to specify which controls should not be automatically reshown when it redraws the GUI. You no longer need to hide/show the control within the script - this function does that as well as telling the UDF whether or not to show it on redraw.

Here is the modified UDF:

And here is a script based on yours to show it working:

#include <GUIConstantsEx.au3>
#include "GUIExtender_Mod.au3"

Opt("GUIOnEventMode", 1)

HotKeySet("^h", "_Hide")
HotKeySet("^s", "_Show")

$hGUI = GUICreate("", 500, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "Exit1")
; No need for the RESTORE Event - handled internally by the UDF

_GUIExtender_Init($hGUI, 1)
_GUIExtender_Section_Create($hGUI, Default, 300)
_GUIExtender_Section_Activate($hGUI, 2)
GUICtrlCreateButton("Toggle", 20, 20)
GUICtrlSetOnEvent(-1, "Toggle")
Global $idButton = GUICtrlCreateButton("Hello", 20, 200)
_GUIExtender_Section_Create($hGUI, Default, Default)
_GUIExtender_Section_Create($hGUI, -99)
_GUIExtender_Section_Action($hGUI, 2, False) ; hide section 2

GUISetState(@SW_SHOW)

; Hide control
_GUIExtender_Hidden_Control($hGUI, $idButton)

While 1
    Sleep(10)
WEnd

Func Toggle()
    _GUIExtender_Section_Action($hGUI, 2, 9)
EndFunc   ;==>Toggle

Func _Show()
    ; Show control
    _GUIExtender_Hidden_Control($hGUI, $idButton, False)
EndFunc
 Func _Hide()
     ; Hide control
    _GUIExtender_Hidden_Control($hGUI, $idButton)
EndFunc

Func Exit1()
    Exit
EndFunc   ;==>Exit1

Please play with it and see if you can break it.

M23

Edited April 16, 2022 by Melba23
Beta code removed

MWIProd · January 21, 2022

Hello Melba23,

Sorry for my late response. I didn't notice your so fast answer. 😯

This is a good day for me. The new version works like a charm.

I am very grateful to you. 🙏

Edited January 21, 2022 by MWIProd

Melba23 · January 21, 2022

MWIProd,

Delighted to hear it - I will release a new version this weekend.

M23

Melba23 · January 30, 2022

Hi,

I would be grateful for some Beta testing on this new version of the UDF as the requester of the latest changes is not responding in his thread:

There are 2 example scripts for you to play with:

- GUIExtender_Test_Example: This demonstrates the new "keep controls hidden" functionality developed over the posts above.

- GUIExtender_Ex_Test_Example: This demonstrates the fusion of extendable sections and scrollbars using my GUIExtender and GUIScrollbars_Size UDFs.

I would be grateful for comments and any eventual bug reports before releasing a new version - here is a zip with all necessary files: GUIExtender_Ex_Beta.zip

M23

Melba23 · April 16, 2022

[New Version] - 16 Apr 2022

Added:

A new function _GUIExtender_Hidden_Control which allows you to specify which controls should not be automatically reshown when it redraws the GUI. You no longer need to hide/show the control within the script - this function does that as well as telling the UDF whether or not to show it on redraw.

New UDF and an additional example in the first post.

M23

Draygoes · April 16, 2022

Nice! Thanks for the update @Melba23:)

lesmly · March 5, 2023

I encountered such a problem, I do not know if it is a bug or lack of my skills.
When I try to add a context menu and use the window shrink button I get an error

Subscript used on non-accessible variable.:
ControlMove($aActive_Section_Data[0][3], "", $iCID, $aPos1[0] - $iAdjust_X, $aPos1[1] - $iAdjust_Y)
ControlMove($aActive_Section_Data[0][3], "", $iCID, $aPos1^ ERROR

Can you check what is causing this?
I am basing this on your example 5

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>

#include "GUIExtender.au3"

$hGUI = GUICreate("Test", 400, 300)

_GUIExtender_Init($hGUI, 1)

_GUIExtender_Section_Create($hGUI, 0, 100)
_GUIExtender_Section_Activate($hGUI, 1)
GUICtrlCreateLabel("", 0, 0, 100, 300)
GUICtrlSetBkColor(-1, 0xFFCCCC)

_GUIExtender_Section_Create($hGUI, 100, 200)
$cButton_1 = GUICtrlCreateButton(">>", 110, 10, 20, 30)
$cButton_2 = GUICtrlCreateButton("<<", 260, 10, 20, 30)

;
$listlistylst = GUICtrlCreateListView("My List", 150, 20, 70, 162)
$hCMenuLST = GUICtrlCreateContextMenu($listlistylst)
$hCMenuzaznacz = GUICtrlCreateMenu("Check", $hCMenuLST)
$hCmenu2p = GUICtrlCreateMenuItem("2 floor", $hCMenuzaznacz)
$hCmenu3p = GUICtrlCreateMenuItem("3 floor", $hCMenuzaznacz)
;

_GUIExtender_Section_Create($hGUI, 300, 100)
_GUIExtender_Section_Activate($hGUI, 3)
GUICtrlCreateLabel("", 300, 0, 100, 300)
GUICtrlSetBkColor(-1, 0xCCCCFF)
_GUIExtender_Section_Create($hGUI, -99)

GUISetState()

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[0]
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton_1
            Switch _GUIExtender_Section_State($hGUI, 1)
                Case 0
                    ; Extend to the left - override default
                    _GUIExtender_Section_Action($hGUI, 1, 1, 2)
                    GUICtrlSetData($cButton_1, ">>")
                Case 1
                    ; Retract from the left - override default
                    _GUIExtender_Section_Action($hGUI, 1, 0, 2)
                    GUICtrlSetData($cButton_1, "<<")
            EndSwitch
        Case  $cButton_2
            Switch _GUIExtender_Section_State($hGUI, 3)
                Case 0
                    ; Extend to the right (default)
                    _GUIExtender_Section_Action($hGUI, 3)
                    GUICtrlSetData($cButton_2, "<<")
                Case 1
                    ; Retract from the right (default
                    _GUIExtender_Section_Action($hGUI, 3, 0)
                    GUICtrlSetData($cButton_2, ">>")
            EndSwitch
    EndSwitch

    _GUIExtender_EventMonitor($aMsg[1], $aMsg[0])

WEnd

Melba23 · March 6, 2023

lesmly,

Nice catch! The Context menu is being created within the GUIExtender structure, but of course cannot be hidden/restored like a normal control. The solution is to create the menu outside of the GUIExtender structure like this:

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>

#include "GUIExtender.au3"

$hGUI = GUICreate("Test", 400, 300)

_GUIExtender_Init($hGUI, 1)

_GUIExtender_Section_Create($hGUI, 0, 100)
_GUIExtender_Section_Activate($hGUI, 1)
GUICtrlCreateLabel("", 0, 0, 100, 300)
GUICtrlSetBkColor(-1, 0xFFCCCC)

_GUIExtender_Section_Create($hGUI, 100, 200)
$cButton_1 = GUICtrlCreateButton(">>", 110, 10, 20, 30)
$cButton_2 = GUICtrlCreateButton("<<", 260, 10, 20, 30)

;
$listlistylst = GUICtrlCreateListView("My List", 150, 20, 70, 162)
;

_GUIExtender_Section_Create($hGUI, 300, 100)
_GUIExtender_Section_Activate($hGUI, 3)
GUICtrlCreateLabel("", 300, 0, 100, 300)
GUICtrlSetBkColor(-1, 0xCCCCFF)
_GUIExtender_Section_Create($hGUI, -99)

$hCMenuLST = GUICtrlCreateContextMenu($listlistylst)
$hCMenuzaznacz = GUICtrlCreateMenu("Check", $hCMenuLST)
$hCmenu2p = GUICtrlCreateMenuItem("2 floor", $hCMenuzaznacz)
$hCmenu3p = GUICtrlCreateMenuItem("3 floor", $hCMenuzaznacz)

GUISetState()

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[0]
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton_1
            Switch _GUIExtender_Section_State($hGUI, 1)
                Case 0
                    ; Extend to the left - override default
                    _GUIExtender_Section_Action($hGUI, 1, 1, 2)
                    GUICtrlSetData($cButton_1, ">>")
                Case 1
                    ; Retract from the left - override default
                    _GUIExtender_Section_Action($hGUI, 1, 0, 2)
                    GUICtrlSetData($cButton_1, "<<")
            EndSwitch
        Case  $cButton_2
            Switch _GUIExtender_Section_State($hGUI, 3)
                Case 0
                    ; Extend to the right (default)
                    _GUIExtender_Section_Action($hGUI, 3)
                    GUICtrlSetData($cButton_2, "<<")
                Case 1
                    ; Retract from the right (default
                    _GUIExtender_Section_Action($hGUI, 3, 0)
                    GUICtrlSetData($cButton_2, ">>")
            EndSwitch
    EndSwitch

    _GUIExtender_EventMonitor($aMsg[1], $aMsg[0])

WEnd

Let me know if that does not work for you - it certainly does for me!

M23

lesmly · March 6, 2023

works great now!

Thanks!

GUI_Extender - New Version 16 Apr 2022

Recommended Posts

Link to comment

Share on other sites

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

Melba23

Melba23

Melba23

Posted Images

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members