Switch an Item from a ComboBox with Hotkey

[Cascraft]

Hi Experts

How do I switch an Item from a ComboBox up/down with Hotkey?

 

Code:

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 310, 152, 361, 178)
$Combo1 = GUICtrlCreateCombo("Combo1", 16, 64, 145, 25)
GUICtrlSetData(-1, "Item1|Item2|Item3|Item4|Item5")
$Label1 = GUICtrlCreateLabel("Press Alt+F TO select UP", 16, 16, 128, 17)
$Label2 = GUICtrlCreateLabel("Press Alt+C TO select DOWN", 16, 40, 143, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    If _IsPressed(12) And _IsPressed(46) Then
        ; SWITCH UP
                                                 ;????COMMAND????("Form1", "", $Combo1, "ShowDropDown", "")
    ElseIf _IsPressed(12) And _IsPressed(43) Then
       ; SWITCH DOWN
    EndIf
WEnd

 

[Melba23]

Cascraft,

Welcome to the AutoIt forums.

This seems to work:

#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <GuiComboBox.au3>

Local $hDLL = DllOpen("user32.dll")

$Form1 = GUICreate("Form1", 310, 152, 361, 178)
$Combo1 = GUICtrlCreateCombo("Combo1", 16, 64, 145, 25)
GUICtrlSetData(-1, "Item1|Item2|Item3|Item4|Item5")
$Label1 = GUICtrlCreateLabel("Press Alt+F TO select UP", 16, 16, 128, 17)
$Label2 = GUICtrlCreateLabel("Press Alt+C TO select DOWN", 16, 40, 143, 17)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            DllClose($hDLL)
            Exit
    EndSwitch
    If _IsPressed(12, $hDLL) And _IsPressed(46, $hDLL) Then
        $iIndex = _GUICtrlComboBox_GetCurSel($Combo1)
        If $iIndex < _GUICtrlComboBox_GetCount($Combo1) - 1 Then
            $iIndex += 1
            $iRet = _GUICtrlComboBox_SetCurSel($Combo1, $iIndex)
        EndIf
        While _IsPressed(12, $hDLL) And _IsPressed(46, $hDLL)
            Sleep(10)
        WEnd

    ElseIf _IsPressed(12, $hDLL) And _IsPressed(43, $hDLL) Then
       ; SWITCH DOWN
    EndIf
WEnd

I leave the DOWN part to you.

M23